build.gradle

plugins {
	// https://fabricmc.net/wiki/documentation:fabric_loom
	id 'fabric-loom' version '1.7-SNAPSHOT' apply false
    id "org.jetbrains.gradle.plugin.idea-ext" version "1.1.7"
}

subprojects {
    apply plugin: 'java'

    java.toolchain.languageVersion = JavaLanguageVersion.of(21)
    //java.withSourcesJar()
    //java.withJavadocJar()

    jar {
        manifest {
            attributes([
                'Specification-Title'     : mod_name,
                'Specification-Vendor'    : mod_author,
                'Specification-Version'   : project.jar.archiveVersion,
                'Implementation-Title'    : project.name,
                'Implementation-Version'  : project.jar.archiveVersion,
                'Implementation-Vendor'   : mod_author,
                'Implementation-Timestamp': new Date().format("yyyy-MM-dd'T'HH:mm:ssZ"),
                'Timestamp'               : System.currentTimeMillis(),
                'Built-On-Java'           : "${System.getProperty('java.vm.version')} (${System.getProperty('java.vm.vendor')})",
                'Built-On-Minecraft'      : minecraft_version
            ])
        }
    }

    repositories {
		mavenCentral()
		maven { url = "https://maven.shedaniel.me/" }
		maven { url = "https://maven.terraformersmc.com/releases/" }
		maven { url = "https://maven.fabricmc.net/" }
		// Needed by modmenu
		// https://placeholders.pb4.eu/dev/getting-started/#__tabbed_1_1
		maven {
			url "https://maven.nucleoid.xyz/"
			name "Nucleoid"
		}

		exclusiveContent {
			forRepository {
				maven {
					name = "CurseForge"
					url = "https://cursemaven.com"
				}
			}
			filter {
				includeGroup "curse.maven"
			}
		}

		// https://docs.modrinth.com/docs/tutorials/maven/#advanced-repository-declaration-recommended
		exclusiveContent {
			forRepository {
				maven {
					name = "Modrinth"
					url = "https://api.modrinth.com/maven"
				}
			}
			filter {
				includeGroup "maven.modrinth"
			}
		}
    }

    tasks.withType(JavaCompile).configureEach {
		// ensure that the encoding is set to UTF-8, no matter what the system default is
		// this fixes some edge cases with special characters not displaying correctly
		// see http://yodaconditions.net/blog/fix-for-java-file-encoding-problems-with-gradle.html
		// If Javadoc is generated, this must be specified in that task too.
        it.options.encoding = 'UTF-8'
    }

    tasks.withType(GenerateModuleMetadata).configureEach {
        enabled = false
    }

    tasks.withType(Jar).all {
        duplicatesStrategy 'include'
    }
}