build.gradle

plugins {
  alias libs.plugins.indra
  alias libs.plugins.indra.checkstyle
  alias libs.plugins.indra.publishing.sonatype
  alias libs.plugins.spotless
  alias libs.plugins.indra.licenser.spotless
  alias libs.plugins.indra.crossdoc
  alias libs.plugins.nexusPublish
  id 'eclipse'
}

dependencies {
  compileOnlyApi libs.jetbrainsAnnotations
  testImplementation platform(libs.junit.bom)
  testImplementation libs.junit.api
  testRuntimeOnly libs.junit.engine
  testRuntimeOnly libs.junit.launcher
  checkstyle libs.stylecheck
  compileOnly libs.jansi
}

spotless {
  ratchetFrom 'origin/trunk'
  java {
    endWithNewline()
    indentWithSpaces 2
    importOrderFile rootProject.file('.spotless/kyori.importorder')
    trimTrailingWhitespace()
  }
}

eclipse {
  classpath {
  file.whenMerged { classpath ->
    classpath.entries.each { entry ->
    if (entry instanceof org.gradle.plugins.ide.eclipse.model.SourceFolder) {
      def extraReads = ['org.junit.jupiter.api']
      .collect { "net.kyori.ansi=$it" }
      .join(':')
      entry.entryAttributes['add-reads'] = extraReads
      entry.entryAttributes['module'] = 'true'
    }
    }
  }
  }
}

sourceSets {
  main {
    multirelease {
      alternateVersions(9, 22)
      moduleName "net.kyori.ansi"
      requireAllPackagesExported()
    }
  }
}

indraSonatype {
  useAlternateSonatypeOSSHost("s01")
}

indra {
  github("KyoriPowered", "ansi") {
    ci(true)
  }
  mitLicense()
  checkstyle libs.versions.checkstyle.get()

  javaVersions {
    testWith(11, 17, 20)
  }

  signWithKeyFromPrefixedProperties("kyori")
  configurePublications {
    pom {
      developers {
        developer {
          id = "kashike"
          timezone = "America/Vancouver"
        }

        developer {
          id = "lucko"
          name = "Luck"
          url = "https://lucko.me"
          email = "git@lucko.me"
        }

        developer {
          id = "zml"
          name = "zml"
          timezone = "America/Vancouver"
        }

        developer {
          id = "Electroid"
        }
      }
    }
  }
}

indraCrossdoc {
  baseUrl().set(providers.gradleProperty("javadocPublishRoot"))
}