build.gradle

plugins {
    id 'fabric-loom' version '1.2-SNAPSHOT'
    id 'io.github.juuxel.loom-vineflower' version '1.11.0'
}

repositories {
    maven { url = "https://oss.sonatype.org/content/repositories/snapshots" }
    maven { url = "https://maven.isxander.dev/releases" }
    maven { url "https://maven.terraformersmc.com/releases/"}
}

sourceCompatibility = JavaVersion.VERSION_17
targetCompatibility = JavaVersion.VERSION_17

archivesBaseName = project.archives_base_name
version = project.mod_version + (project.version_suffix ? ('_' + project.version_suffix) : '') + '+' + project.minecraft_version
group = project.maven_group

dependencies {
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
    modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"
    modImplementation fabricApi.module('fabric-api-base', project.fabric_version)
    modImplementation fabricApi.module('fabric-screen-api-v1', project.fabric_version)
    modImplementation fabricApi.module('fabric-lifecycle-events-v1', project.fabric_version)
    modImplementation fabricApi.module('fabric-entity-events-v1', project.fabric_version)
    modImplementation fabricApi.module('fabric-command-api-v2', project.fabric_version)

    modImplementation "dev.isxander.yacl:yet-another-config-lib-fabric:${project.yacl_version}"
    modImplementation("com.terraformersmc:modmenu:${project.mod_menu_version}"){
        exclude group: "net.fabricmc.fabric-api"
    }
}

loom {
    accessWidenerPath = file("src/main/resources/sleepwarp.accesswidener")
}

processResources {
    inputs.property "version", project.version

    filesMatching("fabric.mod.json") {
        expand "version": project.version
    }
}

tasks.withType(JavaCompile).configureEach {
    it.options.release = 17
}

java {
    withSourcesJar()
}

jar {
    from("LICENSE") {
        rename { "${it}_${project.archivesBaseName}" }
    }
}