build.gradle

plugins {
  id 'com.palantir.git-version' version '0.12.3'
  id 'org.checkerframework' version '0.5.11'
}

// Get dependency versions from a centralized location
apply from: 'dependencies.gradle'

// Gets the git commit hash of the latest commit, used for version string
ext.projectVersion = '1.0'
def gitHash = versionDetails().gitHash

allprojects {
  group = 'net.draycia'
  description = 'CarbonChat'
  version = project.property('projectVersion') + '-' + gitHash
}

subprojects {
  apply plugin: 'checkstyle'
  apply plugin: 'java'
  apply plugin: 'java-library'
  apply plugin: 'maven-publish'
  apply plugin: 'org.checkerframework'

  repositories {
    mavenCentral()

    maven { url = 'https://repo.maven.apache.org/maven2' }
    maven { url = 'https://oss.sonatype.org/content/groups/public/' }
    maven { url = 'https://maven.enginehub.org/repo/' }
    maven { url = 'https://papermc.io/repo/repository/maven-public/' }
    maven { url = 'https://repo.extendedclip.com/content/repositories/placeholderapi/' }
    maven { url = 'https://jitpack.io' }
    maven { url = 'https://dl.bintray.com/ichbinjoe/public/' }
    maven { url = 'https://repo.codemc.org/repository/maven-public/' }
    maven { url = 'https://repo.glaremasters.me/repository/public/' }
    maven { url = "https://repo.aikar.co/content/groups/aikar/" }
    maven { url = 'https://repo.minebench.de/' }
  }

  dependencies {
    checkstyle("ca.stellardrift:stylecheck:${vers['stylecheck']}")
  }

  checkstyle {
    def configRoot = new File(rootProject.projectDir, '.checkstyle')
    toolVersion = vers['checkstyle']
    configDirectory = configRoot
    configProperties = [basedir: configRoot.getAbsolutePath()]
  }

  checkerFramework {
    checkers = [
      'org.checkerframework.checker.nullness.NullnessChecker'
    ]
  }

  sourceCompatibility = '1.8'
  targetCompatibility = '1.8'
}