-
Notifications
You must be signed in to change notification settings - Fork 0
/
PhaseTransition.wl
2575 lines (1600 loc) · 104 KB
/
PhaseTransition.wl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
(* ::Package:: *)
BeginPackage["PhaseTransition`"];
ptParams::usage="ptParams: function to compute parameters of the first order phase transition (1PT).\nInput: (gStar,direction,vw,{Temperature Evolution},coeffs,Tcrit,method,Kfactor,full,scaleFactor,Nlx).\n\tIf method='analytic' then {Temperature Evolution}={\[Gamma], t0, tcrit};\n\telse if method='semi'/'numeric'/'alt' then {Temperature Evolution}={Tfn, tScale}.\nOutput: {\!\(\*SubscriptBox[\(T\), \(PT\)]\), \!\(\*SubscriptBox[\(t\), \(PT\)]\), \!\(\*OverscriptBox[\(\[Lambda]\), \(_\)]\), \!\(\*SubscriptBox[\(\[CapitalPhi]\), \(b\)]\), \!\(\*SubscriptBox[\(\[CapitalDelta]V\), \(T\)]\), \!\(\*SubscriptBox[\(E\), \(c\)]\), \!\(\*SubscriptBox[\(S\), \(E\)]\), \!\(\*SubscriptBox[\(S\), \(E\)]\)', \!\(\*SubscriptBox[\(S\), \(E\)]\)'', \!\(\*SubscriptBox[\(\[CapitalGamma]\), \(nucl\)]\)/\[ScriptCapitalV], \!\(\*SubscriptBox[\(\[Beta]\), \(1\)]\), \!\(\*SubscriptBox[\(\[Beta]\), \(2\)]\), \!\(\*SubscriptBox[\(n\), \(b\)]\), \!\(\*SubscriptBox[\(R\), \(b\)]\), <R>, \!\(\*SubscriptBox[\(\[Beta]\), \(eff\)]\), \!\(\*SubscriptBox[\(\[Alpha]\), \(\[Infinity]\)]\), {\!\(\*SubscriptBox[\(\[Alpha]\), \(n\)]\)}={\!\(\*SubscriptBox[\(\[Alpha]\), \(\[Epsilon]\)]\), \!\(\*SubscriptBox[\(\[Alpha]\), \(V\)]\), \!\(\*SubscriptBox[\(\[Alpha]\), \(L\)]\), \!\(\*SubscriptBox[\(\[Alpha]\), \(\[Theta]\)]\)}, {\!\(\*SubscriptBox[\(\[Kappa]\), \(run\)]\)}={\!\(\*SubscriptBox[\(\[Kappa]\), \(run, \[Epsilon]\)]\), \!\(\*SubscriptBox[\(\[Kappa]\), \(run, V\)]\), \!\(\*SubscriptBox[\(\[Kappa]\), \(run, L\)]\), \!\(\*SubscriptBox[\(\[Kappa]\), \(run, \[Theta]\)]\)}}";
tTPT::usage="tTPT: function to compute the time and temperature of the 1PT.\nInput: (direction,vw,TempEvol,coeffs,Tcrit,method,Kfactor,full,scaleFactor,Nlx).\n\tIf method='analytic' then {Temperature Evolution}={\[Gamma], t0, tcrit};\n\telse if method='semi'/'numeric'/'alt' then {Temperature Evolution}={Tfn, tScale}.\nOutput: \!\(\*SubscriptBox[\(t\), \(PT\)]\),\!\(\*SubscriptBox[\(T\), \(PT\)]\)";
Lmlnh::usage="Lmlnh: interpolated function \!\(\*SubscriptBox[\(log\), \(10\)]\)(-ln[h(\!\(\*SubscriptBox[\(log\), \(10\)]\) x)]), where h is the fractional volume in the metastable phase of the 1PT.\nInput: (direction,vw,TempEvol,coeffs,Tcrit,Kfactor,full,scaleFactor,Nlx).\nOutput: \!\(\*SubscriptBox[\(log\), \(10\)]\)(-ln[h(\!\(\*SubscriptBox[\(log\), \(10\)]\)x)])";
Lnbubble::usage="Lnbubble: interpolated function \!\(\*SubscriptBox[\(log\), \(10\)]\)(\!\(\*SubscriptBox[\(n\), \(b\)]\)(\!\(\*SubscriptBox[\(log\), \(10\)]\)(x)), where \!\(\*SubscriptBox[\(n\), \(b\)]\) is the mean bubble number density.\nInput: (LmlnhLx,TempEvol,coeffs,Tcrit,xVal,Kfactor,full,scaleFactor).\nOutput: \!\(\*SubscriptBox[\(log\), \(10\)]\)(\!\(\*SubscriptBox[\(n\), \(b\)]\)(\!\(\*SubscriptBox[\(log\), \(10\)]\)(x)))";
LRbubble::usage="LRbubble: interpolated function \!\(\*SubscriptBox[\(log\), \(10\)]\)(\!\(\*SubscriptBox[\(R\), \(b\)]\)(\!\(\*SubscriptBox[\(log\), \(10\)]\)(x))), where \!\(\*SubscriptBox[\(R\), \(b\)]\) is the average bubble radius.\nInput: (LmlnhLx,LnbLx,vw,TempEvol,coeffs,Tcrit,xVal,Kfactor,full,scaleFactor).\nOutput: \!\(\*SubscriptBox[\(log\), \(10\)]\)(\!\(\*SubscriptBox[\(R\), \(b\)]\)(\!\(\*SubscriptBox[\(log\), \(10\)]\)(x)))";
EcTemp::usage="EcTemp: function to compute the energy of the critical bubble of the 1PT.\nInput: (coeffs,Tcrit,T).\nOutput: \!\(\*SubscriptBox[\(E\), \(c\)]\)";
SETemp::usage="SETemp: function to compute the Euclidean bounce action of the critical bubble of the 1PT.\nInput: (coeffs,Tcrit,T).\nOutput: \!\(\*SubscriptBox[\(S\), \(E\)]\)";
S1Rate::usage="S1Rate: function to compute the first time derivative of the Euclidean bounce action.\nInput: (dlnTdt[t],coeffs,Tcrit,T).\nOutput: \!\(\*SubscriptBox[\(S\), \(E\)]\)'(t)";
S2Rate::usage="S2Rate: function to compute the second time derivative of the Euclidean bounce action.\nInput: (dlnTdt[t],d2lnTdt2[t],coeffs,Tcrit,T).\nOutput: \!\(\*SubscriptBox[\(S\), \(E\)]\)''(t)";
\[CapitalGamma]nucl::usage="\[CapitalGamma]nucl: function to compute the bubble nucleation rate of the 1PT.\nInput: (coeffs,Tcrit,T,Kfactor,full).\nOutput: \!\(\*SubscriptBox[\(\[CapitalGamma]\), \(nucl\)]\)/\[ScriptCapitalV]";
\[Beta]1Rate::usage="\[Beta]1Rate: function to compute the first time derivative of the log of the nucleation rate.\nInput: (dlnTdt[t],coeffs,Tcrit,T,Kfactor,full).\nOutput: \!\(\*SubscriptBox[\(\[Beta]\), \(1\)]\)(t)";
\[Beta]2Rate::usage="\[Beta]2Rate: function to compute the second time derivative of the log of the nucleation rate.\nInput: (dlnTdt[t],d2lnTdt2[t],coeffs,Tcrit,T,Kfactor,full).\nOutput: \!\(\*SubscriptBox[\(\[Beta]\), \(2\)]\)(t)";
Begin["`Private`"];
(* ::Title:: *)
(*PhaseTransition.wl*)
(* ::Text:: *)
(*WRITTEN BY: MANUEL A. BUEN-ABAD, 2022.*)
(**)
(*This is a code that computes various parameters and functions associated with bubble nucleation during First Order Phase Transitions (1PT). Many of the results here have been hard-wired into the code. This helps to make importing this code much faster and painless, but may obscure the results. For the derivation of these hard-coded results, see notebook 02_phase_transition.nb.*)
(* ::Chapter:: *)
(*0. Preamble*)
(* ::Section:: *)
(*Assumptions*)
$Assumptions=Mc>0&&M^2>0&&\[Delta]>0&&\[Mu]>0&&T>0&&T0>0&&T>T0&&A>0&&\[Lambda]>0&&4*A^2<3*\[Lambda]*\[Mu]^2&&Tc>0&&Tc>T0&&\[Lambda]bar>0&&\[Lambda]bar<9/8
(* ::Section:: *)
(*Directories*)
bubbleDir=NotebookDirectory[]<>"results/phase_transition/bubbles/";
fnsLambdaDir=NotebookDirectory[]<>"results/phase_transition/fns_lambda/";
(* ::Section:: *)
(*Test Arguments*)
Clear[noOption]
noOption[value_, options_List] := If[MemberQ[options, value] == False, Message[noOption::ArgumentsNotAllowed, value, options]; Abort[]];
noOption::ArgumentsNotAllowed = "Argument `1` not a string from options `2`.";
(* ::Section:: *)
(*Interpolation Package*)
(* ::Input::Initialization:: *)
Needs["DifferentialEquations`InterpolatingFunctionAnatomy`"];
(* ::Section:: *)
(*Definitions*)
Clear[smallnum]
smallnum=10^-6;
(* ::Chapter:: *)
(*1. Potential*)
(* ::Text:: *)
(*In this Notebook we will assume there is one single scalar \[CapitalPhi] undergoing the phase transition.*)
(* ::Section:: *)
(*1.1 Definition*)
(* ::Text:: *)
(*We first write the thermal potential (density) of the scalar field. Note that it is equal to the zero-temperature potential (T=0) contribution (from your usual QFT course) plus the thermal free energy density (\[ScriptCapitalF]) contributions from bosons and fermions coupled to it.*)
(**)
(*The only assumptions are that: \[CapitalPhi] is real, and that M^2(T)>0, \[Delta](T)>0.*)
(* ::ItemNumbered:: *)
(*\[CapitalPhi] \[Element]R^+*)
(* ::ItemNumbered:: *)
(*M^2(T)>0*)
(* ::ItemNumbered:: *)
(*\[Delta](T)>0*)
(* ::ItemNumbered:: *)
(*\[Lambda]>0*)
(* ::Text:: *)
(*M^2(T)>0 is necessary so that we're above the binodal temperature and the symmetric phase is a minimum and not a maximum. The \[Delta](T)>0 condition can be relaxed and all results will still follow upon the change of variables \[Delta](T)->\[Dash]\[Delta](T), \[CapitalPhi]->\[Dash]\[CapitalPhi].*)
V[x_]=M^2/2 x^2-\[Delta]/3 x^3+(\[Lambda]/4!) (x^4)(*M^2(T) and \[Delta](T) general functions of T, with contributions from bosons and fermions*);
(* ::Text:: *)
(*The extrema of the potential are:*)
extrema={{x->0},{x->(3 \[Delta]-Sqrt[9 \[Delta]^2-6 M^2 \[Lambda]])/\[Lambda]},{x->(3 \[Delta]+Sqrt[9 \[Delta]^2-6 M^2 \[Lambda]])/\[Lambda]}};
Fs=(x/.extrema[[1]])(*\[CapitalPhi]_s: value in symmetric minimum*);
Fm=(x/.extrema[[2]])(*\[CapitalPhi]_m: value at maximum*);
Fb=(x/.extrema[[3]])(*\[CapitalPhi]_b: value in broken minimum*);
(* ::Text:: *)
(*The potential at those values is:*)
val={0,((-3 \[Delta]+Sqrt[9 \[Delta]^2-6 M^2 \[Lambda]])^2 (3 M^2 \[Lambda]+\[Delta] (-3 \[Delta]+Sqrt[9 \[Delta]^2-6 M^2 \[Lambda]])))/(12 \[Lambda]^3),-(((3 \[Delta]+Sqrt[9 \[Delta]^2-6 M^2 \[Lambda]])^2 (-3 M^2 \[Lambda]+\[Delta] (3 \[Delta]+Sqrt[9 \[Delta]^2-6 M^2 \[Lambda]])))/(12 \[Lambda]^3))};
Vs=val[[1]];
Vm=val[[2]];
Vb=val[[3]];
Clear[extrema,val]
(* ::Text:: *)
(*As we shall see, at T=0 \[Delta]=0, and therefore the VEV and the potential value is:*)
Fb0=(Sqrt[6] Sqrt[-M^2 \[Lambda]])/\[Lambda];
Vb0=-((3 M^4)/(2 \[Lambda]));
(* ::Section:: *)
(*1.2 Critical temperature*)
(* ::Text:: *)
(*Knowing the value of the potential at the various phases we can find when both minima are degenerate, i.e. V_b = V_ s = 0, in terms of the coefficients of the parameter M of the potential. The result motivates the following definitions: M_c^2(T) \[Congruent]4/3 \[Delta](T)^2/\[Lambda] and \[Lambda]bar(T)\[Congruent]M^2(T)/M_c^2(T):*)
PotToMc\[Lambda]bar={M->Mc*Sqrt[\[Lambda]bar],\[Delta]->Sqrt[\[Lambda] Mc^2]*Sqrt[3]/2};
(* ::Text:: *)
(*Clearly, when \[Lambda]bar(T_c)=1 we have M(T_c) = M_c(T_c). This is the definition of T_c: the so-called critical temperature. One can find T_c if one knows the functional form of M(T) and of \[Delta](T).*)
(* ::Section:: *)
(*1.3 Simplification*)
(* ::Text:: *)
(*The extrema of the potential can be written in terms of these new variables, yielding more convenient expressions (with an overall dimensional scale given by M_c and a T-dependent function, via \[Lambda]bar(T).*)
(* ::Text:: *)
(*Note that M^2(T) is the \[CapitalPhi]-mass (i.e. V''(\[CapitalPhi])) in the symmetric phase (\[LeftAngleBracket]\[CapitalPhi]\[RightAngleBracket]=\[CapitalPhi]_s=0). In the broken phase (\[LeftAngleBracket]\[CapitalPhi]\[RightAngleBracket]=\[CapitalPhi]_b) the mass M_b^2(T) (V'') is:*)
Mb=(1/2 Mc Sqrt[9+3 Sqrt[9-8 \[Lambda]bar]-8 \[Lambda]bar]);
(* ::Text:: *)
(*From here, we can find the difference V_b - V_s between the two minima:*)
VbmVs=((3 Mc^4 (-9 (3+Sqrt[9-8 \[Lambda]bar])+4 (9+2 Sqrt[9-8 \[Lambda]bar]-2 \[Lambda]bar) \[Lambda]bar))/(16 \[Lambda]))(*potential difference*);
(* ::Text:: *)
(*Therefore, \[CapitalDelta]V\[Congruent]|V_b - V_s|=sign(\[Lambda]bar - 1) (V_b - V_s) is always positive:*)
\[CapitalDelta]V=(1/(16 \[Lambda]) 3 Mc^4 (-9 (3+Sqrt[9-8 \[Lambda]bar])+4 (9+2 Sqrt[9-8 \[Lambda]bar]-2 \[Lambda]bar) \[Lambda]bar) Sign[-1+\[Lambda]bar]);
(* ::Section:: *)
(*1.4 Dimensionless expressions*)
(* ::Text:: *)
(*A convenient way to write our equations is in terms of dimensionless quantities. The actual physical quantities can then be obtained from the dimensionless ones by multiplying by the appropriate scales.*)
(**)
(*We define \[CapitalPhi]bar\[Congruent]\[CapitalPhi]/\[CapitalPhi]_b and rbar=M\[CenterDot]r. We will see that the dimensionality of the potential is given by M^2 \[CapitalPhi]_b^2:*)
PotDim=(-((3 Mc^4 \[Lambda]bar (-3 (3+Sqrt[9-8 \[Lambda]bar])+4 \[Lambda]bar))/(2 \[Lambda])));
(* ::Text:: *)
(*Then, the dimensionless potential is:*)
dimlessV[x_,\[Lambda]bar_]=((x^2 (-4 x (3+Sqrt[9-8 \[Lambda]bar])+x^2 (9+3 Sqrt[9-8 \[Lambda]bar]-4 \[Lambda]bar)+8 \[Lambda]bar))/(16 \[Lambda]bar));
(* ::Text:: *)
(*The dimensionless potential energy difference between both minima is:*)
dimless\[CapitalDelta]V[\[Lambda]bar_]=(Abs[-1+\[Lambda]bar]/(-3+Sqrt[9-8 \[Lambda]bar]+4 \[Lambda]bar));
(* ::Section:: *)
(*1.5 Potential coefficients M(T) & \[Delta](T)*)
(* ::Text:: *)
(*Let us recall the important functions. The potential depends on M(T) and \[Delta](T). In terms of M_c and \[Lambda]bar we used the substitutions*)
(* ::Input:: *)
(*PotToMc\[Lambda]bar*)
(* ::Text:: *)
(*Inverting those substitutions we get M_c and \[Lambda]bar in terms of M and \[Delta]:*)
defMc=Mc->(2 \[Delta])/Sqrt[3 \[Lambda]];
def\[Lambda]bar=(\[Lambda]bar->M^2/Mc^2)/.defMc;
Mc\[Lambda]barToPot={defMc,def\[Lambda]bar};
(* ::Text:: *)
(*For some theories the M(T) and \[Delta](T) coefficients have the following temperature dependence:*)
PotToCoeffs={M->\[Mu] Sqrt[(T^2-T0^2)],\[Delta]->A T};
(* ::Text:: *)
(*where T_0 is the binodal temperature, and \[Mu] and A are dimensionless parameters. M_c and \[Lambda]bar are therefore:*)
Mc\[Lambda]barToCoeffs=Mc\[Lambda]barToPot/.PotToCoeffs;
(* ::Text:: *)
(*From here we can find the binodal temperature in terms of the critical temperature T_c, at which \[Lambda]bar(T_c)=1:*)
Tbinodal=({T0->(Tc Sqrt[-((4 A^2)/(3 \[Lambda]))+\[Mu]^2])/\[Mu]});
(* ::Text:: *)
(*Clearly the condition for there to be a critical temperature is*)
cond1[\[Mu]_,A_,\[Lambda]_]=(1-4/3 A^2/(\[Lambda] \[Mu]^2)>0);
(* ::Text:: *)
(*The spinodal temperature, on the other hand, is when \[Lambda]bar=9/8 and the second minimum vanishes:*)
Tspinodal=({Ts->Tc/Sqrt[1+A^2/(8 A^2-6 \[Lambda] \[Mu]^2)]});
(* ::Text:: *)
(*This occurs for parameter values that satisfy the following condition*)
cond2[\[Mu]_,A_,\[Lambda]_]=(1+A^2/(8 A^2-6 \[Lambda] \[Mu]^2)>0);
(* ::Text:: *)
(*We hereby define some functions of the coefficients of the potential that allow us to perform error handling whenever we stray from the physical parameter space.*)
noCritTemp[coeffs_]:=If[cond1[coeffs[[1]],coeffs[[2]],coeffs[[3]]],None,Message[noCritTemp::ParameterSpace,coeffs];Abort[]];
noCritTemp::ParameterSpace="The parameters {\[Mu],A,\[Lambda]}=`1` in the potential do not allow for a critical temperature, nor a first order phase transition.";
(* ::Text:: *)
(*Finally, this leads to the updated rules, in terms of {T, T_c, \[Mu], A}:*)
Mc\[Lambda]barToCoeffs=({Mc->(2 A T)/(Sqrt[3] Sqrt[\[Lambda]]),\[Lambda]bar->(4 Tc^2+(3 (T-Tc) (T+Tc) \[Lambda] \[Mu]^2)/A^2)/(4 T^2)});
PotToCoeffs=({M->Sqrt[T^2+1/3 Tc^2 (-3+(4 A^2)/(\[Lambda] \[Mu]^2))] \[Mu],\[Delta]->A T});
(* ::Text:: *)
(*We can also write T in terms of \[Lambda]bar for a given set of parameters*)
TTo\[Lambda]bar=Tc Sqrt[(4 A^2-3 \[Lambda] \[Mu]^2)/(4 A^2 \[Lambda]bar-3 \[Lambda] \[Mu]^2)];
(* ::Text:: *)
(*And therefore M_c in terms of \[Lambda]bar:*)
McTo\[Lambda]bar={Mc->2 A Tc Sqrt[(4 A^2-3 \[Lambda] \[Mu]^2)/(12 A^2 \[Lambda] \[Lambda]bar-9 \[Lambda]^2 \[Mu]^2)]};
(* ::Text:: *)
(*The variable \[CapitalDelta]\[Congruent](4/3)A^2/(\[Lambda] \[Mu]^2) is very useful, since \[CapitalDelta]=0 corresponds to no cubic term (and thus no broken phase), whereas \[CapitalDelta]=1 corresponds to the 1PT condition not being satisfied, and \[CapitalDelta]=8/9 to the spinodal temperature going to T_s->\[Infinity]:*)
ARule={A->Sqrt[3]/2 Sqrt[\[Lambda]]\[Mu] Sqrt[\[CapitalDelta]]};
(* ::Text:: *)
(*From here we can then write T and M_c in terms of \[Lambda]bar and \[CapitalDelta], which is particularly simple:*)
TTo\[Lambda]bar\[CapitalDelta]={T->Tc Sqrt[(1-\[CapitalDelta])/(1-\[CapitalDelta]*\[Lambda]bar)]}
McTo\[Lambda]bar\[CapitalDelta]={Mc->Tc \[Mu] Sqrt[\[CapitalDelta]] Sqrt[(1-\[CapitalDelta])/(1-\[CapitalDelta]*\[Lambda]bar)]}
(* ::Text:: *)
(*For the T=0 case the substitution for the potential coefficients are:*)
PotToCoeffs0Temp={M->Tc Sqrt[-1+(4 A^2)/(3 \[Lambda] \[Mu]^2)] \[Mu],\[Delta]->0};
(* ::Text:: *)
(*For future reference, we compute (d \[Lambda]bar)/dT, (d \[Lambda]bar)/(d lnT), (d^2 \[Lambda]bar)/(d ln T^2), (d ln \[Lambda]bar)/(d ln T), and (d^2 ln \[Lambda]bar)/(d ln T^2):*)
d\[Lambda]dT=((Tc^2 (-4 A^2+3 \[Lambda] \[Mu]^2))/(2 A^2 T^3));
d\[Lambda]dlnT=d\[Lambda]dT*T;
d2\[Lambda]dlnT2=(Tc^2 (4 A^2-3 \[Lambda] \[Mu]^2))/(A^2 T^2);
dln\[Lambda]dlnT=((2 Tc^2 (-4 A^2+3 \[Lambda] \[Mu]^2))/(4 A^2 Tc^2+3 (T^2-Tc^2) \[Lambda] \[Mu]^2));
d2ln\[Lambda]dlnT2=-((12 T^2 Tc^2 \[Lambda] \[Mu]^2 (-4 A^2+3 \[Lambda] \[Mu]^2))/(4 A^2 Tc^2+3 (T^2-Tc^2) \[Lambda] \[Mu]^2)^2);
(* ::Chapter:: *)
(*2. Critical Bubble*)
(* ::Text:: *)
(*The critical bubble is the profile for \[CapitalPhi]_bubble(x) \[Congruent] \[CapitalPhi]_bub that corresponds to a stationary solution interpolating between the two minima \[CapitalPhi]=constant minima (i.e. \[CapitalPhi]_s & \[CapitalPhi]_b), and are solutions to the stationary equation for the Euclidean action (S_E), which can be written in terms of the energy of the critical bubble, E_T:*)
(**)
(*S_E[\[CapitalPhi]] = S_E[\[CapitalPhi]]/T=T^-1 \[Integral]d^3 x 1/2 (\[Del]\[CapitalPhi])^2+ V_T(\[CapitalPhi])*)
(**)
(*\[Delta]E_T[\[CapitalPhi]]/\[Delta]\[CapitalPhi]=0 \[DoubleRightArrow] -\[Del]^2\[CapitalPhi]+\[PartialD]V_T(\[CapitalPhi])/\[PartialD]\[CapitalPhi]=0*)
(**)
(*Note that we will be dealing with spherically-symmetric, time-independent expressions, so this equation reduces to:*)
(**)
(*-(1/r^2) d/dr (r^2 d\[CapitalPhi]_bub/dr) + V_T'(\[CapitalPhi]_bub)=0*)
(**)
(*The dimensionality of this equation is then M^2 \[CapitalPhi]_b. Dividing the whole expression by this dimension (M^2 \[CapitalPhi]_b) allows us to find its dimensionless form, which we will use in the next section. On the other hand, the dimensionality of the E_T energy is (\[CapitalPhi]_b^2)/M, and thus the action has a prefactor P_S\[Congruent](\[CapitalPhi]_b^2)/(M T).*)
(**)
(*This prefactor can be rewritten in terms of \[Lambda]bar. It, and its first and second derivatives w.r.t. \[Lambda]bar, are given by:*)
PS=(8Sqrt[3] A)/(\[Lambda]^(3/2) \[Lambda]bar^(1/2)) ((3+Sqrt[9-8 \[Lambda]bar])/4)^2;
dPSd\[Lambda]=-((Sqrt[3] A (9 (3+Sqrt[9-8 \[Lambda]bar])+4 Sqrt[9-8 \[Lambda]bar] \[Lambda]bar))/(2 \[Lambda]bar Sqrt[\[Lambda]^3 (9-8 \[Lambda]bar) \[Lambda]bar]));
d2PSd\[Lambda]2=-((Sqrt[3] A (-243 (3+Sqrt[9-8 \[Lambda]bar])+4 \[Lambda]bar (216+45 Sqrt[9-8 \[Lambda]bar]+8 Sqrt[9-8 \[Lambda]bar] \[Lambda]bar)))/(4 (\[Lambda] (9-8 \[Lambda]bar))^(3/2) \[Lambda]bar^(5/2)));
(* ::Section:: *)
(*2.1 Differential Equation*)
(* ::Text:: *)
(*The differential equation is:*)
(**)
(*-(1/r^2) d/dr (r^2 d\[CapitalPhi]_bub/dr) + V_T'(\[CapitalPhi]_bub)=0,*)
(**)
(*which has dimensionality M^2 \[CapitalPhi]_b. Dividing the whole expression by this dimension (M^2 \[CapitalPhi]_b) allows us to find its dimensionless form.*)
(**)
(*The term with the derivative in the potential is:*)
dimlessVprime[x_,\[Lambda]bar_]=x+(x^2 (-9-3 Sqrt[9-8 \[Lambda]bar]))/(4 \[Lambda]bar)+(x^3 (9+3 Sqrt[9-8 \[Lambda]bar]-4 \[Lambda]bar))/(4 \[Lambda]bar);
(* ::Text:: *)
(*In terms of these dimensionless quantities, the bubble solution satisfies the following boundary conditions:*)
(**)
(*\[CapitalPhi]bar(rbar->\[Infinity]) \[Congruent] \[CapitalPhi]bar_fv is the false vacuum initial value of the scalar field \[CapitalPhi]bar in the phase transition: \[CapitalPhi]bar_fv = \[CapitalPhi]bar_s=0 (\[CapitalPhi]bar_fv = \[CapitalPhi]bar_b = 1) for a cold/subcritical PT (hot/supercritical PT)*)
(**)
(*\[CapitalPhi]bar(rbar=0) \[Congruent] \[CapitalPhi]bar_tv is the true vacuum final value of the scalar field \[CapitalPhi]bar in the phase transition: close to \[CapitalPhi]bar_tv = \[CapitalPhi]bar_b = 1 (\[CapitalPhi]bar_tv = \[CapitalPhi]bar_s = 0) for a cold/subcritical PT (hot/supercritical PT)*)
(**)
(*Recall that whether we have a hot (supercritical)/cold (subcritical) phase transition depends on the value of \[Lambda]bar (\[GreaterLess]1), and thus whether we tunnel from the broken to the symmetric phase, or vice versa.*)
(* ::Text:: *)
(*In terms of these dimensionless quantities, the energy in the critical bubble is given by:*)
(**)
(*E_T[\[CapitalPhi]_bub]=\[Integral]d^3 x 1/2 (\[Del]\[CapitalPhi]_bub)^2+ V_T(\[CapitalPhi]_bub) = (\[CapitalPhi]_b^2)/M 4\[Pi] \[Integral] drbar rbar^2 ( 1/2 (d\[CapitalPhi]bar_bub/drbar)^2 + Vbar_T(\[CapitalPhi]bar_bub) )*)
(**)
(*with \[CapitalPhi]_bub = \[CapitalPhi]_b \[CapitalPhi]bar_bub and Vbar_T(\[CapitalPhi]bar) = V_T(\[CapitalPhi]bar \[CapitalPhi]_b)/(\[CapitalPhi]_b^2 M^2)*)
(**)
(*As we will see more clearly in the thin wall approximation, this expression is formally infinite. However, what the physics depends on is the (finite) difference between the energies of the initial constant-\[CapitalPhi] configuration (\[CapitalPhi]bar_fv) and the bubble \[CapitalPhi]bar_bub configuration. This is called the critical energy, and is given by:*)
(**)
(*E_c\[Congruent]E_T[\[CapitalPhi]_bub]-E_T[\[CapitalPhi]_fv].*)
(* ::Text:: *)
(*Finally, the dimensionless critical bubble equation is:*)
(**)
(*\[CapitalPhi]bar_bub''(r) + (2/rbar) \[CapitalPhi]bar_bub'(r) - Vbar_T(\[CapitalPhi]bar_bub) = 0*)
(* ::Section:: *)
(*2.2 Analytic solution: thin wall approximation*)
(* ::Text:: *)
(*In the thin wall approximation (twa) \[Epsilon]\[Congruent]\[CapitalDelta]V/V_m<<1, which means that the gain in the vacuum energy from the bubble (~\[CapitalDelta]V\[CenterDot]R^3\[Proportional]\[Epsilon]\[CenterDot]R^3), only becomes larger than the energy from the bubble surface (~(R^2)) for a large bubble radius R, much larger than the thickness of the bubble wall.*)
(**)
(*One can show that in the twa \[CapitalPhi]' (r)^2 = 2 V_T(\[CapitalPhi]), and that the (dimensionless) critical energy can be written as:*)
(**)
(*Ebar_c=Ebar_T[\[CapitalPhi]bar_bub]-Ebar_T[\[CapitalPhi]bar_fv]=[(4\[Pi])/3 Rbar_c^3 Vbar_T(\[CapitalPhi]bar_tv) + 4\[Pi] Rbar_c^2 \[Sigma]bar+(4\[Pi])/3 Vbar_T(\[CapitalPhi]bar_fv) (\[Infinity]^3-Rbar_c^3)] - (4\[Pi])/3 Vbar_T(\[CapitalPhi]bar_fv) \[Infinity]^3 = -(4\[Pi])/3 Rbar_c^3 \[CapitalDelta] Vbar_T + 4\[Pi] Rbar_c^2 \[Sigma]bar ,*)
(**)
(*where R_c is the critical radius, and we have split the contributions to the energy in three parts: the inside (rbar<Rbar_c), the surface (rbar\[TildeTilde]Rbar_c), and the outside (rbar>Rbar_c). The (infinite) energy from the constant-\[CapitalPhi] initial configuration cancels out the (infinite) part from the energy of the critical bubble, as promised. What we are left with is a term from the difference \[CapitalDelta]Vbar\[Congruent]Vbar(\[CapitalPhi]bar_fv)-Vbar(\[CapitalPhi]bar_tv)>0 between the two minima, as well as the surface term.*)
(**)
(*The contribution from the surface depends on the surface tension \[Sigma]bar, given by:*)
(**)
(*\[Sigma]bar\[TildeTilde]|\[Integral]_(\[CapitalPhi]bar_fv)^(\[CapitalPhi]bar_tv) d\[CapitalPhi]bar Sqrt[2 Vbar_T(\[CapitalPhi]bar)]| = |\[Integral]_0^1 d\[CapitalPhi]bar Sqrt[2 Vbar_T(\[CapitalPhi]bar)]|*)
(* ::Subsection:: *)
(*Surface tension \[Sigma]*)
(*the dimensionless surface tension; performing the integral gives 1/6*)
\[Sigma]=1/6;
(* ::Text:: *)
(*Its dimensionality is \[CapitalPhi]_b^2 M, as can be seen both from the fact that the dimensionality of E_c is \[CapitalPhi]_b^2 /M and that of R_c is 1/M, and from the fact that the dimensionality of V_T is M^2 \[CapitalPhi]_b^2 and that of \[CapitalPhi] is \[CapitalPhi]_b.*)
(* ::Subsection:: *)
(*Critical radius R_c*)
(* ::Text:: *)
(*Moving on, we can calculate the critical bubble radius in the twa by realizing that, if the bubble is an extremum of Ebar_c, then Rbar_c is such that \[PartialD]Ebar_c/\[PartialD]Rbar_c=0. The result is:*)
Rctwa[\[Lambda]bar_]=((-3+Sqrt[9-8 \[Lambda]bar]+4 \[Lambda]bar)/(3 Abs[-1+\[Lambda]bar]))(*the critical radius*);
(* ::Subsection:: *)
(*Critical energy E_c*)
(* ::Text:: *)
(*The bubble's critical energy is then:*)
Ectwa[\[Lambda]bar_]=((2 \[Pi] (-3+Sqrt[9-8 \[Lambda]bar]+4 \[Lambda]bar)^2)/(81 (-1+\[Lambda]bar)^2));
(* ::Text:: *)
(*The first and second derivatives are*)
dEctwad\[Lambda][\[Lambda]bar_]=-((8 \[Pi] (-3+Sqrt[9-8 \[Lambda]bar]+4 (3-2 \[Lambda]bar) \[Lambda]bar))/(81 Sqrt[9-8 \[Lambda]bar] (-1+\[Lambda]bar)^3));
d2Ectwad\[Lambda]2[\[Lambda]bar_]=-((8 \[Pi] (-5-9 Sqrt[9-8 \[Lambda]bar]+4 \[Lambda]bar (-9+2 Sqrt[9-8 \[Lambda]bar]+2 (9-4 \[Lambda]bar) \[Lambda]bar)))/(27 (9-8 \[Lambda]bar)^(3/2) (-1+\[Lambda]bar)^4));
(* ::Subsection:: *)
(*Bubble profile \[CapitalPhi]_bub(r)*)
(* ::Text:: *)
(*It can be shown that in the twa*)
(**)
(*d \[CapitalPhi]bar/d rbar \[TildeTilde] sign(\[Lambda]bar-1)\[CenterDot]Sqrt[2Vbar_T(\[CapitalPhi]bar)],*)
(**)
(*(i.e. positive/negative derivatives for hot (supercritical)/cold (subcritical) PT). From here we can solve for rbar(\[CapitalPhi]bar):*)
(**)
(*rbar\[TildeTilde]|\[Integral]_(\[CapitalPhi]bar_fv)^(\[CapitalPhi]bar_tv) d\[CapitalPhi]bar'/Sqrt[2 Vbar_T(\[CapitalPhi]bar')]*)
(**)
(*and then invert the equation.*)
\[CapitalDelta]rtwa[\[CapitalPhi]lo_,\[CapitalPhi]hi_]=(Log[(\[CapitalPhi]hi (-1+\[CapitalPhi]lo))/((-1+\[CapitalPhi]hi) \[CapitalPhi]lo)])(*\[CapitalDelta]r change in r due to a change in \[CapitalPhi]*);
\[CapitalPhi]tvtwa[\[Lambda]bar_]=(E^(1/(-1+\[Lambda]bar))/(E^(1/(-1+\[Lambda]bar))+E^((Sqrt[9-8 \[Lambda]bar]+4 \[Lambda]bar)/(3 (-1+\[Lambda]bar)))))(*final value of \[CapitalPhi] from PT (namely, \[CapitalPhi](r\[Rule]0)) for a given critical radius R_c(\[Lambda]bar)*);
\[CapitalPhi]twa[r_,\[Lambda]bar_]=(1/(1+E^((-3+Sqrt[9-8 \[Lambda]bar]+4 \[Lambda]bar-3 r Abs[-1+\[Lambda]bar])/(3 (-1+\[Lambda]bar)))))(*the bubble profile in the twa*);
(* ::Subsection:: *)
(*Wall thickness l_w*)
(* ::Text:: *)
(*We can define the wall thickness l_w in terms of the change in radius r upon a certain change \[CapitalDelta] \[CapitalPhi]bar in the scalar field, centered around half the field-distance \[CapitalPhi]_*=|(\[CapitalPhi]_tv-\[CapitalPhi]_fv)/2|:*)
(**)
(*l_w \[Congruent] \[CapitalDelta] rbar = \[Integral]_((1-\[CapitalDelta]\[CapitalPhi]bar)/2)^((1+\[CapitalDelta]\[CapitalPhi]bar)/2) d\[CapitalPhi]bar'/(d\[CapitalPhi]bar'/drbar) = \[Integral]_((1-\[CapitalDelta]\[CapitalPhi]bar)/2)^((1+\[CapitalDelta]\[CapitalPhi]bar)/2) d\[CapitalPhi]bar'/(Sqrt[2 Vbar_T(\[CapitalPhi]bar')])*)
thickness[\[CapitalDelta]\[CapitalPhi]_]=(Log[(1+\[CapitalDelta]\[CapitalPhi])^2/(-1+\[CapitalDelta]\[CapitalPhi])^2])(*wall thickness for arbitrary change \[CapitalDelta]\[CapitalPhi]bar in \[CapitalPhi]bar around 1/2*);
(* ::Text:: *)
(*Since what where does the wall start and ends is an arbitrary definition, we simply take its value to be the thickness for changes of \[CapitalDelta]\[CapitalPhi]bar=0.9 around 1/2:*)
lw=thickness[9/10](*bubble thickness*);
(* ::Section:: *)
(*2.3 Semi-analytical solution: thick wall approximation*)
(* ::Text:: *)
(*In the limit where the minimum nucleated inside the bubble is very deep we can use the thick wall approximation, where we keep only the most relevant terms in the potential. We then want to find Ebar_c.*)
(* ::Subsection:: *)
(*Numerical action*)
(* ::Text:: *)
(*The action can be massaged into a dimensionless expression Sbar_E, whose value is roughly 19.4:*)
SThickNum=19.404686768981865;
(* ::Subsection:: *)
(*Cold (subcritical) 1PT*)
(* ::Text:: *)
(*For subcritical, cold 1PT, Ebar_c is:*)
EcThick["cold"][\[Lambda]bar_]=310.47498830370984 \[Sqrt](1/(3+Sqrt[9-8 \[Lambda]bar]+Sqrt[2] Sqrt[-(9+3 Sqrt[9-8 \[Lambda]bar]-4 \[Lambda]bar) (-1+\[Lambda]bar)])^4) \[Lambda]bar^2;
(* ::Text:: *)
(*In addition, in the \[Lambda]bar->0 limit, it and its first and second derivatives are:*)
limEcThick["cold"][\[Lambda]bar_]=2.1560763076646516` \[Lambda]bar^2;
limdEcThick["cold"][\[Lambda]bar_]=4.312152615329304` \[Lambda]bar;
limd2EcThick["cold"][\[Lambda]bar_]=4.312152615329304`;
(* ::Subsection:: *)
(*Hot (supercritical) 1PT*)
(* ::Text:: *)
(*For supercritical, hot 1PT, Ebar_c is:*)
EcThick["hot"][\[Lambda]bar_]=(155.23749415185492` Sqrt[((1-Sqrt[1-Sqrt[9-8 \[Lambda]bar]]+Sqrt[9-8 \[Lambda]bar])^4 \[Lambda]bar)/(9+3 Sqrt[9-8 \[Lambda]bar]-8 \[Lambda]bar)])/(3 +Sqrt[9-8 \[Lambda]bar])^2;
(* ::Text:: *)
(*In addition, in the \[Lambda]bar->9/8 limit, it and its first and second derivatives are:*)
limEcThick["hot"][\[Lambda]bar_]=113.04978910678393` (9/8-\[Lambda]bar)^(3/4);
limdEcThick["hot"][\[Lambda]bar_]=-(84.78734183008798`/(9/8-\[Lambda]bar)^(1/4));
limd2EcThick["hot"][\[Lambda]bar_]=-(21.19683545752185`/(9/8-\[Lambda]bar)^(5/4));
(* ::Section:: *)
(*2.4 Numerical solution*)
(* ::Text:: *)
(*We now need to find the critical bubble profiles, i.e. the solutions to the critical bubble differential equation. Note that since \[CapitalPhi]bar=1(0) is a minimum (\[CapitalPhi]_b or \[CapitalPhi]_s respectively), then for both of these values V_T'(\[CapitalPhi])=0 and \[CapitalPhi]bar is constant in rbar: there is not bubble, just a constant value for all radii. Thus we need to start a bit off from these values, but not so much that we over/undershoot and get stuck in the maximum instead.*)
(**)
(*The whole point of the numerical approach is to perform a shooting algorithm to find the initial condition that allows us to interpolate between the required minima.*)
(* ::Subsection:: *)
(*Defining useful lists*)
(* ::Input:: *)
(*Clear[\[Lambda]barList,\[Lambda]barString,rList]*)
(* ::Text:: *)
(*Computing a list of \[Lambda]bar*)
\[Lambda]barList=Table[lb,{lb,0.01,0.99,0.005}];
\[Lambda]barList=\[Lambda]barList~Join~Table[lb,{lb,1.01,1.124,0.001}];
(* ::Text:: *)
(*String form of \[Lambda]bar*)
\[Lambda]barString[\[Lambda]bar_]:=Module[{decimals,lbStr},
decimals=IntegerString[Round[1000*(\[Lambda]bar-IntegerPart[\[Lambda]bar])],10,3];
lbStr=ToString[IntegerPart[\[Lambda]bar]]<>"."<>decimals;
lbStr
]
(* ::Text:: *)
(*A list of many values for radius:*)
rList={0.0}~Join~Table[r,{r,10^-2,100,(100-10^-2)/399}];
(* ::Subsection:: *)
(*Importing numerical results*)
(* ::Text:: *)
(*Importing numerical results previously computed*)
Clear[bubTab,bubFn,rmaxTab]
For[i=1,i<=(\[Lambda]barList//Length),i++,
\[Lambda]bar=\[Lambda]barList[[i]];
fileName="bubble_lb-"<>\[Lambda]barString[\[Lambda]bar]<>".csv";
bubTab[i]=Import[bubbleDir<>fileName];
bubFn[i]=Interpolation[bubTab[i],InterpolationOrder->2]
]
rmaxTab=Import[fnsLambdaDir<>"rmax.csv"];
Clear[i,\[Lambda]bar,fileName]
(* ::Section:: *)
(*2.5 Critical Energy (dimensionless): full value*)
(* ::Text:: *)
(*The energy of the critical bubble is:*)
(**)
(*E_T[\[CapitalPhi]_bub]=\[Integral]d^3 x 1/2 (\[Del]\[CapitalPhi]_bub)^2+ V_T(\[CapitalPhi]_bub) = (\[CapitalPhi]_b^2)/M 4\[Pi] \[Integral] drbar rbar^2 ( 1/2 (d\[CapitalPhi]bar_bub/drbar)^2 + Vbar_T(\[CapitalPhi]bar_bub) )*)
(**)
(*with \[CapitalPhi]_bub = \[CapitalPhi]_b \[CapitalPhi]bar_bub and Vbar_T(\[CapitalPhi]bar) = V_T(\[CapitalPhi]bar \[CapitalPhi]_b)/(\[CapitalPhi]_b^2 M^2)*)
(**)
(*As we saw, this expression is formally infinite. However, what the physics depends on is the (finite) difference between the energies of the initial constant-\[CapitalPhi] configuration (\[CapitalPhi]bar_fv) and the bubble \[CapitalPhi]bar_bub configuration. This is called the critical energy, and is given by:*)
(**)
(*E_c\[Congruent]E_T[\[CapitalPhi]_bub]-E_T[\[CapitalPhi]_fv].*)
(* ::Subsection:: *)
(*Ebar_c(\[Lambda]bar)*)
(* ::Subsubsection:: *)
(*Importing full Ebar_c(\[Lambda]bar) table*)
EcritTab=Import[fnsLambdaDir<>"Ecrit.csv"];
alllbarTab=#[[1]]&/@EcritTab;
(* ::Subsubsection:: *)
(*Defining Ebar_c(\[Lambda]bar)*)
(* ::Text:: *)
(*Separating the regions for \[Lambda]bar<1 and \[Lambda]bar>1.*)
(* ::Input:: *)
(*Clear[lolbarTab,hilbarTab,lolbarFn,hilbarFn,loL,loR,hiL,hiR,EcFn]*)
lolbarTab=Select[EcritTab,#[[1]]<1&];
lolbarTab={#[[1]]//Log10,#[[2]]//Log10}&/@lolbarTab;
hilbarTab=Select[EcritTab,#[[1]]>1&];
hilbarTab={#[[1]]//Log10,#[[2]]//Log10}&/@hilbarTab;
(* ::Text:: *)
(*Interpolating in log-space*)
lolbarFn=Interpolation[lolbarTab,InterpolationOrder->1,Method->"Spline"];
hilbarFn=Interpolation[hilbarTab,InterpolationOrder->1,Method->"Spline"];
(* ::Text:: *)
(*Edges of the patches*)
{loL,loR}={10^lolbarTab[[1,1]],10^lolbarTab[[-1,1]]};
{hiL,hiR}={10^hilbarTab[[1,1]],10^hilbarTab[[-1,1]]};
(* ::Text:: *)
(*Defining the full function*)
Clear[EcFn]
EcFn[\[Lambda]bar_]:=Which[0<=\[Lambda]bar<loL,limEcThick["cold"][\[Lambda]bar],loL<=\[Lambda]bar<loR,10^lolbarFn[Log10[\[Lambda]bar]],((loR<=\[Lambda]bar<1)||(1<\[Lambda]bar<=hiL)),Ectwa[\[Lambda]bar],hiL<\[Lambda]bar<=hiR,10^hilbarFn[Log10[\[Lambda]bar]],hiR<\[Lambda]bar<=9/8,limEcThick["hot"][\[Lambda]bar]]
(* ::Subsection:: *)
(*Ebar_c'(\[Lambda]bar)*)
(* ::Subsubsection:: *)
(*Importing the first derivative of Ebar_c(\[Lambda]bar)*)
DEcritTab=Import[fnsLambdaDir<>"DEcrit.csv"];
(* ::Subsubsection:: *)
(*Defining Ebar_c'(\[Lambda]bar)*)
(* ::Input:: *)
(*Clear[DlolbarTab,DhilbarTab,DlolbarFn,DhilbarFn,DloL,DloR,DhiL,DhiR,dEcFnd\[Lambda]]*)
(* ::Text:: *)
(*Separating the regions for \[Lambda]bar<1 and \[Lambda]bar>1, which have positive/negative values of the derivative.*)
DlolbarTab=Select[DEcritTab,#[[1]]<1&];
DlolbarTab={#[[1]]//Log10,#[[2]]//Log10}&/@DlolbarTab;
DhilbarTab=Select[DEcritTab,#[[1]]>1&];
DhilbarTab={#[[1]]//Log10,Abs[#[[2]]]//Log10}&/@DhilbarTab;
(* ::Text:: *)
(*Interpolating in log-space*)
DlolbarFn=Interpolation[DlolbarTab,InterpolationOrder->1,Method->"Spline"];
DhilbarFn=Interpolation[DhilbarTab,InterpolationOrder->1,Method->"Spline"];
(* ::Text:: *)
(*Edges of the patches*)
{DloL,DloR}={10^DlolbarTab[[1,1]],10^DlolbarTab[[-1,1]]};
{DhiL,DhiR}={10^DhilbarTab[[1,1]],10^DhilbarTab[[-1,1]]};
(* ::Text:: *)
(*Defining the full function*)
Clear[dEcFnd\[Lambda]]
dEcFnd\[Lambda][\[Lambda]bar_]:=Which[0<=\[Lambda]bar<DloL,limdEcThick["cold"][\[Lambda]bar],DloL<=\[Lambda]bar<DloR,10^DlolbarFn[Log10[\[Lambda]bar]],((DloR<=\[Lambda]bar<1)||(1<\[Lambda]bar<=DhiL)),dEctwad\[Lambda][\[Lambda]bar],DhiL<\[Lambda]bar<=DhiR,-10^DhilbarFn[Log10[\[Lambda]bar]],DhiR<\[Lambda]bar<=9/8,limdEcThick["hot"][\[Lambda]bar]]
(* ::Subsection:: *)
(*Ebar_c''(\[Lambda]bar)*)
(* ::Subsubsection:: *)
(*Importing the second derivative of Ebar_c(\[Lambda]bar)*)
D2EcritTab=Import[fnsLambdaDir<>"D2Ecrit.csv"];
(* ::Subsubsection:: *)
(*Defining Ebar_c''(\[Lambda]bar)*)
(* ::Input:: *)
(*Clear[D2ColdlbarTab,D2HotlbarTab,D2SpinlbarTab,D2ColdlbarFn,D2HotlbarFn,D2SpinlbarFn,D2ColdL,D2ColdR,D2HotL,D2HotR,D2SpinL,D2SpinR,d2EcFnd\[Lambda]2]*)
(* ::Text:: *)
(*Separating the regions according to \[Lambda]bar and the sign of the second derivative*)
D2ColdlbarTab=Select[D2EcritTab,#[[1]]<1&];
D2ColdlbarTab={#[[1]]//Log10,#[[2]]//Log10}&/@D2ColdlbarTab;
D2HotlbarTab=Select[D2EcritTab,((#[[1]]>1)&&(#[[2]]>0))&];
D2HotlbarTab={#[[1]]//Log10,#[[2]]//Log10}&/@D2HotlbarTab;
D2SpinlbarTab=Select[D2EcritTab,((#[[1]]>1)&&(#[[2]]<0))&];
D2SpinlbarTab={#[[1]]//Log10,Abs[#[[2]]]//Log10}&/@D2SpinlbarTab;
(* ::Text:: *)
(*Interpolating in log-space*)
D2ColdlbarFn=Interpolation[D2ColdlbarTab,InterpolationOrder->1,Method->"Spline"];
D2HotlbarFn=Interpolation[D2HotlbarTab,InterpolationOrder->1,Method->"Spline"];
D2SpinlbarFn=Interpolation[D2SpinlbarTab,InterpolationOrder->1,Method->"Spline"];
(* ::Text:: *)
(*Edges of the patches*)
{D2ColdL,D2ColdR}={10^D2ColdlbarTab[[1,1]],10^D2ColdlbarTab[[-1,1]]};
{D2HotL,D2HotR}={10^D2HotlbarTab[[1,1]],10^D2HotlbarTab[[-1,1]]};
{D2SpinL,D2SpinR}={10^D2SpinlbarTab[[1,1]],10^D2SpinlbarTab[[-1,1]]};
(* ::Text:: *)
(*Defining the full function*)
Clear[d2EcFnd\[Lambda]2]
d2EcFnd\[Lambda]2[\[Lambda]bar_]:=Which[0<=\[Lambda]bar<D2ColdL,limd2EcThick["cold"][\[Lambda]bar],D2ColdL<=\[Lambda]bar<D2ColdR,10^D2ColdlbarFn[Log10[\[Lambda]bar]],((D2ColdR<=\[Lambda]bar<1)||(1<\[Lambda]bar<=D2HotL)),d2Ectwad\[Lambda]2[\[Lambda]bar],D2HotL<\[Lambda]bar<=D2HotR,10^D2HotlbarFn[Log10[\[Lambda]bar]],D2HotR<\[Lambda]bar<=D2SpinL,10^D2HotlbarFn[Log10[D2HotR]]+((-10^D2SpinlbarFn[Log10[D2SpinL]]-10^D2HotlbarFn[Log10[D2HotR]])/(D2SpinL-D2HotR))(\[Lambda]bar-D2HotR),D2SpinL<\[Lambda]bar<=D2SpinR,-10^D2SpinlbarFn[Log10[\[Lambda]bar]],D2SpinR<\[Lambda]bar<=9/8,limd2EcThick["hot"][\[Lambda]bar]]
(* ::Subsection:: *)
(*Analytical Approximation*)
(* ::Text:: *)
(*We are interested in a simple, one-term, analytic expression for Ebar_c(\[Lambda]bar) that may approximately capture the behavior for all \[Lambda]bar.*)
(**)
(*From our study of the thin wall approximation we know Ebar_c ~ (1-\[Lambda]bar)^-2, whereas in the thick wall approximation*)
(**)
(*Ebar_c ~ \[Lambda]bar^2 (\[Lambda]bar<1)*)
(*Ebar_c ~ (9-8\[Lambda]bar)^(3/4) (\[Lambda]bar>1)*)
(**)
(*We can then just fit a non-linear model to both regimes, and find a simple expression that is good to within O(1):*)
EcAnCold[\[Lambda]bar_]=(1.9764934553839089` (1.1308763363462961` -\[Lambda]bar)^0.9143524346793435` \[Lambda]bar^2)/(1-\[Lambda]bar)^2;
EcAnHot[\[Lambda]bar_]=(1.6441933519976608*(9/8-\[Lambda]bar)^(3/4))/(1-\[Lambda]bar)^2;
EcAn[\[Lambda]bar_]:=Which[0<=\[Lambda]bar<1,EcAnCold[\[Lambda]bar],9/8>=\[Lambda]bar>1,EcAnHot[\[Lambda]bar],\[Lambda]bar==1,\[Infinity]]
(* ::Text:: *)
(*For the action, we multiply P_S by Ebar_c:*)
SAn[\[Lambda]bar_]:=Which[0<=\[Lambda]bar<1,((Sqrt[3] A (3+Sqrt[9-8 \[Lambda]bar])^2)/(2 \[Lambda]^(3/2) Sqrt[\[Lambda]bar]))*EcAnCold[\[Lambda]bar],9/8>=\[Lambda]bar>1,((Sqrt[3] A (3+Sqrt[9-8 \[Lambda]bar])^2)/(2 \[Lambda]^(3/2) Sqrt[\[Lambda]bar]))*EcAnHot[\[Lambda]bar],\[Lambda]bar==1,\[Infinity]]
(* ::Text:: *)
(*A simple power-law estimate for S(\[Lambda]bar), based on the inflection points:*)
\[Lambda]barInfCold=0.5229448768554983`;
\[Lambda]barInfHot=1.075660395061243`;
SAnColdPL[\[Lambda]bar_]:=A/\[Lambda]^(3/2) (E^(1.346607299235003`+ 4.854987779449222` \[Lambda]bar))
SAnHotPL[\[Lambda]bar_]:=A/\[Lambda]^(3/2) (E^(54.86051144998107`- 45.609033621086894` \[Lambda]bar))
(* ::Text:: *)
(*The inverse \[Lambda]bar(S):*)
\[Lambda]barColdS[S_]:=-0.27736574434545125`+ 0.20597374193873785`*Log[(S \[Lambda]^(3/2))/A]
\[Lambda]barHotS[S_]:=1.2028431013415912`- 0.02192548099808148` *Log[(S \[Lambda]^(3/2))/A]
(* ::Chapter:: *)
(*3. Important Physical Quantities*)
(* ::Section:: *)
(*3.1 Temperature function*)
(* ::Subsection:: *)
(*TLow & THigh*)
(* ::Text:: *)
(*These will be shorthand names for the lowest and highest temperatures allowed (close to the binodal and spinodal temperatures):*)
TLow=Tc Sqrt[(4 A^2-3 \[Lambda] \[Mu]^2)/(A^2/250-3 \[Lambda] \[Mu]^2)];
THigh=Tc Sqrt[(4 A^2-3 \[Lambda] \[Mu]^2)/((112499 A^2)/25000-3 \[Lambda] \[Mu]^2)];
(* ::Subsection:: *)
(*Potential Parameters*)
(* ::Text:: *)
(*We start by defining a "master list" whose i-th entry consists of the the following information about the i-th particle of the dark sector:*)
(**)
(*{type, N_i, g_i},*)
(**)
(*where type = "B"/"F" denotes boson/fermion, N_i is the degrees of freedom of the i-th particle, and g_i is its coupling to the higgs \[CapitalPhi].*)
(**)
(*\[Mu]^2/2=1/24 \[Sum]_i c_i N_i g_i^2,*)
(**)
(*A/3=1/(12\[Pi]) \[Sum]_B N_B g_B^3,*)
(**)
(*a = \[Pi]^2/30 g_* = \[Pi]^2/30 \[Sum]_(m_i << T) c_i' N_i,*)
(**)
(*where g_* is the usual number of relativistic d.o.f. in the dark sector plasma.*)
Clear[cType,cprimeType,\[Mu]FromList,AFromList,aFromList]
(*Boson/Fermion factor in V_T(T)*)
cType[type_String]:=Which[type=="B",1,type=="F",1/2]
(*Boson/Fermion factor in \[Rho]_rad(T)*)
cprimeType[type_String]:=Which[type=="B",1,type=="F",7/8]
(*\[Mu]-coefficient in thermal potential V_T*)
\[Mu]FromList[particleContent_List]:=Sqrt[1/12 Total[cType[#[[1]]]*#[[2]]*#[[3]]^2&/@particleContent]];
(*A-coefficient in thermal potential V_T*)
AFromList[particleContent_List]:=1/(4\[Pi]) Total[If[#[[1]]=="B",1,0]*cType[#[[1]]]*#[[2]]*#[[3]]^3&/@particleContent];
(*a-coefficient in \[Rho]_rad(T) (a=\[Pi]^2/30 g_* ). Note only massless particles contribute to it*)
aFromList[particleContent_List,scalarValue_]:=\[Pi]^2/30 Total[cprimeType[#[[1]]]*#[[2]]*HeavisideTheta[-Rationalize[(#[[3]]*scalarValue)]]&/@particleContent]/.{HeavisideTheta[0]->1};
(* ::Text:: *)
(*Nevertheless we will most likely not bother nailing down the exact particle content of the dark sector. As such, we will be concerned mostly with \[Mu], A, and a directly.*)
(* ::Subsection:: *)
(*Transition strength \[Alpha]_n, runaway threshold strength \[Alpha]_\[Infinity], and runaway condition*)
(* ::Text:: *)
(*From this, let us write some functions that will help us directly write down the phase transition strength in terms of the relevant parameters.*)
(**)
(*\[Alpha]_\[Epsilon]=-V_b0/\[Rho]_r (vacuum energy),*)
(**)
(*Subscript[\[Alpha], V]\[Congruent]\[CapitalDelta]V_T/\[Rho]_r (potential energy),*)
(**)
(*Subscript[\[Alpha], L]\[Congruent]\[CapitalDelta]L/\[Rho]_r=\[CapitalDelta](V_T-T*dV_T/dT)/\[Rho]_r (latent heat),*)
(**)
(*Subscript[\[Alpha], \[Theta]]\[Congruent]\[CapitalDelta]\[Theta]/\[Rho]_r=\[CapitalDelta](V_T-(T/4)*dV_T/dT)/\[Rho]_r (trace anomaly),*)
(**)
(*\[Alpha]_\[Infinity]\[TildeTilde](\[Mu]^2/2) T^2 \[CapitalPhi]_b^2/\[Rho]_r (=\[CapitalDelta]P_LO in Ellis et al. 1903.09642)*)
(**)
(*The runaway condition is*)
(**)
(*\[Kappa]_run>0,*)
(**)
(*where \[Kappa]_run \[Congruent] sign[1-\[Lambda]bar](\[Alpha]_n - \[Alpha]_\[Infinity])/\[Alpha]_n .*)
Clear[\[CapitalDelta]VT,\[CapitalDelta]Lheat,\[CapitalDelta]\[Theta]an]
\[CapitalDelta]VT[coeffs_List,Tcrit_,Temp_]:=Block[{\[Mu],A,\[Lambda],Tc=Tcrit,T,\[Lambda]bar,sign,res},
(*distributing the coefficients*)
{\[Mu],A,\[Lambda]}=coeffs;
(*checking whether there can be a first order phase transition*)
noCritTemp[coeffs];
(*\[Lambda]bar*)
\[Lambda]bar=(\[Lambda]bar/.Mc\[Lambda]barToCoeffs)/.T->Temp;
(*>0 if <\[CapitalPhi]>_b is the true vacuum (cPTs), <0 if it's the false vacuum (hPTs)*)
sign=Sign[1-\[Lambda]bar];
(*\[CapitalDelta]V_T: the potential energy difference \[CapitalDelta]V_T=(V_T+)-(V_T-)*)
res=(sign*(Vs-Vb)/.PotToCoeffs)/.T->Temp;
res
];
\[CapitalDelta]Lheat[coeffs_List,Tcrit_,Temp_]:=Block[{\[Mu],A,\[Lambda],Tc=Tcrit,T,\[Lambda]bar,sign,sterm,VbT,bterm,res},
(*distributing the coefficients*)
{\[Mu],A,\[Lambda]}=coeffs;
(*checking whether there can be a first order phase transition*)
noCritTemp[coeffs];