-
Notifications
You must be signed in to change notification settings - Fork 0
/
Raytrace.hs
328 lines (265 loc) · 10.2 KB
/
Raytrace.hs
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
module Raytrace where
-- Ensure output is encoded at UTF8
import Data.Char (chr)
import Prelude hiding (putStr)
import Data.ByteString.Char8 (putStr)
import Data.String ( IsString(fromString) )
toRadians :: Float -> Float
toRadians deg = deg * (pi/180)
toDegrees :: Float -> Float
toDegrees rads = rads * (180/pi)
{-
--== VECTOR DEFINITION ==--
-}
-- Define vector type
type Vec = [Float]
-- Vector addition
(/+/) :: Vec -> Vec -> Vec
(/+/) = zipWith (+)
-- Vector subtraction
(/-/) :: Vec -> Vec -> Vec
(/-/) = zipWith (-)
-- Vector-Scalar multiplication
(/*/) :: Float -> Vec -> Vec
(/*/) = map . (*)
-- Dot product of two vectors
(/./) :: Vec -> Vec -> Float
(/./) a b = sum $ zipWith (*) a b
-- Vector length
vecLen :: Vec -> Float
vecLen = sqrt . sum . map (^2)
-- Unit vector
unit :: Vec -> Vec
unit a = map (/length) a
where length = vecLen a
-- Vector from one point to another
vecTo :: Vec -> Vec -> Vec
vecTo a b = zipWith (-) b a
-- Negate a vector
negVec :: Vec -> Vec
negVec = map negate
-- A vector of zeros
zeroVec :: Vec
zeroVec = repeat 0
-- Sum a list of vectors together
sumVecs :: [Vec] -> Vec
sumVecs = foldr (/+/) zeroVec
-- Converts a vector to a string delimited by spaces
vecToStr :: Vec -> String
vecToStr = concatMap ((++" ").show.floor)
vecToStr2 :: Vec -> String
vecToStr2 = map (chr . floor)
{-
--== MATRIX DEFINITION ==--
-}
-- A 4x4 matrix (A single list represented by (x + y*4))
type Mat = [Float]
-- Get a value in a matrix at a specific position
getMatVal :: Mat -> Int -> Int -> Float
getMatVal m x y = m !! (x+y*4)
-- Matrix-Vector multiplication
-- This assumes the Vec is |3|
matVecMul :: Mat -> Vec -> Vec
matVecMul m v = [rowMul x | x<-three]
where
rowMul col = sum [getMatVal m x col * (v!!x) | x<-three]
three = [0,1,2]
-- Matrix-Matrix multiplication
matMul :: Mat -> Mat -> Mat
matMul a b = [cij x y | y<-four,x<-four]
where
cij x y = sum [getMatVal a x n * getMatVal b n y | n <- four]
four = [0..3]
matXRotation :: Float -> Mat
matXRotation ang = [
1, 0, 0, 0,
0, c,-s, 0,
0, s, c, 0,
0, 0, 0, 1 ]
where
s = sin $ toRadians ang
c = cos $ toRadians ang
matYRotation :: Float -> Mat
matYRotation ang = [
c, 0, s, 0,
0, 1, 0, 0,
-s,0, c, 0,
0, 0, 0, 1 ]
where
s = sin $ toRadians ang
c = cos $ toRadians ang
matZRotation :: Float -> Mat
matZRotation ang = [
c,-s, 0, 0,
s, c, 0, 0,
0, 0, 1, 0,
0, 0, 0, 1 ]
where
s = sin $ toRadians ang
c = cos $ toRadians ang
matRotation :: Vec -> Mat
matRotation [x,y,z] = matXRotation x `matMul` matYRotation y `matMul` matZRotation z
matRotation _ = [] -- should never happen
{-
--== OBJECT DEFINITIONS ==--
-}
-- Define different renderable objects
data Object3D =
Sphere {pos::Vec, radius::Float, color::Vec, reflective::Float} |
Plane {pos::Vec, norm::Vec, color::Vec, reflective::Float}
deriving (Eq, Show)
-- A ray has a starting point and a direction
data Ray = Ray {origin::Vec, dir::Vec} deriving (Eq, Show)
-- Get the position where a ray intersected
getHitPos :: Ray -> Float -> Vec
getHitPos (Ray o dir) dist = o /+/ (dist /*/ dir)
data Camera = Camera {camPos::Vec, camRot::Vec} deriving (Eq,Show)
data Light = Light {lightPos::Vec, lightIntensity::Float, lightColor::Vec}
-- Set of objects and light sources
data World = World [Object3D] [Light]
-- A single ray could intersect with multiple objects.
-- It could also pass through a single object multiple times.
-- This function takes a ray and a list of objects then returns
-- a list of all intersections and the distance to the intersection with the object.
rayObjectIntersections :: Ray -> World -> [([Float], Object3D)]
rayObjectIntersections r (World objs _) = [(rayIntersection r obj, obj) | obj <- objs, not $ null $ rayIntersection r obj]
rayObjNormal :: Ray -> Vec -> Object3D -> Vec
rayObjNormal (Ray _ rayDir) hitPos s@Sphere {} =
pos s `vecTo` hitPos
rayObjNormal (Ray _ rayDir) hitPos p@Plane {}
| rayDir /./ norm p < 0 = norm p -- test for which face the ray hit
| otherwise = negVec $ norm p
-- The reflected ray when it hits an object
-- The Ray, The distance to the object, The object -> Reflected Ray
rayReflection :: Ray -> Float -> Object3D -> Ray
rayReflection r@(Ray _ rayDir) dist obj = Ray startVec refVec
where
hitPos = getHitPos r dist
normal = rayObjNormal r hitPos obj
dotP = rayDir /./ normal
refVec = unit (rayDir /-/ ((2*dotP)/*/normal))
startVec = hitPos /+/ (0.01 /*/ refVec)
-- ray, object, return distances to intersection
-- an empty list means it did not intersect
rayIntersection :: Ray -> Object3D -> [Float]
-- https://en.wikipedia.org/wiki/Line%E2%80%93sphere_intersection
rayIntersection r s@Sphere {}
| nabla < 0 = []
| nabla == 0 = filter (>=0) [dfh]
| otherwise = filter (>=0) [dist (-), dist (+)]
where
nabla = (uv /./ oSubC)^2 - vecLen oSubC^2 + radius s^2
uv = unit $ dir r
oSubC = origin r /-/ pos s
dfh = -(uv /./ oSubC)
dist sign = dfh `sign` sqrt nabla
-- https://en.wikipedia.org/wiki/Line%E2%80%93plane_intersection
rayIntersection r p@Plane {}
| lDotN == 0 = []
| otherwise = filter (>=0) [d]
where
lDotN = dir r /./ norm p
d = ((pos p /-/ origin r) /./ norm p) / lDotN
{-
--== RUNNING SECTION ==--
-}
dimensions :: (Int, Int)
dimensions = (1280, 720)
fieldOfView :: Float
fieldOfView = 90
aspectRatio :: Float
aspectRatio = x / y
where
x = fromIntegral $ fst dimensions
y = fromIntegral $ snd dimensions
-- The multiplier of brightness in complete darkess
ambientCoeff :: Float
ambientCoeff = 0.5
-- The limit of how far a ray can render
rayLimit :: Float
rayLimit = 999
createRay :: Int -> Int -> Ray
createRay x y = Ray (camPos defaultCamera) direction
where
invWidth = 1 / fromIntegral width
invHeight = 1 / fromIntegral height
angle = tan (pi * 0.5 * fieldOfView / 180)
xx = (2*((fromIntegral x+0.5)*invWidth)-1)*angle*aspectRatio
yy = (1-2*((fromIntegral y+0.5)*invHeight))*angle
width = fst dimensions
height = snd dimensions
direction = matRotation (camRot defaultCamera) `matVecMul` unit [xx,yy,-1]
-- Creates a list of rays based on the dimensions of the image and the fov
generateRayMatrix :: [Ray]
generateRayMatrix = [createRay x y | y <- [0..height-1], x <- [0..width-1]]
where
width = fst dimensions
height = snd dimensions
-- Trace the ray and return the color of the pixel
-- Ray, World, Ray Depth -> Color
getColor :: Ray -> World -> Int -> Vec
getColor r w@(World objs lights) depth
| null objIntersections = [0,0,0] -- did not intersect
| reflectivity > 0 && depth >= 0 = reflect -- switch between pure reflection and partial
| otherwise = diffuse
where
objIntersections = rayObjectIntersections r w
closestObj = getClosestObj objIntersections rayLimit (snd (head objIntersections))
reflectedRay = uncurry (rayReflection r) closestObj -- the ray reflected about the object normal
reflectivity = reflective (snd closestObj) -- the fraction of reflectivity of the object
diffuse = getDiffuse r w (snd closestObj) (getHitPos r (fst closestObj))
onlyReflect = getColor reflectedRay w (depth-1) -- pure reflection
reflect | reflectivity == 1 = onlyReflect
| otherwise = ((1-reflectivity) /*/ diffuse) /+/ (reflectivity /*/ onlyReflect) -- mixed reflection
-- Get the closest object to the camera
-- A list of intersected objects and their distances with an initial distance and object
getClosestObj :: [([Float], Object3D)] -> Float -> Object3D -> (Float, Object3D)
getClosestObj [(dist, obj)] minDist minObj -- only one object
| minimum dist < minDist = (minimum dist, obj)
| otherwise = (minDist, minObj)
getClosestObj ((dist, obj):xs) minDist minObj
| minimum dist < minDist = getClosestObj xs (minimum dist) obj
| otherwise = getClosestObj xs minDist minObj
getClosestObj _ _ _ = undefined -- should never reach here
-- Diffuse colors
getDiffuse :: Ray -> World -> Object3D -> Vec -> Vec
getDiffuse r@(Ray _ rayDir) w@(World _ lights) obj hitPos = baseColor /+/ finalLightTotal
where
baseColor = ambientCoeff /*/ color obj
lvec l = unit (hitPos `vecTo` lightPos l) -- unit vector from hit to light
shadowRay l = Ray (hitPos /+/ (0.01 /*/ lvec l)) (lvec l) -- may need to test for performance
isNotInShadow l = null $ rayObjectIntersections (shadowRay l) w -- is another object between obj and light
objLightDotPod l = unit (rayObjNormal r hitPos obj) /./ lvec l -- dot product between object normal and light
lightCount = fromIntegral (length lights)
lightAddition l = (lightIntensity l * objLightDotPod l) /*/ lightColor l -- how much color to add to the pixel
totalLightAddition = sumVecs [lightAddition l | l<-lights, isNotInShadow l, objLightDotPod l > 0] -- all lights added together
finalLightTotal = ((1-ambientCoeff) / lightCount ) /*/ totalLightAddition
main :: IO ()
main = do
-- Print PPM header
putStr $ fromString "P6 "
putStr $ fromString (show (fst dimensions)++" "++show (snd dimensions))
putStr $ fromString " 255 "
-- Print image data
putStr $ fromString $ concatMap (\x -> vecToStr2 $ getColor x testWorld 4) generateRayMatrix
{-
--== SCENE DEFINITION ==--
-}
defaultCamera :: Camera
defaultCamera = Camera [0,1,0.1] [-10,0,0] -- up/down, left/right, roll
testPlane :: Object3D
testPlane = Plane [0,0,0] [0,1,0] [120,0,120] 0
testPlane2 :: Object3D
testPlane2 = Plane [-5,0,-5] [-1,-1.2,-0.5] [0,0,120] 0
testSphere :: Object3D
testSphere = Sphere [3,0.6,-2] 1 [0,120,120] 0.5
testSphere2 :: Object3D
testSphere2 = Sphere [2,5.5,-8] 1.5 [0,120,0] 0.5
testSphere3 :: Object3D
testSphere3 = Sphere [-6,3,-6] 2 [120,0,0] 0.5
testSphere4 :: Object3D
testSphere4 = Sphere [1,1.5,-10] 2 [120,120,120] 1
testLight :: Light
testLight = Light [0,100,0] 1 [255,255,255]
testWorld :: World
testWorld = World [testPlane,testSphere,testSphere2,testPlane2,testSphere3,testSphere4] [testLight]