build.gradle

import groovy.json.JsonSlurper
plugins {
	id 'fabric-loom' version '1.7-SNAPSHOT'
	id 'maven-publish'
	id "com.github.johnrengelman.shadow" version "8.1.1"
	id "de.undercouch.download" version "4.1.2"
}

sourceCompatibility = JavaVersion.VERSION_16
targetCompatibility = JavaVersion.VERSION_16

group = project.maven_group

def minecraft_version = "1.19.2"
def minecraft_major_version = minecraft_version.split("\\.")[0] as int // Always return 1, unless mojang goes haywire :P
def minecraft_main_version = minecraft_version.split("\\.")[1] as int
def mc_requirement = "${minecraft_major_version}.${minecraft_main_version}.x"
def minecraft_minor_version = minecraft_version.split("\\.").size() > 2 ? minecraft_version.split("\\.")[2] as int : 0

def yarn_mappings = project.yarn_version
def loader_version = project.loader_version
def fapi_version = project.fabric_version

version = project.mod_version + "+" + minecraft_version
repositories {
	// Add repositories to retrieve artifacts from in here.
	// You should only use this when depending on other mods because
	// Loom adds the essential maven repositories to download Minecraft and libraries from automatically.
	// See https://docs.gradle.org/current/userguide/declaring_repositories.html
	// for more information about repositories.
}

configurations {
	shadow
}

if(!project.file("lib/mtr-fabric.jar").exists()) {
	download {
		src "https://www.minecrafttransitrailway.com/libs/${project.mtr_version}/MTR-fabric-${minecraft_version}-${project.mtr_version}.jar"
		dest "lib/mtr-fabric.jar"
		overwrite true
	}
}

task setupLibrary() {
	doLast {
		delete("lib/mtr-fabric.jar")
		download {
			src "https://www.minecrafttransitrailway.com/libs/${project.mtr_version}/MTR-fabric-${minecraft_version}-${project.mtr_version}.jar"
			dest "lib/mtr-fabric.jar"
			overwrite true
		}
	}
}

task downloadOptimizedMod() {
	doLast {
		def outputPath = "run/mods/"

		download {
			src getModrinthDLURL("fabric", minecraft_version, "lazydfu")
			dest outputPath + "dfu.jar"
			overwrite true
		}
		download {
			src getModrinthDLURL("fabric", minecraft_version, "ferrite-core")
			dest outputPath + "ferrite-core.jar"
			overwrite true
		}
		download {
			src getModrinthDLURL("fabric", minecraft_version, "smoothboot-fabric")
			dest outputPath + "smooth-boot.jar"
			overwrite true
		}
		download {
			src getModrinthDLURL("fabric", minecraft_version, "ksyxis")
			dest outputPath + "ksyxis.jar"
			overwrite true
		}
	}
}

dependencies {
	// To change the versions see the gradle.properties file
	minecraft "com.mojang:minecraft:${minecraft_version}"
	mappings "net.fabricmc:yarn:${yarn_mappings}:v2"
	modImplementation "net.fabricmc:fabric-loader:${loader_version}"

	// Fabric API. This is technically optional, but you probably want it anyway.
	modImplementation "net.fabricmc.fabric-api:fabric-api:${fapi_version}"
	modImplementation files("lib/mtr-fabric.jar")
	implementation "org.eclipse.jetty:jetty-http:${rootProject.jetty_version}"
	implementation "org.eclipse.jetty:jetty-io:${rootProject.jetty_version}"
	implementation "org.eclipse.jetty:jetty-security:${rootProject.jetty_version}"
	implementation "org.eclipse.jetty:jetty-server:${rootProject.jetty_version}"
	implementation "org.eclipse.jetty:jetty-servlet:${rootProject.jetty_version}"
	implementation "org.eclipse.jetty:jetty-util:${rootProject.jetty_version}"
	implementation "org.eclipse.jetty:jetty-util-ajax:${rootProject.jetty_version}"
	implementation "javax.servlet:javax.servlet-api:${rootProject.servlet_api_version}"
	shadow "org.eclipse.jetty:jetty-http:${rootProject.jetty_version}"
	shadow "org.eclipse.jetty:jetty-io:${rootProject.jetty_version}"
	shadow "org.eclipse.jetty:jetty-security:${rootProject.jetty_version}"
	shadow "org.eclipse.jetty:jetty-server:${rootProject.jetty_version}"
	shadow "org.eclipse.jetty:jetty-servlet:${rootProject.jetty_version}"
	shadow "org.eclipse.jetty:jetty-util:${rootProject.jetty_version}"
	shadow "org.eclipse.jetty:jetty-util-ajax:${rootProject.jetty_version}"
	shadow "javax.servlet:javax.servlet-api:${rootProject.servlet_api_version}"

	// PSA: Some older mods, compiled on Loom 0.2.1, might have outdated Maven POMs.
	// You may need to force-disable transitiveness on them.
}

