build.gradle

plugins {
    id 'fabric-loom' version '1.9-SNAPSHOT'
    id 'maven-publish'
}

version = project.mod_version
group = project.maven_group

sourceSets {
    main {
        resources {
            srcDir "src/generated/resources"
        }
    }
    testmod {
        compileClasspath += main.compileClasspath
        runtimeClasspath += main.runtimeClasspath
        compileClasspath += testmod.compileClasspath
        runtimeClasspath += testmod.runtimeClasspath
    }
}

loom {
    accessWidenerPath = file("src/main/resources/gametestlib.accesswidener")
    runs {
        testmodServer {
            server()
            name = "Testmod Server"
            vmArg "-Dfabric-api.gametest"
            vmArg "-Dfabric-api.gametest.server=true"
            vmArg "-Dfabric-api.gametest.command=true"
            vmArg "-Dgametestlib.keepAlive=false"
            source sourceSets.testmod
            runDir "build/testmod"
        }
        gametest {
            server()
            name "Game Test"
            vmArg "-Dfabric-api.gametest"
            vmArg "-Dfabric-api.gametest.server=true"
            vmArg "-Dfabric-api.gametest.command=true"
            vmArg "-Dgametestlib.keepAlive=true"
            runDir "build/gametest"
        }
    }
}

fabricApi {
    configureDataGeneration() {
        outputDirectory = file("src/generated/resources")
        client = true
    }
}

repositories {
    allprojects {
        repositories {
            maven {
                name 'JitPack'
                url 'https://jitpack.io'
            }
        }
    }
    mavenCentral()
}

dependencies {
    // To change the versions see the gradle.properties file
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    mappings loom.officialMojangMappings()
    modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"

    modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"

    // Lombok
    compileOnly(annotationProcessor("org.projectlombok:lombok:${project.lombok_version}"))

    testmodImplementation sourceSets.main.output
}

processResources {
    inputs.property "version", project.version
    inputs.property "minecraft_version", project.minecraft_version
    inputs.property "loader_version", project.loader_version
    filteringCharset "UTF-8"

    filesMatching("fabric.mod.json") {
        expand "version": project.version,
                "minecraft_version": project.minecraft_version,
                "loader_version": project.loader_version
    }
}

def targetJavaVersion = 17
tasks.withType(JavaCompile).configureEach {
    // ensure that the encoding is set to UTF-8, no matter what the system default is
    // this fixes some edge cases with special characters not displaying correctly
    // see http://yodaconditions.net/blog/fix-for-java-file-encoding-problems-with-gradle.html
    // If Javadoc is generated, this must be specified in that task too.
    it.options.encoding = "UTF-8"
    if (targetJavaVersion >= 10 || JavaVersion.current().isJava10Compatible()) {
        it.options.release = targetJavaVersion
    }
}

java {
    def javaVersion = JavaVersion.toVersion(targetJavaVersion)
    if (JavaVersion.current() < javaVersion) {
        toolchain.languageVersion = JavaLanguageVersion.of(targetJavaVersion)
    }
    archivesBaseName = project.archives_base_name
    // Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
    // if it is present.
    // If you remove this line, sources will not be generated.
    withSourcesJar()
}

jar {
    from("LICENSE") {
        rename { "${it}_${project.archivesBaseName}"}
    }
}

// configure the maven publication
publishing {
    publications {
        main (MavenPublication) {
            artifactId "gametestlib"
            artifact(remapJar)
        }
    }
}