-
Notifications
You must be signed in to change notification settings - Fork 0
/
spaceinvader.asm
1500 lines (1226 loc) · 52.3 KB
/
spaceinvader.asm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
; ==============================
; Definition des constantes
; ==============================
; Memoire video
; ------------------------------
VIDEO_START equ $ffb500 ; Adresse de départ
VIDEO_WIDTH equ 480 ; Largeur en pixels
VIDEO_HEIGHT equ 320 ; Hauteur en pixels
VIDEO_SIZE equ (VIDEO_WIDTH*VIDEO_HEIGHT/8) ; Taille en octets
BYTE_PER_LINE equ (VIDEO_WIDTH/8) ; Nombre d'octets par ligne
VIDEO_BUFFER equ (VIDEO_START-VIDEO_SIZE) ; Tampon vidéo
; Bitmaps
; ------------------------------
WIDTH equ 0 ; Largeur en pixels
HEIGHT equ 2 ; Hauteur en pixels
MATRIX equ 4 ; Matrice de points
; Envahisseurs
; ------------------------------
INVADER_PER_LINE equ 10
INVADER_PER_COLUMN equ 5
INVADER_COUNT equ INVADER_PER_LINE*INVADER_PER_COLUMN
INVADER_STEP_X equ 4
INVADER_STEP_Y equ 8
INVADER_X_MIN equ 0
INVADER_X_MAX equ (VIDEO_WIDTH-(INVADER_PER_LINE*32))
INVADER_SHOT_MAX equ 5
; Ship
; ------------------------------
SHIP_STEP equ 4; Pas du vaisseau
SHIP_SHOT_STEP equ 4; Pas d'un tir de vaisseau
INVADER_SHOT_STEP equ 1; Pas d'un tir d'envahisseur
; Bonus
; ------------------------------
BONUS_INVADER_STEP equ 3 ; Pas du invader bonus
BONUS_GAIN equ 4 ; Vitesse gagner grace au bonus
BONUS_POP equ 30 ; Nombre dinvader pour le spawn du bonus
BONUS_STOP equ 10 ; Nombre dinvader pour la fin de la vitesse bonus
; Jeux
; ------------------------------
SHIP_WIN equ 1
SHIP_HIT equ 3
SHIP_COLLIDING equ 45
INVADER_LOW equ 30
; Sprites
; ------------------------------
STATE equ 0; État de l'affichage
X equ 2; Abscisse
Y equ 4; Ordonnée
BITMAP1 equ 6; Bitmap no 1
BITMAP2 equ 10; Bitmap no 2
HIDE equ 0; Ne pas afficher le sprite
SHOW equ 1; Afficher le sprite
SIZE_OF_SPRITE equ 14; Taille d'un sprite en octets
; ==============================
; Initialisation des vecteurs
; ==============================
org $0
vector_000 dc.l VIDEO_BUFFER ; Valeur initiale de A7
vector_001 dc.l Main ; Valeur initiale du PC
PrintChar incbin "PrintChar.bin"
; ==============================
; Programme principal
; ==============================
org $500
; ==============================
; Sous-programmes
; ==============================
PixelToByte ; Taille en pixels + 7 -> D3.W
addq.w #7,d3
; D3.W/8 -> D3.W
lsr.w #3,d3
; Sortie du sous-programme.
rts
CopyBitmap ; Sauvegarde les registres dans la pile.
movem.l d3/d4/a0/a1,-(a7)
; Largeur en octets -> D3.W
move.w WIDTH(a0),d3
jsr PixelToByte
; Nombre d'itérations - 1 (car DBRA) -> D4.W
; Nombre d'itérations = Hauteur en pixels
move.w HEIGHT(a0),d4
subq.w #1,d4
; Adresse de la matrice de points -> A0.L
lea MATRIX(a0),a0
\loop ; Copie une ligne de la matrice.
jsr CopyLine
; Passe à l'adresse vidéo de ligne suivante.
adda.l #BYTE_PER_LINE,a1
; Reboucle tant qu'il y a des lignes à afficher.
dbra d4,\loop
; Restaure les registres puis sortie.
movem.l (a7)+,d3/d4/a0/a1
rts
FillScreen ; Sauvegarde les registres dans la pile.
movem.l d7/a0,-(a7)
; Fait pointer A0 sur la mémoire vidéo.
; Cette instruction est identique à :
movea.l #VIDEO_START,a0
lea VIDEO_START,a0
; Initialisation du compteur de boucle (D7.W).
; La copie se fera sur 32 bits, c'est-à-dire sur 4 octets.
; Le nombre d'itérations est donc la taille en octets divisée par 4.
; Le test de sortie se fera à l'aide de DBRA,
; donc D7.W doit contenir le nombre d'itérations moins 1 (cf. cours).
move.w #VIDEO_SIZE/4-1,d7
\loop ; Copie la donnée dans la mémoire vidéo
; et passe à l'adresse suivante.
move.l d0,(a0)+
dbra d7,\loop
; Restaure les registres puis sortie.
movem.l (a7)+,d7/a0
rts
CopyLine ; Sauvegarde les registres.
movem.l d1-d4/a1,-(a7)
; Nombre d'itérations = Largeur en octets
; Nombre d'itérations - 1 (car DBRA) -> D3.W
subq.w #1,d3
\loop ; Octet à copier -> D1.B et D2.B
move.b (a0)+,d1
move.b d1,d2
; Décale D1.B vers la droite de D0 bits.
lsr.b d0,d1
; Décale D2.B vers la gauche de (8 - D0) bits.
moveq.l #8,d4
sub.w d0,d4
lsl.b d4,d2
; Copie D1.B et D2.B dans la mémoire vidéo.
or.b d1,(a1)+
or.b d2,(a1)
; Reboucle tant qu'il y a des octets à copier.
dbra d3,\loop
; Restaure les registres puis sortie.
movem.l (a7)+,d1-d4/a1
rts
PixelToAddress ; Sauvegarde les registres.
movem.l d1/d2,-(a7)
; Détermine le nombre d'octets à ajouter en abscisse.
; Divise l'abscisse par 8 :
; Quotient -> D1.W (nombre d'octets)
; Reste -> D0.W (décalage)
move.w d1,d0
lsr.w #3,d1
andi.w #%111,d0
; Détermine le nombre d'octets à ajouter en ordonnée.
; Multiplie l'ordonnée par le nombre d'octets par ligne.
; D2.W * BYTE_PER_LINE -> D2.L
mulu.w #BYTE_PER_LINE,d2
; Détermine l'adresse vidéo.
; VIDEO_START + Nombre d'octets à ajouter en abscisse et en ordonnée.
lea VIDEO_BUFFER,a1
adda.w d1,a1
adda.l d2,a1
; Restaure les registres puis sortie.
movem.l (a7)+,d1/d2
rts
PrintBitmap ; Sauvegarde les registres.
movem.l d0/a1,-(a7)
; Adresse vidéo -> A1.L
; Décalage -> D0.W
jsr PixelToAddress
; Copie la matrice de points du bitmap dans la mémoire vidéo.
jsr CopyBitmap
\quit ; Restaure les registres puis sortie.
movem.l (a7)+,d0/a1
rts
ClearScreen ; Sauvegarde les registres.
move.l d0,-(a7)
; Remplit la mémoire vidéo avec des zéros.
moveq.l #0,d0
jsr FillScreen
; Restaure les registres puis sortie.
move.l (a7)+,d0
rts
BufferToScreen ; Sauvegarde les registres.
movem.l d7/a0/a1,-(a7)
; Tampon vidéo -> A0.L
lea VIDEO_BUFFER,a0
; mémoire vidéo -> A1.L
lea VIDEO_START,a1
; Nombre d'itérations - 1 -> D7.W (car DBRA)
; Nombre d'itérations = Nombre de mots longs
move.w #VIDEO_SIZE/4-1,d7
\loop ; Copie un mot long du tampon vers la mémoire vidéo.
move.l (a0),(a1)+
; Met à 0 le mot long du tampon qui vient d'être copié.
clr.l (a0)+
; Reboucle tant qu'il y a des mots longs à copier.
dbra d7,\loop
; Restaure les registres puis sortie.
movem.l (a7)+,d7/a0/a1
rts
PrintSprite ; Sauvegarde les registres.
movem.l d1/d2/a0,-(a7)
; Si le sprite ne doit pas être affiché, on quitte.
cmp.w #HIDE,STATE(a1)
beq \quit
; Affiche le sprite.
move.w X(a1),d1
move.w Y(a1),d2
movea.l BITMAP1(a1),a0
jsr PrintBitmap
\quit ; Restaure les registres puis sortie.
movem.l (a7)+,d1/d2/a0
rts
IsOutOfX ; Sauvegarde les registres.
move.l d1,-(a7)
; Si l'abscisse est négative, le bitmap sort de l'écran.
; On renvoie true.
tst.w d1
bmi \true
; Abscisse à la droite du bitmap -> D1.W
add.w WIDTH(a0),d1
; Si l'abscisse à la droite du bitmap
; est supérieure stricte à la largeur de l'écran,
; le bitmap sort de l'écran.
; On renvoie true.
cmp.w #VIDEO_WIDTH,d1
bgt \true
; Sinon, le bitmap ne sort pas de l'écran.
; On renvoie false.
\false ; Sortie qui renvoie false (Z = 0).
move.l (a7)+,d1
andi.b #%11111011,ccr
rts
\true ; Sortie qui renvoie true (Z = 1).
move.l (a7)+,d1
ori.b #%00000100,ccr
rts
IsOutOfY ; Sauvegarde les registres.
move.l d2,-(a7)
; Si l'ordonnée est négative, le bitmap sort de l'écran. ; On renvoie true.
tst.w d2
bmi \true
; Ordonnée juste sous le bitmap -> D2.W
add.w HEIGHT(a0),d2
; Si l'ordonnée juste sous le bitmap
; est supérieure stricte à la hauteur de l'écran, ; le bitmap sort de l'écran.
; On renvoie true.
cmp.w #VIDEO_HEIGHT,d2
bgt \true
; Sinon, le bitmap ne sort pas de l'écran.
; On renvoie false.
\false ; Sortie qui renvoie false (Z = 0).
move.l (a7)+,d2
andi.b #%11111011,ccr
rts
\true ; Sortie qui renvoie true (Z = 1).
move.l (a7)+,d2
ori.b #%00000100,ccr
rts
IsOutOfScreen ; Si le bitmap sort de l'axe des abscisses, on renvoie true.
jsr IsOutOfX
beq \quit
; Si le bitmat sort de l'axe des ordonnées, on renvoie true. ; Sinon on renvoie false.
jsr IsOutOfY
\quit rts
MoveSprite ; Sauvegarde les registres.
movem.l d1/d2/a0,-(a7)
; Nouvelle abscisse du sprite -> D1.W ; Nouvelle ordonnée du sprite -> D2.W
add.w X(a1),d1
add.w Y(a1),d2
; Adresse du bitmap 1 du sprite -> A0.L
movea.l BITMAP1(a1),a0
; Si les nouvelles coordonnées font sortir le bitmap de l'écran,
; on renvoie false (sans modifier les coordonnées du sprite).
jsr IsOutOfScreen
beq \false
; Sinon, on modifie les coordonées du sprite.
move.w d1,X(a1)
move.w d2,Y(a1)
; Et on renvoie true.
; Sortie qui renvoie true (Z = 1).
\true ori.b #%00000100,ccr
bra \quit
; Sortie qui renvoie false (Z = 0).
\false andi.b #%11111011,ccr
\quit movem.l (a7)+,d1/d2/a0
rts
MoveSpriteKeyboard ; Sauvegarde les registres.
movem.l d1/d2,-(a7)
; Initialise le mouvement relatif à zéro.
clr.w d1
clr.w d2
\up ; Si la touche "haut" est pressée,
; décremente D2.W (déplacement d'un pixel vers le haut).
tst.b UP_KEY
beq \down
sub.w #1,d2
\down ; Si la touche "bas" est pressée,
; incrémente D2.W (déplacement d'un pixel vers le bas).
tst.b DOWN_KEY
beq \right
add.w #1,d2
\right ; Si la touche "droite" est pressée,
; incrémente D1.W (déplacement d'un pixel vers la droite).
tst.b RIGHT_KEY
beq \left
add.w #1,d1
\left ; Si la touche "gauche" est pressée,
; décremente D1.W (déplacement d'un pixel vers la gauche).
tst.b LEFT_KEY
beq \next
sub.w #1,d1
\next ; Déplace le sprite (en fonction de D1.W et de D2.W).
jsr MoveSprite
; Restaure les registres puis sortie.
movem.l (a7)+,d1/d2
rts
GetRectangle ; Sauvegarde les registres.
move.l a0,-(a7)
; Abscisse du point supérieur gauche -> D1.W
move.w X(a0),d1
; Ordonnée du point supérieur gauche -> D2.W
move.w Y(a0),d2
; Adresse du bitmap 1 -> A0.L
movea.l BITMAP1(a0),a0
; Abscisse du point inférieur droit -> D3.W
move.w WIDTH(a0),d3
add.w d1,d3
subq.w #1,d3
; Ordonnée du point inférieur droit -> D4.W
move.w HEIGHT(a0),d4
add.w d2,d4
subq.w #1,d4
; Restaure les registres puis sortie.
movea.l (a7)+,a0
rts
IsSpriteColliding ; Sauvegarde les registres.
movem.l d1-d4/a0,-(a7)
; Si les sprites ne sont pas visibles, on quitte.
; Le BNE saute si Z = 0, on renvoie donc false.
; On ne peut pas effectuer un BNE \false tout de suite,
; car ce dernier passe par le nettoyage de la pile.
cmp.w #SHOW,STATE(a1)
bne \quit
cmp.w #SHOW,STATE(a2)
bne \quit
; Coordonnées du rectangle 1 -> Pile
; D1.W -> (a7) ; x1 = Abscisse du point supérieur gauche
; D2.W -> 2(a7) ; y1 = Ordonnée du point supérieur gauche
; D3.W -> 4(a7) ; X1 = Abscisse du point inférieur droit
; D4.W -> 6(a7) ; Y1 = Ordonnée du point inférieur droit
movea.l a1,a0
jsr GetRectangle
movem.w d1-d4,-(a7)
; Coordonnées du rectangle 2 -> D1-D4
; D1.W = x2 = Abscisse du point supérieur gauche
; D2.W = y2 = Ordonnée du point supérieur gauche
; D3.W = X2 = Abscisse du point inférieur droit
; D4.W = Y2 = Ordonnée du point inférieur droit
movea.l a2,a0
jsr GetRectangle
; Si x2 > X1, on renvoie false.
cmp.w 4(a7),d1
bgt \false
; Si y2 > Y1, on renvoie false.
cmp.w 6(a7),d2
bgt \false
; Si X2 < x1, on renvoie false.
cmp.w (a7),d3
blt \false
; Si Y2 < y1, on renvoie false.
cmp.w 2(a7),d4
blt \false
\true ; Sortie qui renvoie true (Z = 1).
ori.b #%00000100,ccr
bra \cleanStack
\false ; Sortie qui renvoie false (Z = 0).
andi.b #%11111011,ccr
\cleanStack ; Dépile les coordonnées du rectangle 1.
; (L'instruction ADDA ne modifie pas les flags.)
adda.l #8,a7
\quit ; Restaure les registres puis sortie.
movem.l (a7)+,d1-d4/a0
rts
PrintShip ; Sauvegarde les registres.
move.l a1,-(a7)
; Affiche le vaisseau.
lea Ship,a1
jsr PrintSprite
; Restaure les registres puis sortie.
move.l (a7)+,a1
rts
MoveShip ; Sauvegarde les registres.
movem.l d1/d2/a1,-(a7)
; Initialise le mouvement relatif à zéro.
clr.w d1
clr.w d2
\right ; Si la touche "droite" est pressée,
; incrémente D1.W (déplacement vers la droite).
tst.b RIGHT_KEY
beq \left
add.w #SHIP_STEP,d1
\left ; Si la touche "gauche" est pressée,
; décrémente D1.W (déplacement vers la gauche).
tst.b LEFT_KEY
beq \next
sub.w #SHIP_STEP,d1
\next ; Déplace le vaisseau (en fonction de D1.W et de D2.W).
lea Ship,a1
jsr MoveSprite
; Restaure les registres puis sortie.
movem.l (a7)+,d1/d2/a1
rts
PrintShipShot ; Sauvegarde les registres.
move.l a1,-(a7)
; Affiche le tir du vaisseau.
lea ShipShot,a1
jsr PrintSprite
; Restaure les registres puis sortie.
move.l (a7)+,a1
rts
MoveShipShot ; Sauvegarde les registres.
movem.l a1/d1/d2/d3,-(a7)
; Adresse du sprite de tir -> A1.L
lea ShipShot,a1
; Si le tir n'est pas affiché, on ne fait rien.
cmp.w #HIDE,STATE(a1)
beq \quit
; Déplace le tir vers le haut.
; Si le déplacement a eu lieu, on peut quitter.
clr.w d1
move.w #-SHIP_SHOT_STEP,d2
move BonusStepReal,d3
add.w d3,d2
jsr MoveSprite
beq \quit
\outOfScreen ; Sinon, le tir sort de l'écran.
; Il faut alors le camoufler.
move.w #HIDE,STATE(a1)
\quit ; Restaure les registres puis sortie.
movem.l (a7)+,a1/d1/d2/d3
rts
NewShipShot movem.l d1-d3/a0/a1,-(a7)
; Si la touche espace est relâchée, on ne fait rien.
tst.b SPACE_KEY
beq \quit
; Si le tir de vaisseau est déjà présent, on ne fait rien.
lea ShipShot,a0
cmp.w #SHOW,STATE(a0)
beq \quit
; Coordonées du vaisseau -> Coordonées du tir
lea Ship,a1
move.w X(a1),X(a0)
move.w Y(a1),Y(a0)
; Largeur du vaisseau -> D1.W
movea.l BITMAP1(a1),a1
move.w WIDTH(a1),d1
; Hauteur du tir -> D2.W
; Largeur du tir -> D3.W
movea.l BITMAP1(a0),a1
move.w HEIGHT(a1),d2
move.w WIDTH(a1),d3
; Centre le tir horizontalement par rapport au vaisseau.
sub.w d3,d1
lsr.w #1,d1
add.w d1,X(a0)
; Positionne le tir juste au dessus du vaisseau.
sub.w d2,Y(a0)
; Le tir est rendu visible.
move.w #SHOW,STATE(a0)
\quit ; Restaure les registres puis sortie.
movem.l (a7)+,d1-d3/a0/a1
rts
InitInvaderLine ; Sauvegarde les registres.
movem.l d1-d3/d7/a0,-(a7)
; Nombre d'itérations = Nombre d'envahisseurs par ligne
; Nombre d'itérations - 1 (car DBRA) -> D7.W
move.w #INVADER_PER_LINE-1,d7
; Modifie l'abscisse de départ de la ligne
; afin de centrer le sprite sur une largeur de 32 pixels.
; D1.W += (32 - Largeur du sprite) / 2
move.w #32,d3
sub.w WIDTH(a1),d3
lsr.w #1,d3
add.w d3,d1
\loop ; Initialise tous les champs du sprite.
move.w #SHOW,STATE(a0)
move.w d1,X(a0)
move.w d2,Y(a0)
move.l a1,BITMAP1(a0)
move.l a2,BITMAP2(a0)
; Passe à l'envahisseur suivant.
adda.l #SIZE_OF_SPRITE,a0
addi.w #32,d1
dbra d7,\loop
; Restaure les registres puis sortie.
movem.l (a7)+,d1-d3/d7/a0
rts
PrintInvaders ; Sauvegarde les registres.
movem.l d7/a1,-(a7)
; Nombre d'itérations = Nombre d'envahisseurs
; Nombre d'itérations - 1 (car DBRA) -> D7.W
move.w #INVADER_COUNT-1,d7
; Adresse de départ des sprites -> A1.L
lea Invaders,a1
\loop ; Affiche un envahisseur.
jsr PrintSprite
; Passe au prochain envahisseur et reboucle.
adda.l #SIZE_OF_SPRITE,a1
dbra d7,\loop
; Sauvegarde les registres puis sortie.
movem.l (a7)+,d7/a1
rts
InitInvaders ; Sauvegarde les registres.
movem.l d1/d2/a0-a2,-(a7)
; 1re ligne d'envahisseurs.
move.w InvaderX,d1
move.w InvaderY,d2
lea Invaders,a0
lea InvaderC1_Bitmap,a1
lea InvaderC2_Bitmap,a2
jsr InitInvaderLine
; 2e ligne d'envahisseurs.
add.w #32,d2
adda.l #SIZE_OF_SPRITE*INVADER_PER_LINE,a0
lea InvaderB1_Bitmap,a1
lea InvaderB2_Bitmap,a2
jsr InitInvaderLine
; 3e ligne d'envahisseurs.
add.w #32,d2
adda.l #SIZE_OF_SPRITE*INVADER_PER_LINE,a0
jsr InitInvaderLine
; 4e ligne d'envahisseurs.
add.w #32,d2
adda.l #SIZE_OF_SPRITE*INVADER_PER_LINE,a0
lea InvaderA1_Bitmap,a1
lea InvaderA2_Bitmap,a2
jsr InitInvaderLine
; 5e ligne d'envahisseurs.
add.w #32,d2
adda.l #SIZE_OF_SPRITE*INVADER_PER_LINE,a0
jsr InitInvaderLine
; Restaure les registres puis sortie.
movem.l (a7)+,d1/d2/a0-a2
rts
SwapBitmap ; Échange les contenus de BITMAP1 et BITMAP2.
move.l BITMAP1(a1),-(a7)
move.l BITMAP2(a1),BITMAP1(a1)
move.l (a7)+,BITMAP2(a1)
; Sortie du sous-programme.
rts
DestroyInvaders ; Sauvegarde les regitres.
movem.l d7/a1/a2,-(a7)
; Fait pointer A1.L sur les envahisseurs.
; Fait pointer A2.L sur le tir du vaisseau.
lea Invaders,a1
lea ShipShot,a2
; Nombre d'itérations – 1 (car DBRA) -> D7.W
move.w #INVADER_COUNT-1,d7
\loop ; Si le tir n'entre pas en collision
; avec l'envahisseur, on passe au suivant.
jsr IsSpriteColliding
bne \next
\colliding ; S'il y a une collision,
; on efface le tir et l'envahisseur.
; Puis on décrémente le nombre d'envahisseurs.
move.w #HIDE,STATE(a1)
move.w #HIDE,STATE(a2)
subq.w #1,InvaderCount
\next ; Passe à l'envahisseur suivant.
adda.l #SIZE_OF_SPRITE,a1
dbra d7,\loop
\quit ; Restaure les registres.
movem.l (a7)+,d7/a1/a2
rts
SpeedInvaderUp ; Sauvegarde les registres.
movem.l d0/a0/a1,-(a7)
; Initialise le compteur de vitesse.
clr.w InvaderSpeed
; Nombre d'envahisseurs en cours d'affichage -> D0.W
move.w InvaderCount,d0
; Fait pointer A0.L sur le tableau des paliers de vitesse.
lea SpeedLevels,a0
\loop ; Incrémente le compteur de vitesse.
addq.w #1,InvaderSpeed
; Compare le nombre d'envahisseurs à un palier du tableau.
; Si le nombre d'envahisseurs est plus grand,
; on passe au palier suivant.
cmp.w (a0)+,d0
bhi \loop
; Restaure les registres puis sortie.
\quit movem.l (a7)+,d0/a0/a1
rts
GetInvaderStep ; Sauvegarde les registres.
move.l d0,-(a7)
; Nouvelle abscisse globale -> D0.W
move.w InvaderX,d0
add.w InvaderCurrentStep,d0
; Si l'abscisse globale est trop petite,
; les envahisseurs ont atteint le bord gauche.
; Il faut donc changer de direction.
cmpi.w #INVADER_X_MIN,d0
blt \change
; Si l'abscisse globale est trop grande,
; les envahisseurs ont atteint le bord droit.
; Il faut donc changer de direction.
cmpi.w #INVADER_X_MAX,d0
bgt \change
\noChange ; Pas de changement de direction.
; Mouvement relatif -> D1.W et D2.W.
; L'abscisse globale est mise à jour.
move.w InvaderCurrentStep,d1
clr.w d2
move.w d0,InvaderX
bra \quit
\change ; Changement de direction.
; Mouvement relatif -> D1.W et D2.W.
; L'ordonnée globale est mise à jour.
; Le signe du pas est inversé.
clr.w d1
move.w #INVADER_STEP_Y,d2
add.w d2,InvaderY
neg.w InvaderCurrentStep
\quit ; Restaure les registres puis sortie.
move.l (a7)+,d0
rts
MoveAllInvaders ; Sauvegarde les registres.
movem.l d1/d2/a1/d7,-(a7)
; Récupère les déplacements relatifs dans D1.W et D2.W.
; (La position globale est mise à jour.)
jsr GetInvaderStep
; Fait pointer A1.L sur le premier envahisseur.
lea Invaders,a1
; Nombre d'envahisseurs - 1 (car DBRA) -> D7.W
move.w #INVADER_COUNT-1,d7
\loop ; Si l'envahisseur n'est pas affiché, on passe au suivant.
cmp.w #HIDE,STATE(a1)
beq \continue
; Déplace l'envahisseur et permute ses bitmaps.
jsr MoveSprite
jsr SwapBitmap
\continue ; Pointe sur le prochain envahisseur.
adda.l #SIZE_OF_SPRITE,a1
; On reboucle tant qu'il reste des envahisseurs.
dbra d7,\loop
\quit ; Restaure les registres puis sortie.
movem.l (a7)+,d1/d2/a1/d7
rts
MoveInvaders ; Décrémente la variable "skip",
; et ne fait rien si elle n'est pas nulle.
subq.w #1,\skip
bne \quit
; Réinitialise "skip" à sa valeur maximale
move.w InvaderSpeed,\skip
add.w #1,\skip
; Appel de MoveAllInvaders.
jsr MoveAllInvaders
\quit ; Sortie du sous programme.
rts
; Compteur d'affichage des envahisseurs
\skip dc.w 1
InitInvaderShots ; Sauvegarde les registres.
movem.l d7/a0,-(a7)
; Adresse des tirs -> A0.L
lea InvaderShots,a0
; Nombre d'itérations - 1 (car DBRA) -> D7.W
move.w #INVADER_SHOT_MAX-1,d7
\loop ; Initialise l'état et les bitmaps.
move.w #HIDE,STATE(a0)
move.l #InvaderShot1_Bitmap,BITMAP1(a0)
move.l #InvaderShot2_Bitmap,BITMAP2(a0)
; Passe au tir suivant.
adda.l #SIZE_OF_SPRITE,a0
dbra d7,\loop
; Restaure les registres puis sortie.
movem.l (a7)+,d7/a0
rts
GetHiddenShot ; Sauvegarde les registres.
move.l d7,-(a7)
; Adresse des tirs -> A0.L
lea InvaderShots,a0
; Nombre d'itérations - 1 (car DBRA) -> D7.W
move.w #INVADER_SHOT_MAX-1,d7
\loop ; Si le tir n'est pas visible, renvoie true.
; (L'adresse du tir se trouve dans A0.L.)
cmp.w #HIDE,STATE(a0)
beq \true
; Passe au tir suivant.
adda.l #SIZE_OF_SPRITE,a0
dbra d7,\loop
\false ; Renvoie false (pas de tir disponible).
move.l (a7)+,d7
andi.b #%11111011,ccr
rts
\true ; Renvoie true (un tir disponible a été trouvé).
move.l (a7)+,d7
ori.b #%00000100,ccr
rts
ConnectInvaderShot ; Sauvegarde les registres.
movem.l d1/d2/d3/a0/a1,-(a7)
; Si l'envahisseur n'est pas visible, on quitte.
cmpi.w #HIDE,STATE(a1)
beq \quit
; Récupère l'adresse d'un tir disponible.
; Si aucun tir disponible, on ne fait rien.
jsr GetHiddenShot
bne \quit
; Place le tir au même endroit que l'envahisseur.
move.w X(a1),X(a0)
move.w Y(a1),Y(a0)
; Détermine la largeur et la hauteur de l'envahisseur.
movea.l BITMAP1(a1),a1
move.w WIDTH(a1),d1
move.w HEIGHT(a1),d2
; Détermine la largeur du tir.
movea.l BITMAP1(a0),a1
move.w WIDTH(a1),d3
; (Largeur Envahisseur – Largeur Tir) / 2 -> D1.W
sub.w d3,d1
lsr.w #1,d1
; On centre le tir sur les abscisses.
; On descend le tir juste au dessous de l'envahisseur.
add.w d1,X(a0)
add.w d2,Y(a0)
; Le tir est rendu visible.
move.w #SHOW,STATE(a0)
\quit ; Restaure les registres puis sortie.
movem.l (a7)+,d1/d2/d3/a0/a1
rts
Random move.l \old,d0
muls.w #16807,d0
and.l #$7fffffff,d0
move.l d0,\old
lsr.l #4,d0
and.l #$7ff,d0
rts
\old dc.l 425625
NewInvaderShot ; Sauvegarde les registres.
movem.l d0/a1,-(a7)
; Récupère un nombre aléatoire.
jsr Random
; Si ce nombre est supérieur ou égale
; au nombre d'envahisseurs, on ne fait rien.
cmp.w #INVADER_COUNT,d0
bhs \quit
; Détermine l'adresse de l'envahisseur.
mulu.w #SIZE_OF_SPRITE,d0
lea Invaders,a1
adda.l d0,a1
; Connecte un tir à cet envahisseur.
jsr ConnectInvaderShot
\quit ; Restaure les registres puis sortie.
movem.l (a7)+,a1/d0
rts
PrintInvaderShots ; Sauvegarde les registres.
movem.l d7/a1,-(a7)
; Nombre d'itérations = Nombre de tirs d'envahisseurs.
; Nombre d'itérations - 1 (car DBRA) -> D7.W
move.w #INVADER_SHOT_MAX-1,d7
; Adresse des tirs d'envahisseurs -> A1.L
lea InvaderShots,a1
\loop ; Affiche un tir d'envahisseur.
jsr PrintSprite
; Passe au prochain tir et reboucle.
adda.l #SIZE_OF_SPRITE,a1
dbra d7,\loop
; Restaure les registres puis sortie.
movem.l (a7)+,d7/a1
rts
MoveInvaderShots ; Sauvegarde les registres.
movem.l a1/d7/d1/d2,-(a7)
; Nombre d'itérations = Nombre de tirs d'envahisseurs.
; Nombre d'itérations - 1 (car DBRA) -> D7.W
move.w #INVADER_SHOT_MAX-1,d7
; Adresse des tirs d'envahisseurs -> A1.L
lea InvaderShots,a1
\loop ; Si le tir n'est pas affiché, on ne fait rien.
cmp.w #HIDE,STATE(a1)
beq \continue
; Déplace un tir.
clr.w d1
move.w #INVADER_SHOT_STEP,d2
jsr MoveSprite
beq \continue
\outOfScreen ; Le tir sort de l'écran (on le rend invisible).
move.w #HIDE,STATE(a1)
\continue ; Passe au prochain tir et reboucle.
adda.l #SIZE_OF_SPRITE,a1
dbra d7,\loop
; Échange les bitmaps.
jsr SwapInvaderShots
; Restaure les registres puis sortie.
movem.l (a7)+,a1/d7/d1/d2
rts
SwapInvaderShots ; Décrémente la variable \skip,
; et ne fait rien si elle n'est pas nulle.
subq.w #1,\skip
bne \quit
; Réinitialise la variable \skip.
move.w #6,\skip
; Sauvegarde les registres.
movem.l d7/a1,-(a7)
; Nombre d'itérations = Nombre de tirs d'envahisseurs.
; Nombre d'itérations - 1 (car DBRA) -> D7.W
move.w #INVADER_SHOT_MAX-1,d7
; Adresse des tirs d'envahisseurs -> A1.L
lea InvaderShots,a1
\loop ; Échange les bitmaps 1 et 2 pour tous les tirs.
jsr SwapBitmap
adda.l #SIZE_OF_SPRITE,a1
dbra d7,\loop
; Restaure les registres puis sortie.
movem.l (a7)+,d7/a1
\quit rts
; Initialise une variable \skip à 6.
\skip dc.w 6
IsShipHit ; Sauvegarde les registres.
movem.l d7/a1/a2,-(a7)
; Adresse du vaisseau -> A1.L
lea Ship,a1
; Adresse des tirs d'envahisseurs -> A2.L
lea InvaderShots,a2
; Nombre d'itérations = Nombre de tirs d'envahisseurs.
; Nombre d'itérations - 1 (car DBRA) -> D7.W
move.w #INVADER_SHOT_MAX-1,d7
\loop ; Si un tir entre en collision avec le vaisseau,
; on renvoie true.
jsr IsSpriteColliding
beq \true
; Passe au tir suivant.
adda.l #SIZE_OF_SPRITE,a2
dbra d7,\loop
\false ; Renvoie false (aucune collision).
andi.b #%11111011,ccr
bra \quit
\true ; Renvoie true (collision).
ori.b #%00000100,ccr