build.gradle

import org.jetbrains.kotlin.gradle.tasks.KotlinCompile

buildscript {
  ext.deps = [
      'junit': 'junit:junit:4.13',
      'truth': 'com.google.truth:truth:1.0.1',
      'kotlinStdlib': 'org.jetbrains.kotlin:kotlin-stdlib-jdk8:1.3.61',
      'kotlinSerialization': 'org.jetbrains.kotlinx:kotlinx-serialization-runtime:0.14.0',
      'asm': 'org.ow2.asm:asm:7.3.1',
      'asmUtil': 'org.ow2.asm:asm-util:7.3.1',
      'androidGradlePlugin': 'com.android.tools.build:gradle:4.0.0-beta01',
      'androidLint': 'com.android.tools.lint:lint:27.0.0-beta01',
      'jimfs': 'com.google.jimfs:jimfs:1.1',
      'xmlutil': 'net.devrieze:xmlutil-serialization-jvm:0.14.0.2',
  ]

  dependencies {
    classpath 'org.jetbrains.kotlin:kotlin-gradle-plugin:1.3.61'
    classpath 'org.jetbrains.kotlin:kotlin-serialization:1.3.61'
  }
  repositories {
    mavenCentral()
  }
}

subprojects {
  tasks.withType(KotlinCompile).all {
    kotlinOptions {
      freeCompilerArgs += '-XXLanguage:+NewInference'
      jvmTarget = '1.8'
    }
  }

  plugins.withType(JavaBasePlugin) {
    sourceCompatibility = JavaVersion.VERSION_1_8
    targetCompatibility = JavaVersion.VERSION_1_8
  }

  repositories {
    mavenCentral()
    google()
    jcenter()
  }
}