build.gradle

plugins {
    id "java"
    id "org.jetbrains.kotlin.jvm" version "1.9.0"
    id "maven-publish"
    id "com.github.johnrengelman.shadow" version "7.1.2"
}

if (hasProperty("buildScan")) {
    buildScan {
        termsOfServiceUrl = "https://gradle.com/terms-of-service"
        termsOfServiceAgree = "yes"
    }
}

static def determineVersion(String defaultVersion) {
    def envVersion = System.getenv("VERSION")
    return envVersion == null ? defaultVersion : envVersion
}

group = "dev.mikchan.mcnp"
version = determineVersion("1.0.0")

repositories {
    mavenCentral()

    maven {
        name = "spigotmc-repo"
        url = "https://hub.spigotmc.org/nexus/content/repositories/snapshots/"
    }

    maven {
        name = "sonatype"
        url = "https://oss.sonatype.org/content/groups/public/"
    }

    maven {
        name = "aikar"
        url = "https://repo.aikar.co/content/groups/aikar/"
    }
}

dependencies {
    compileOnly "org.spigotmc:spigot-api:1.20.1-R0.1-SNAPSHOT"

    implementation "org.jetbrains.kotlin:kotlin-stdlib:1.9.0"

    implementation "co.aikar:acf-paper:0.5.1-SNAPSHOT"
    shadow "co.aikar:acf-paper:0.5.1-SNAPSHOT"
}

def targetJavaVersion = 17
java {
    def javaVersion = JavaVersion.toVersion(targetJavaVersion)
    sourceCompatibility = javaVersion
    targetCompatibility = javaVersion
    if (JavaVersion.current() < javaVersion) {
        toolchain.languageVersion = JavaLanguageVersion.of(targetJavaVersion)
    }

    withSourcesJar()
}

tasks.withType(JavaCompile).configureEach {
    if (targetJavaVersion >= 10 || JavaVersion.current().isJava10Compatible()) {
        options.release = targetJavaVersion
    }
}

processResources {
    def props = [version: version]
    inputs.properties props
    filteringCharset "UTF-8"
    filesMatching("plugin.yml") {
        expand props
    }
}
compileKotlin {
    kotlinOptions {
        jvmTarget = targetJavaVersion
    }
}
compileTestKotlin {
    kotlinOptions {
        jvmTarget = targetJavaVersion
    }
}

shadowJar {
    archiveClassifier.set(null)

    dependencies {
        include(dependency("co.aikar:acf-paper"))
    }

    relocate "co.aikar.commands", "dev.mikchan.mcnp.badapple.shadow.co.aikar.commands"
    relocate "co.aikar.locales", "dev.mikchan.mcnp.badapple.shadow.co.aikar.locales"
}

publishing {
    repositories {
        maven {
            name = "GitHub"
            url = "https://maven.pkg.github.com/MikChanNoPlugins/BadApple"
            credentials {
                username = project.findProperty("gpr.user") ?: System.getenv("GITHUB_ACTOR")
                password = project.findProperty("gpr.key") ?: System.getenv("GITHUB_TOKEN")
            }
        }
    }

    publications {
        gpr(MavenPublication) {
            groupId = group
            artifactId = "bad-apple"

            artifact jar
            // artifact javadocJar
            artifact sourcesJar
        }
    }
}