build.gradle

import se.bjurr.gitchangelog.plugin.gradle.GitChangelogTask

buildscript {
    repositories {
        jcenter()
        maven { url = "http://files.minecraftforge.net/maven" }
    }
    dependencies {
        classpath 'net.minecraftforge.gradle:ForgeGradle:2.3-SNAPSHOT'
    }
}

plugins {
  id "com.gradle.build-scan" version "1.9"
  id "com.matthewprenger.cursegradle" version "1.0.9"
  id "se.bjurr.gitchangelog.git-changelog-gradle-plugin" version "1.53"
  id "com.github.johnrengelman.shadow" version "2.0.2"
}

apply plugin: 'net.minecraftforge.gradle.forge'
//Only edit below this line, the above code adds and enables the necessary things for Forge to be setup.


//version = "0.1"
group = "atm.bloodworkxgaming.blooddebug" // http://maven.apache.org/guides/mini/guide-naming-conventions.html
archivesBaseName = "${archivebase}"

sourceCompatibility = targetCompatibility = '1.8' // Need this here so eclipse task generates correctly.
compileJava {
    sourceCompatibility = targetCompatibility = '1.8'
}
apply from: "gradle/scripts/getbuildnumber.gradle"

minecraft {
    version = "1.12.2-14.23.1.2566"
    runDir = "run"
    replace "@MAJOR@", version_major
    replace "@MINOR@", version_minor
    replace "@REVIS@", version_revis
    replace "@BUILD@", project.getBuildNumber()
    
    // the mappings can be changed at any time, and must be in the following format.
    // snapshot_YYYYMMDD   snapshot are built nightly.
    // stable_#            stables are built at the discretion of the MCP team.
    // Use non-default mappings at your own risk. they may not always work.
    // simply re-run your setup task after changing the mappings to update your workspace.
    mappings = "snapshot_20171213"
    // makeObfSourceJar = false // an Srg named sources jar is made by default. uncomment this to disable.
}

apply from: "gradle/scripts/version.gradle"

repositories {
    maven {
        url "https://repo.eclipse.org/content/groups/releases/"
    }
}

dependencies {
    compile group: 'org.eclipse.mylyn.github', name: 'org.eclipse.egit.github.core', version: '4.9.0.201710071750-r'
}

processResources {
    // this will ensure that this task is redone when the versions change.
    inputs.property "version", project.version
    inputs.property "mcversion", project.minecraft.version

    // replace stuff in mcmod.info, nothing else
    from(sourceSets.main.resources.srcDirs) {
        include 'mcmod.info'
                
        // replace version and mcversion
        expand 'version':project.version, 'mcversion':project.minecraft.version
    }
        
    // copy everything else except the mcmod.info
    from(sourceSets.main.resources.srcDirs) {
        exclude 'mcmod.info'
    }
}

task deobfJar(type: Jar) {
     from sourceSets.main.output
     //if project name is BBM-Dev it makes the deobf jar deobf-dev if not its just deobf
     classifier = "deobf"
     //sets where the jars go to.
     mustRunAfter "jar" 
}

shadowJar {
    classifier = ""
    
    dependencies {
        include(dependency {
           it.moduleGroup == 'org.eclipse.mylyn.github'
        })
  }
}

reobf {
    shadowJar { mappingType = "SEARGE" }
}

curseforge{
  if (project.hasProperty("thecursedkey")) {
        apiKey = project.thecursedkey
    }
    else {
    apiKey = ""
    }
  project {
  //AdvancedRocketry
    id = "283672"
    /*relations {
        requiredLibrary 'libvulpes'
    }*/
    changelog = file('changelog.html')
    changelogType = 'html'
    releaseType = "alpha"
    addGameVersion minecraft.version
    mainArtifact(shadowJar) {
      displayName = "BloodDebug ${project.version}-UNSTABLE build " + project.getBuildNumber() +  " for " + minecraft.version
    }
    addArtifact (deobfJar){
         displayName = "BloodDebug ${project.version}-UNSTABLE-deobf build " + project.getBuildNumber() + " for " + minecraft.version
    }
   }
}

task makeChangelog(type: GitChangelogTask) {
    file = new File ("changelog.html")
    untaggedName = "Current release ${project.version}"
    fromCommit = startGitRev
    toRef =  "HEAD"
    gitHubIssuePattern = "nonada123";
    templateContent = """
{{#tags}}
<h1> Highly untested and may break world</h1>
  <h3>{{name}}</h3>
  <ul>
    {{#commits}}
    <li> <a href="https://github.com/BloodWorkXGaming/BloodDebug/commit/{{hash}}" target=_blank> {{{message}}}</a>
</li>
    {{/commits}}
  </ul>
{{/tags}}
"""
}

tasks.build.dependsOn makeChangelog, shadowJar