shadowJar {
	configurations = [project.configurations.shadow]
	archiveClassifier.set("dev-shadow")
	relocate "javax.servlet", "mtr.libraries.javax.servlet"
	relocate "org.eclipse", "mtr.libraries.org.eclipse"
}

remapJar {
	input.set shadowJar.archiveFile
	dependsOn shadowJar
}

processResources {
	inputs.property "version", project.version

	filesMatching("fabric.mod.json") {
		expand (
				"version": project.version,
				"mc_version": mc_requirement
		)
	}
}

tasks.withType(JavaCompile).configureEach {
	// ensure that the encoding is set to UTF-8, no matter what the system default is
	// this fixes some edge cases with special characters not displaying correctly
	// see http://yodaconditions.net/blog/fix-for-java-file-encoding-problems-with-gradle.html
	// If Javadoc is generated, this must be specified in that task too.
	it.options.encoding = "UTF-8"

	// Minecraft 1.17 (21w19a) upwards uses Java 16.
	def targetVersion = 17
	if (JavaVersion.current().isJava9Compatible()) {
		it.options.release = targetVersion
	}
}

java {
	// Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
	// if it is present.
	// If you remove this line, sources will not be generated.
	withSourcesJar()
}

jar {
	from("LICENSE") {
		rename { "${it}_${project.archivesBaseName}"}
	}
}

// configure the maven publication
publishing {
	publications {
		mavenJava(MavenPublication) {
			// add all the jars that should be included when publishing to maven
			artifact(remapJar) {
				builtBy remapJar
			}
			artifact(sourcesJar) {
				builtBy remapSourcesJar
			}
		}
	}

	// See https://docs.gradle.org/current/userguide/publishing_maven.html for information on how to set up publishing.
	allprojects {
		repositories {
			maven {
				url = "https://minecraft.guntram.de/maven/"
			}
			maven { url 'https://www.jitpack.io' }
			maven { url 'https://oss.sonatype.org/content/repositories/snapshots' }
		}

		afterEvaluate {
			for (def task in it.tasks) {
				if (!project.file("lib/mtr-fabric.jar").exists()) {
					task.dependsOn rootProject.tasks.setupLibrary
				}
			}
		}
	}
}

static def getModrinthVersion(loader, minecraftVersion, projectId) {
	def versionsArray = new JsonSlurper().parse(("https://api.modrinth.com/v2/project/" + projectId + "/version").toURL())
	for (def versionElement : versionsArray) {
		if (versionElement["loaders"].contains(loader) && versionElement["game_versions"].contains(minecraftVersion)) {
			return versionElement["version_number"]
		}
	}
	return ""
}

static def getModrinthDLURL(loader, minecraftVersion, projectId) {
	def versionsArray = new JsonSlurper().parse(("https://api.modrinth.com/v2/project/" + projectId + "/version").toURL())
	for (def versionElement : versionsArray) {
		if (versionElement["loaders"].contains(loader) && versionElement["version_type"] == "release" && versionElement["game_versions"].contains(minecraftVersion)) {
			return versionElement["files"][0]["url"].toURL()
		}
	}
	return ""
}