build.gradle

// Top-level build file where you can add configuration options common to all sub-projects/modules.

buildscript {
    ext {
        mavenPublishUrl = 'https://mvnrepo.jiagouyun.com/repository'
        getDefaultProperties = this.&getDefaultProperties
    }

    Properties properties = new Properties()
    def localPropertiesPath = 'local.properties'
    if (project.rootProject.file(localPropertiesPath).exists()) {
        properties.load(project.rootProject.file(localPropertiesPath).newDataInputStream())
    }

    def appIdString = properties.getProperty("RUM_APP_ID")
    def datakitRUMUrl = properties.getProperty("DATAKIT_URL")
    def datawayRUMUrl = properties.getProperty("DATAWAY_URL")
    def clientToken = properties.getProperty("CLIENT_TOKEN")
    def datawayToken = properties.getProperty("DATAWAY_TOKEN")
    def trackId = properties.getProperty("TRACK_ID")
    def traceUrl = properties.getProperty("TRACE_URL")

    ext.ft_env = [
            'rumAppid'      : appIdString,
            'datakitRUMUrl' : datakitRUMUrl,
            'datawayRUMUrl' : datawayRUMUrl,
            'clientToken'   : clientToken,
            'datawayToken'  : datawayToken,
            'trackId'       : trackId,
            'traceUrl'      : traceUrl,
            'prodTestEnv'   : 'gray',
            'prodPublishEnv': 'prod'
    ]
    repositories {
        google()
//        jcenter()
//        mavenLocal()
        maven {
            url "${mavenPublishUrl}/maven-releases"
        }
        maven {
            url "https://plugins.gradle.org/m2/"
        }

        flatDir dirs: "ft-plugin/build/libs"

    }
    dependencies {
        classpath 'com.android.tools.build:gradle:7.4.2'
        classpath 'com.cloudcare.ft.mobile.sdk.tracker.plugin:ft-plugin:1.3.3'
//        classpath 'com.guardsquare:proguard-gradle:7.1.0'
//        classpath files('ft-plugin/build/libs/ft-plugin-1.3.1-alpha02.jar')

        classpath "com.github.gmazzo:gradle-buildconfig-plugin:3.1.0"
        classpath 'org.jetbrains.kotlin:kotlin-gradle-plugin:1.8.0'
        // NOTE: Do not place your application dependencies here; they belong
        // in the individual module build.gradle files
    }
}

allprojects {
    repositories {
        google()
        mavenCentral()
        mavenLocal()
        maven {
            url "${mavenPublishUrl}/maven-releases"
        }
        //
//        flatDir {
//            dirs 'libs'
//        }
    }
    configurations.all {
        resolutionStrategy {
            force("org.objenesis:objenesis:2.6")
        }
    }
}


def getDefaultProperties() {
    def userName = System.getProperty("LDAP_ACCOUNT")
    def password = System.getProperty("LDAP_PWD")

    Properties properties = new Properties()
    if (userName != null && password != null) {
        properties.setProperty("LDAP_ACCOUNT", userName)
        properties.setProperty("LDAP_PWD", password)
    } else {
        def file = project.rootProject.file('local.properties')
        if (file.exists()) {
            properties.load(file.newDataInputStream())
        }
    }
    return properties
}

task clean(type: Delete) {
    delete rootProject.buildDir
}