-
Notifications
You must be signed in to change notification settings - Fork 7
/
ChatFMX.Frame.Chat.pas
2021 lines (1858 loc) · 57 KB
/
ChatFMX.Frame.Chat.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
unit ChatFMX.Frame.Chat;
interface
uses
System.SysUtils, System.Types, System.UITypes, System.Classes, System.Variants,
FMX.Types, FMX.Graphics, FMX.Controls, FMX.Forms, FMX.Dialogs, FMX.StdCtrls,
FMX.Layouts, FMX.ListBox, FMX.Objects, FMX.Controls.Presentation,
ChatFMX.DM.Res, FMX.Edit, VK.Types, VK.API, FMX.ImgList, VK.Entity.Message,
VK.Entity.Conversation, System.Messaging, HGM.FMX.SmoothScroll, FMX.Ani,
FMX.Memo.Types, FMX.ScrollBox, FMX.Memo, ChatFMX.Frame.Loading,
VK.Entity.Common.ExtendedList, ChatFMX.Frame.Message, ChatFMX.Classes,
ChatFMX.Frame.Attachment.PinnedMessage, System.Generics.Collections,
VK.Entity.Keyboard, ChatFMX.Frame.Keyboard, FMX.Effects, VK.UserEvents,
ChatFMX.Frame.Message.Base, VK.Entity.Profile;
type
TFrameChat = class;
TUser = class
Id: Int64;
FirstName: string;
LastName: string;
FirstNameAcc: string;
LastNameAcc: string;
FirstNameGen: string;
LastNameGen: string;
Photo50: string;
Verified: Boolean;
Sex: TVkSex;
end;
TUsers = class(TObjectList<TUser>)
function Update(const Id: Int64): TUser; overload;
function Update(const Data: TVkProfile): TUser; overload;
function Contains(const Id: Int64): Boolean;
function Get(const Id: Int64): TUser;
end;
TLayout = class(FMX.Layouts.TLayout)
end;
THeadMode = (hmNormal, hmSelection);
TButton = class(FMX.StdCtrls.TButton)
protected
procedure SetText(const Value: string); override;
end;
TForEachMessage = reference to procedure(Item: TFrameMessage; var Break: Boolean);
TOnPreviewChatChanged = procedure(Chat: TFrameChat) of object;
TFrameMessages = TArray<TFrameMessage>;
TFrameMessagesHelper = record helper for TFrameMessages
function ToIds: TArrayOfInteger;
end;
TMessageFrame = record
Frame: TFrameMessageBase;
Id: Extended;
class function Create(Id: Extended; Frame: TFrameMessageBase): TMessageFrame; static;
end;
TMessages = class(TList<TMessageFrame>)
procedure Sort;
end;
TFrameChat = class(TFrame)
LayoutClient: TLayout;
RectangleHead: TRectangle;
RectangleFooter: TRectangle;
RectangleChatBG: TRectangle;
LayoutHead: TLayout;
LabelTitle: TLabel;
LabelInfo: TLabel;
CircleImage: TCircle;
ButtonActions: TButton;
ButtonSearch: TButton;
ButtonCall: TButton;
ButtonAttchment: TButton;
LayoutMobileIndicate: TLayout;
LayoutMuteIndicate: TLayout;
ImageMobileOnline: TImage;
Path1: TPath;
VertScrollBoxMessages: TVertScrollBox;
LayoutMessageList: TLayout;
LayoutHeadNormal: TLayout;
LayoutSelection: TLayout;
ButtonSelAsSPAM: TButton;
ButtonSelFavorite: TButton;
ButtonSelDelete: TButton;
LabelSelCount: TLabel;
Layout5: TLayout;
Path2: TPath;
LayoutUnsel: TLayout;
ButtonSelAnswerReply: TButton;
ButtonSelReply: TButton;
LayoutSend: TLayout;
ButtonAudio: TButton;
ButtonSend: TButton;
LayoutSendControls: TLayout;
Layout3: TLayout;
RectangleMessage: TRectangle;
LayoutMessgeActions: TLayout;
MemoText: TMemo;
LayoutFooterBottom: TLayout;
LayoutFooterMessage: TLayout;
LabelTextHint: TLabel;
LayoutActivity: TLayout;
FrameLoadingActivity: TFrameLoading;
LabelActivity: TLabel;
LayoutActivityContent: TLayout;
LayoutLoading: TLayout;
FrameLoadingMesages: TFrameLoading;
LayoutVerified: TLayout;
RectangleAddToFriends: TRectangle;
LayoutAddToFriends: TLayout;
LabelAddFriendHint: TLabel;
ButtonAddToFriends: TButton;
LayoutCloseAddToFriends: TLayout;
PathCloseAddToFriends: TPath;
RectangleFooterBlock: TRectangle;
LayoutBlockInfo: TLayout;
ImageWarning: TImage;
LabelWarningText: TLabel;
ButtonBack: TButton;
LayoutBottomHints: TLayout;
CircleToDown: TCircle;
Path3: TPath;
ColorAnimationToDown: TColorAnimation;
RectanglePinnedMessage: TRectangle;
LayoutPinnedMessageClient: TLayout;
LayoutUnpinMessage: TLayout;
PathUnpinMessage: TPath;
Layout6: TLayout;
Path5: TPath;
ButtonSelPin: TButton;
LayoutFooterTop: TLayout;
LayoutReloading: TLayout;
FrameLoading1: TFrameLoading;
PathVer: TPath;
RectangleDesign: TRectangle;
LayoutFooterKeyboard: TLayout;
LayoutMessageActionsAlign: TLayout;
ButtonAttachPhotoVideo: TButton;
ButtonAttachSmile: TButton;
CheckBoxKeyboard: TCheckBox;
LayoutActualDate: TLayout;
RoundRectActualDate: TRoundRect;
LabelActualDate: TLabel;
ShadowEffect1: TShadowEffect;
TimerActivity: TTimer;
TimerVisibility: TTimer;
RectangleBG: TRectangle;
LayoutActions: TLayout;
LayoutSearch: TLayout;
EditSearch: TEdit;
ButtonSearchDate: TButton;
ButtonSearchRun: TButton;
ButtonSearchCancel: TButton;
procedure VertScrollBoxMessagesResize(Sender: TObject);
procedure LayoutMessageListResize(Sender: TObject);
procedure LayoutUnselClick(Sender: TObject);
procedure MemoTextChangeTracking(Sender: TObject);
procedure LayoutFooterBottomResize(Sender: TObject);
procedure VertScrollBoxMessagesViewportPositionChange(Sender: TObject; const OldViewportPosition, NewViewportPosition: TPointF; const ContentSizeChanged: Boolean);
procedure ButtonBackClick(Sender: TObject);
procedure CircleToDownClick(Sender: TObject);
procedure ButtonSendClick(Sender: TObject);
procedure MemoTextKeyDown(Sender: TObject; var Key: Word; var KeyChar: Char; Shift: TShiftState);
procedure ButtonSelPinClick(Sender: TObject);
procedure ButtonSelFavoriteClick(Sender: TObject);
procedure ButtonSelDeleteClick(Sender: TObject);
procedure ButtonSelAsSPAMClick(Sender: TObject);
procedure CheckBoxKeyboardChange(Sender: TObject);
procedure LabelActualDateResize(Sender: TObject);
procedure TimerActivityTimer(Sender: TObject);
procedure LayoutCloseAddToFriendsClick(Sender: TObject);
procedure ButtonAddToFriendsClick(Sender: TObject);
procedure LayoutUnpinMessageClick(Sender: TObject);
procedure TimerVisibilityTimer(Sender: TObject);
procedure LabelInfoMouseEnter(Sender: TObject);
procedure LabelInfoMouseLeave(Sender: TObject);
procedure ButtonSearchClick(Sender: TObject);
procedure ButtonSearchCancelClick(Sender: TObject);
private
FConversationId: TVkPeerId;
FVK: TCustomVK;
FOffset: Int64;
FOffsetEnd: Boolean;
FLoading: Boolean;
FIsMuted: Boolean;
FTitle: string;
FImageUrl: string;
FImageFile: string;
FChatType: TChatType;
FMemberCount: Integer;
FCanCall: Boolean;
FIsMobile: Boolean;
FIsOnline: Boolean;
FLastSeen: TDateTime;
FIsSelfChat: Boolean;
FHeadMode: THeadMode;
FChatScroll: TSmoothScroll;
FVerified: Boolean;
FIsNeedAddToFriends: Boolean;
FUserAccFirstName: string;
FIsCanWrtie: Boolean;
FNotAllowedReason: TVkConversationDisableReason;
FOnBack: TNotifyEvent;
FIsUser: Boolean;
FOutRead: Int64;
FHavePinned: Boolean;
FPinnedMessage: TFrameAttachmentPinnedMessage;
FPinnedMessageId: Int64;
FIsCanPinMessage: Boolean;
FUserSex: TVkSex;
FMessages: TMessages;
FCurrentKeyboard: TFrameKeyboard;
FIsSending: Boolean;
FWasHiddenKeyboard: Boolean;
FMembers: TUsers;
FLastChangeText: TDateTime;
procedure SetConversationId(const Value: TVkPeerId);
procedure ReloadAsync;
procedure SetVK(const Value: TCustomVK);
procedure EndOfChat;
procedure LoadConversationAsync;
procedure LoadConversationInfoAsync;
procedure CreateMessageItem(const Item: TVkMessage; AData: TVkEntityExtendedList<TVkMessage>; IsNew: Boolean);
procedure UpdateInfo(Info: TVkConversation; Data: IExtended);
procedure SetIsMuted(const Value: Boolean);
procedure SetTitle(const Value: string);
procedure FOnReadyImage(const Sender: TObject; const M: TMessage);
procedure FOnNewMessage(const Sender: TObject; const M: TMessage);
procedure FOnEditMessage(const Sender: TObject; const M: TMessage);
procedure FOnDeleteMessage(const Sender: TObject; const M: TMessage);
procedure FOnChangeMessage(const Sender: TObject; const M: TMessage);
procedure FOnReadMessage(const Sender: TObject; const M: TMessage);
procedure SetChatType(const Value: TChatType);
procedure SetMemberCount(const Value: Integer);
procedure UpdateInfoText;
procedure SetCanCall(const Value: Boolean);
procedure SetImageUrl(const Value: string);
procedure SetIsMobile(const Value: Boolean);
procedure SetIsOnline(const Value: Boolean);
procedure SetLastSeen(const Value: TDateTime);
procedure SetIsSelfChat(const Value: Boolean);
procedure FOnMessageSelected(Sender: TObject);
function SelectedCount: Integer;
procedure UpdateSelection(const Count: Integer);
procedure SetHeadMode(const Value: THeadMode);
procedure UpdateFooterSize;
function GetMessageDate(Frame: TFrameMessageBase): TDateTime;
procedure InsertDateLastMessage(LastDate: TDateTime; MessageId: Extended);
procedure SetVerified(const Value: Boolean);
procedure SetIsNeedAddToFriends(const Value: Boolean);
procedure SetIsCanWrtie(const Value: Boolean);
procedure SetOnBack(const Value: TNotifyEvent);
procedure AppendHistory(Items: TVkMessageHistory; const Data: IExtended);
procedure CalcDisappear(const All: Boolean);
procedure ShowHints;
procedure HideHints;
procedure ErrorLoading;
procedure AppendMessage(Items: TVkMessageHistory; Data: IExtended);
function GetChatInfo: TChatInfo;
procedure SetIsUser(const Value: Boolean);
procedure SetOutRead(const Value: Int64);
procedure SendMessage;
procedure SetHavePinned(const Value: Boolean);
procedure CreatePinnedMessage(Item: TVkMessage; Data: IExtended);
function GetSelected: TArray<TFrameMessage>;
procedure UpdatePinMessage(const MessageId: Int64; IsLocalId: Boolean);
procedure DoAction(Action: TVkMessageAction);
procedure SetPinnedMessageId(const Value: Int64);
procedure SetIsCanPinMessage(const Value: Boolean);
procedure UpdatePinButton(const Count: Integer; const Selected: TArray<TFrameMessage>);
procedure UpdateFavoriteButton(const Count: Integer; const Selected: TArray<TFrameMessage>);
procedure UpdateReplyAnswerButton(const Count: Integer);
procedure ForEach(Proc: TForEachMessage);
procedure SetUserSex(const Value: TVkSex);
procedure AddMessageFrame(Frame: TFrameMessageBase);
procedure UpdateMessageList;
procedure CreateKeyBoard(Keyboard: TVkKeyboard);
procedure SetIsSending(const Value: Boolean);
procedure ShowSearch(const Value: Boolean);
procedure FOnReplyMessageClick(Sender: TObject);
procedure ScrollTo(Frame: TFrameMessage);
procedure UpdateActualDate;
procedure FOnUsersTyping(const Sender: TObject; const M: TMessage);
procedure ActivityTyping(Data: TChatTypingData);
function FindMessage(const MessageId: Int64; var Frame: TFrameMessageBase): Boolean;
function ContainsMessage(const MessageId: Int64): Boolean;
procedure UpdateMessage(const MessageId: Int64);
procedure UpdateMessageData(const MessageId: Int64; ItemData: TVkMessage; ExtData: TVkEntityExtendedList<TVkMessage>);
procedure FOnPinnedMessageClick(Sender: TObject);
procedure UpdateUsers(Data: IExtended);
procedure SendTyping;
property HeadMode: THeadMode read FHeadMode write SetHeadMode;
protected
function GetMessageId(Frame: TFrameMessageBase): Int64;
procedure SetVisible(const Value: Boolean); override;
function GetLastMessage: TFrameMessageBase;
function GetFirstMessage: TFrameMessageBase;
public
constructor Create(AOwner: TComponent; AVK: TCustomVK); reintroduce;
destructor Destroy; override;
property ConversationId: TVkPeerId read FConversationId write SetConversationId;
property VK: TCustomVK read FVK write SetVK;
procedure Load(const PeerId: TVkPeerId);
property IsMuted: Boolean read FIsMuted write SetIsMuted;
property Title: string read FTitle write SetTitle;
property ChatType: TChatType read FChatType write SetChatType;
property MemberCount: Integer read FMemberCount write SetMemberCount;
property CanCall: Boolean read FCanCall write SetCanCall;
property ImageUrl: string read FImageUrl write SetImageUrl;
property LastSeen: TDateTime read FLastSeen write SetLastSeen;
property IsOnline: Boolean read FIsOnline write SetIsOnline;
property IsMobile: Boolean read FIsMobile write SetIsMobile;
property IsSelfChat: Boolean read FIsSelfChat write SetIsSelfChat;
procedure UnselectAll;
property Verified: Boolean read FVerified write SetVerified;
property IsNeedAddToFriends: Boolean read FIsNeedAddToFriends write SetIsNeedAddToFriends;
property IsCanWrtie: Boolean read FIsCanWrtie write SetIsCanWrtie;
property IsUser: Boolean read FIsUser write SetIsUser;
property OnBack: TNotifyEvent read FOnBack write SetOnBack;
property ChatInfo: TChatInfo read GetChatInfo;
property OutRead: Int64 read FOutRead write SetOutRead;
property HavePinned: Boolean read FHavePinned write SetHavePinned;
property PinnedMessageId: Int64 read FPinnedMessageId write SetPinnedMessageId;
property IsCanPinMessage: Boolean read FIsCanPinMessage write SetIsCanPinMessage;
property UserSex: TVkSex read FUserSex write SetUserSex;
property CurrentKeyboard: TFrameKeyboard read FCurrentKeyboard;
property IsSending: Boolean read FIsSending write SetIsSending;
end;
const
ChatCountQuery = 40;
ImageIndexFavoriteOn = 22;
ImageIndexFavoriteOff = 9;
ImageIndexPinOn = 21;
ImageIndexPinOff = 20;
implementation
uses
System.Threading, System.DateUtils, VK.Messages, System.Generics.Defaults,
VK.Entity.Group, ChatFMX.PreviewManager, System.Math, ChatFMX.Utils,
HGM.FMX.Image, ChatFMX.Frame.MessageAction, ChatFMX.Frame.MessageDate,
ChatFMX.Events, ChatFMX.Frame.Attachment.ReplyMessage;
{$R *.fmx}
{ TFrameChat }
function TFrameChat.GetSelected: TArray<TFrameMessage>;
begin
var Cnt := 0;
SetLength(Result, LayoutMessageList.ControlsCount);
for var Control in LayoutMessageList.Controls do
if (Control is TFrameMessage) and (Control as TFrameMessage).IsSelected then
begin
Result[Cnt] := Control as TFrameMessage;
Inc(Cnt);
end;
SetLength(Result, Cnt);
end;
procedure TFrameChat.ButtonSearchCancelClick(Sender: TObject);
begin
ShowSearch(False);
end;
procedure TFrameChat.ButtonAddToFriendsClick(Sender: TObject);
begin
//
end;
procedure TFrameChat.ButtonBackClick(Sender: TObject);
begin
if Assigned(FOnBack) then
FOnBack(Self);
end;
procedure TFrameChat.UpdatePinMessage(const MessageId: Int64; IsLocalId: Boolean);
begin
TTask.Run(
procedure
var
Items: TVkMessages;
Params: TVkParamsMessageGet;
ParamsLocal: TVkParamsMessageGetByConvMesId;
begin
Items := nil;
if IsLocalId then
begin
ParamsLocal.PeerId(ConversationId);
ParamsLocal.ConversationMessageId(MessageId);
ParamsLocal.Extended;
VK.Messages.GetByConversationMessageId(Items, ParamsLocal);
end
else
begin
Params.MessageId(MessageId);
Params.Extended;
VK.Messages.GetById(Items, Params);
end;
if Assigned(Items) then
begin
var Extended: IExtended := Items;
if Length(Items.Items) > 0 then
Event.Queue(Self,
procedure
begin
CreatePinnedMessage(Items.Items[0], Extended);
end);
end;
end);
end;
procedure TFrameChat.ButtonSearchClick(Sender: TObject);
begin
ShowSearch(True);
end;
procedure TFrameChat.ButtonSelAsSPAMClick(Sender: TObject);
begin
if SelectedCount <= 0 then
Exit;
var Ids := GetSelected.ToIds;
TTask.Run(
procedure
begin
var MessageIds: TVkMessageDelete;
if VK.Messages.Delete(MessageIds, Ids, 0, False, True) then
MessageIds.Free;
end);
UnselectAll;
end;
procedure TFrameChat.ButtonSelDeleteClick(Sender: TObject);
begin
if SelectedCount <= 0 then
Exit;
var Ids := GetSelected.ToIds;
TTask.Run(
procedure
begin
var MessageIds: TVkMessageDelete;
if VK.Messages.Delete(MessageIds, Ids, 0, False, False) then
MessageIds.Free;
end);
UnselectAll;
end;
procedure TFrameChat.ButtonSelFavoriteClick(Sender: TObject);
begin
if SelectedCount <= 0 then
Exit;
var Ids := GetSelected.ToIds;
case ButtonSelFavorite.ImageIndex of
ImageIndexFavoriteOff:
TTask.Run(
procedure
begin
var MessageIds: TIdList;
VK.Messages.MarkAsImportant(MessageIds, Ids, True);
end);
ImageIndexFavoriteOn:
TTask.Run(
procedure
begin
var MessageIds: TIdList;
VK.Messages.MarkAsImportant(MessageIds, Ids, False);
end);
end;
UnselectAll;
end;
procedure TFrameChat.ButtonSelPinClick(Sender: TObject);
begin
if SelectedCount <> 1 then
Exit;
var Frame := GetSelected[0];
case ButtonSelPin.ImageIndex of
ImageIndexPinOff:
TTask.Run(
procedure
begin
VK.Messages.Pin(ConversationId, Frame.MessageId);
end);
ImageIndexPinOn:
TTask.Run(
procedure
begin
VK.Messages.Unpin(ConversationId);
end);
end;
UnselectAll;
end;
procedure TFrameChat.ButtonSendClick(Sender: TObject);
begin
SendMessage;
end;
procedure TFrameChat.SendMessage;
begin
if IsSending then
Exit;
var NewMessage := VK.Messages.New;
NewMessage.PeerId(ConversationId);
if not MemoText.Text.IsEmpty then
begin
NewMessage.Message(MemoText.Text);
MemoText.Text := '';
MemoText.SetFocus;
end;
IsSending := True;
TTask.Run(
procedure
begin
NewMessage.Send;
Event.Queue(Self,
procedure
begin
IsSending := False;
end);
end);
end;
constructor TFrameChat.Create(AOwner: TComponent; AVK: TCustomVK);
begin
FMessages := TMessages.Create;
inherited Create(AOwner);
FLastChangeText := 0;
FMembers := TUsers.Create;
FWasHiddenKeyboard := False;
FCurrentKeyboard := nil;
LayoutActualDate.Visible := False;
RectangleDesign.Visible := False;
LayoutActivityContent.Visible := False;
FPinnedMessage := nil;
FPinnedMessageId := -1;
FChatScroll := TSmoothScroll.CreateFor(VertScrollBoxMessages);
{$IFDEF ADAPTIVE}
//VertScrollBoxMessages.ShowScrollBars := False;
//RectangleChatBG.Margins.Right := 0;
RectangleBG.Sides := [];
RectangleHead.Sides := [TSide.Bottom];
RectangleHead.Corners := [];
RectangleFooterBlock.Sides := [TSide.Top];
RectangleFooterBlock.Corners := [];
RectangleFooter.Sides := [TSide.Top];
RectangleFooter.Corners := [];
{$ELSE}
FChatScroll.ScrollDelta := 2;
FChatScroll.EnableSmoothScroll := False;
{$ENDIF}
ButtonBack.Visible := False;
FLoading := True;
FVK := AVK;
Name := '';
HeadMode := hmNormal;
MemoText.Text := '';
MemoText.PrepareForPaint;
IsNeedAddToFriends := False;
IsCanWrtie := True;
HavePinned := False;
LayoutMessageList.Left := 0;
LayoutMessageList.Opacity := 0;
ShowSearch(False);
UpdateFooterSize;
Event.QueueSubscribe(Self);
end;
procedure TFrameChat.EndOfChat;
begin
if FLoading then
Exit;
if not FOffsetEnd then
begin
FLoading := True;
Inc(FOffset, ChatCountQuery);
TTask.Run(LoadConversationAsync);
end;
FrameLoadingMesages.Visible := not FOffsetEnd;
end;
procedure TFrameChat.LabelActualDateResize(Sender: TObject);
begin
RoundRectActualDate.Width := LabelActualDate.Width + 30;
end;
procedure TFrameChat.LabelInfoMouseEnter(Sender: TObject);
var
Control: TLabel absolute Sender;
begin
Control.TextSettings.Font.Style := Control.TextSettings.Font.Style + [TFontStyle.fsUnderline];
end;
procedure TFrameChat.LabelInfoMouseLeave(Sender: TObject);
var
Control: TLabel absolute Sender;
begin
Control.TextSettings.Font.Style := Control.TextSettings.Font.Style - [TFontStyle.fsUnderline];
end;
procedure TFrameChat.LayoutCloseAddToFriendsClick(Sender: TObject);
begin
IsNeedAddToFriends := False;
end;
procedure TFrameChat.LayoutFooterBottomResize(Sender: TObject);
begin
UpdateFooterSize;
end;
procedure TFrameChat.LayoutMessageListResize(Sender: TObject);
begin
UpdateMessageList;
var Sz: Single := 10;
for var Control in LayoutMessageList.Controls do
if Control.IsVisible then
Sz := Sz + Control.Height + Control.Margins.Top + Control.Margins.Bottom;
if LayoutMessageList.Height <> Sz then
LayoutMessageList.Height := Sz;
FrameLoadingMesages.Visible :=
(LayoutMessageList.Height + FrameLoadingMesages.Height > VertScrollBoxMessages.Height) and
(not FOffsetEnd);
end;
procedure TFrameChat.LayoutUnpinMessageClick(Sender: TObject);
begin
TTask.Run(
procedure
begin
try
VK.Messages.Unpin(ConversationId);
except
Event.Queue(Self,
procedure
begin
ShowMessage('Не удалось открепить сообщение');
end);
end;
end);
end;
procedure TFrameChat.LayoutUnselClick(Sender: TObject);
begin
UnselectAll;
end;
function TFrameChat.SelectedCount: Integer;
begin
Result := 0;
for var Control in LayoutMessageList.Controls do
if Control is TFrameMessage then
begin
if (Control as TFrameMessage).IsSelected then
Inc(Result);
end;
end;
procedure TFrameChat.UnselectAll;
begin
for var Control in LayoutMessageList.Controls do
if Control is TFrameMessage then
begin
(Control as TFrameMessage).BeginUpdate;
(Control as TFrameMessage).IsSelected := False;
(Control as TFrameMessage).EndUpdate;
end;
UpdateSelection(0);
end;
procedure TFrameChat.UpdatePinButton(const Count: Integer; const Selected: TArray<TFrameMessage>);
begin
ButtonSelPin.Visible := FIsCanPinMessage and (Count = 1);
if ButtonSelPin.Visible then
begin
if Selected[0].MessageId = PinnedMessageId then
begin
ButtonSelPin.ImageIndex := ImageIndexPinOn;
ButtonSelPin.Hint := 'Открепить сообщение';
end
else
begin
ButtonSelPin.ImageIndex := ImageIndexPinOff;
ButtonSelPin.Hint := 'Закрепить сообщение';
end;
ButtonSelPin.Align := TAlignLayout.Left;
ButtonSelPin.Align := TAlignLayout.Right;
end;
end;
procedure TFrameChat.UpdateFavoriteButton(const Count: Integer; const Selected: TArray<TFrameMessage>);
begin
var AllFavorite := True;
for var Item in Selected do
if not Item.IsImportant then
begin
AllFavorite := False;
Break;
end;
if AllFavorite then
begin
ButtonSelFavorite.ImageIndex := ImageIndexFavoriteOn;
ButtonSelFavorite.Hint := 'Снять отметку';
end
else
begin
ButtonSelFavorite.ImageIndex := ImageIndexFavoriteOff;
ButtonSelFavorite.Hint := 'Отметить как важное';
end;
end;
procedure TFrameChat.UpdateReplyAnswerButton(const Count: Integer);
begin
if Count > 1 then
ButtonSelAnswerReply.Text := 'Переслать сюда'
else
ButtonSelAnswerReply.Text := 'Ответить';
end;
procedure TFrameChat.UpdateSelection(const Count: Integer);
begin
if Count <= 0 then
HeadMode := hmNormal
else
begin
HeadMode := hmSelection;
var Selected := GetSelected;
UpdatePinButton(Count, Selected);
UpdateFavoriteButton(Count, Selected);
UpdateReplyAnswerButton(Count);
LabelSelCount.Text := Count.ToString + ' ' +
WordOfCount(Count, ['сообщение', 'сообщения', 'сообщений']);
end;
end;
procedure TFrameChat.ForEach(Proc: TForEachMessage);
begin
var DoBreak := False;
for var Control in LayoutMessageList.Controls do
if Control is TFrameMessage then
begin
Proc(Control as TFrameMessage, DoBreak);
if DoBreak then
Exit;
end;
end;
procedure TFrameChat.FOnChangeMessage(const Sender: TObject; const M: TMessage);
var
Event: TEventMessageChange absolute M;
begin
if Event.Data.PeerId <> NormalizePeerId(FConversationId) then
Exit;
var MessageId := Event.Data.MessageId;
ForEach(
procedure(Item: TFrameMessage; var Break: Boolean)
begin
if Item.MessageId = MessageId then
begin
Item.UpdateFlags(Event.Data.ChangeType, Event.Data.Flags);
Break := True;
end;
end);
UpdateSelection(SelectedCount);
end;
procedure TFrameChat.FOnDeleteMessage(const Sender: TObject; const M: TMessage);
var
Event: TEventDeleteMessage absolute M;
MessageId: Int64;
begin
if Event.PeerId <> NormalizePeerId(FConversationId) then
Exit;
MessageId := Event.LocalId;
ForEach(
procedure(Item: TFrameMessage; var Break: Boolean)
begin
if Item.ConversationMessageId = MessageId then
begin
Item.IsDeleted := True;
Break := True;
end;
end);
UpdateSelection(SelectedCount);
end;
procedure TFrameChat.FOnReadMessage(const Sender: TObject; const M: TMessage);
var
Event: TEventReadMessages absolute M;
MessageId: Int64;
begin
if Event.PeerId <> NormalizePeerId(FConversationId) then
Exit;
MessageId := Event.LocalId;
ForEach(
procedure(Item: TFrameMessage; var Break: Boolean)
begin
if Item.MessageId <= MessageId then
Item.IsUnread := False;
end);
end;
procedure TFrameChat.UpdateMessageData(const MessageId: Int64; ItemData: TVkMessage; ExtData: TVkEntityExtendedList<TVkMessage>);
begin
var Frame: TFrameMessageBase;
if FindMessage(MessageId, Frame) and (Frame is TFrameMessage) then
begin
(Frame as TFrameMessage).Fill(ItemData, ExtData, ChatInfo);
(Frame as TFrameMessage).UpdateVisibility;
end;
end;
procedure TFrameChat.UpdateMessage(const MessageId: Int64);
begin
if ContainsMessage(MessageId) then
TTask.Run(
procedure
var
Items: TVkMessages;
Params: TVkParamsMessageGet;
begin
Items := nil;
Params.MessageId(MessageId);
Params.Extended;
VK.Messages.GetById(Items, Params);
if Assigned(Items) then
begin
var Ext: IExtended := Items;
if Length(Items.Items) > 0 then
Event.Queue(Self,
procedure
var
ExtRef: IExtended;
begin
ExtRef := Ext;
UpdateMessageData(MessageId, Items.Items[0], Items);
ExtRef := nil;
end);
end;
end);
end;
procedure TFrameChat.FOnEditMessage(const Sender: TObject; const M: TMessage);
var
Event: TEventEditMessage absolute M;
begin
if Event.Data.PeerId <> NormalizePeerId(FConversationId) then
Exit;
UpdateMessage(Event.Data.MessageId);
end;
procedure TFrameChat.ActivityTyping(Data: TChatTypingData);
begin
TimerActivity.Enabled := False;
TimerActivity.Enabled := True;
LayoutActivityContent.Visible := True;
if Length(Data.UserIds) > 1 then
LabelActivity.Text := Length(Data.UserIds).ToString + ' печатают'
else if FMembers.Contains(Data.UserIds[0]) then
begin
var FName := FMembers.Get(Data.UserIds[0]).FirstName;
LabelActivity.Text := FName + ' печатает';
end
else
LabelActivity.Text := 'Кто-то печатает';
end;
procedure TFrameChat.FOnUsersTyping(const Sender: TObject; const M: TMessage);
var
Event: TEventUsersTyping absolute M;
begin
if Event.Data.PeerId <> NormalizePeerId(FConversationId) then
Exit;
ActivityTyping(Event.Data);
end;
procedure TFrameChat.FOnNewMessage(const Sender: TObject; const M: TMessage);
var
Msg: TEventNewMessage absolute M;
MessageId: Int64;
begin
if Msg.Data.PeerId <> NormalizePeerId(FConversationId) then
Exit;
MessageId := Msg.Data.MessageId;
TTask.Run(
procedure
var
Items: TVkMessageHistory;
Params: TVkParamsMessageHistory;
begin
Params.PeerId(ConversationId);
Params.StartMessageId(MessageId);
Params.Count(1);
Params.Extended;
Params.Fields([TVkExtendedField.Photo50, TVkExtendedField.Verified,
TVkExtendedField.Sex, TVkExtendedField.FirstNameAcc,
TVkExtendedField.LastNameAcc]);
if VK.Messages.GetHistory(Items, Params) then
begin
var Ext: IExtended := Items;
Event.Queue(Self,
procedure
begin
AppendMessage(Items, Ext);
end);
end;
end);
end;
procedure TFrameChat.UpdateUsers(Data: IExtended);
begin
for var i := 0 to Pred(Data.ProfileCount) do
FMembers.Update(Data.Profile(i));
end;
procedure TFrameChat.AppendHistory(Items: TVkMessageHistory; const Data: IExtended);
begin
UpdateUsers(Data);
var LastId: Int64 := -1;
LayoutMessageList.BeginUpdate;
try
for var Item in Items.Items do
begin
CreateMessageItem(Item, Items, False);
LastId := Item.Id;
end;
if FOffsetEnd then
InsertDateLastMessage(GetMessageDate(GetFirstMessage), LastId - 0.1);
finally
LayoutMessageList.EndUpdate;
end;
VertScrollBoxMessagesResize(nil);
LayoutMessageList.RecalcSize;
CalcDisappear(True);
if LayoutMessageList.Opacity = 0 then
Event.Queue(Self,
procedure
begin
TAnimator.AnimateFloat(LayoutMessageList, 'Opacity', 1);
end);
end;
procedure TFrameChat.AppendMessage(Items: TVkMessageHistory; Data: IExtended);
begin
TimerActivityTimer(nil);
UpdateUsers(Data);
LayoutMessageList.BeginUpdate;
try
for var Item in Items.Items do
CreateMessageItem(Item, Items, True);
if Length(Items.Conversations) > 0 then
UpdateInfo(Items.Conversations[0], Data);
finally
LayoutMessageList.EndUpdate;
end;
VertScrollBoxMessagesResize(nil);
LayoutMessageList.RecalcSize;
CalcDisappear(True);
if LayoutMessageList.Opacity = 0 then
Event.Queue(Self,
procedure
begin
TAnimator.AnimateFloat(LayoutMessageList, 'Opacity', 1);
end);
end;
procedure TFrameChat.FOnMessageSelected(Sender: TObject);
begin
UpdateSelection(SelectedCount);
end;
function TFrameChat.GetChatInfo: TChatInfo;
begin
Result.IsCanWrite := IsCanWrtie;
Result.IsP2P := IsUser;
Result.OutRead := OutRead;
Result.PeerId := ConversationId;
end;
function TFrameChat.GetFirstMessage: TFrameMessageBase;
begin
Result := nil;
var MsgId: Extended := -1;
for var Control in LayoutMessageList.Controls do
if (Control is TFrameMessage) or (Control is TFrameMessageAction) then
begin
var Id :=(Control as TFrameMessageBase).MessageId;
if (MsgId > Id) or (MsgId = -1) then
begin
MsgId := Id;