yubikey-touch-detector: move from programs to services, add packages

Since yubikey-touch-detector is more of a service running in the
background, I propose to move to the services section under misc.
I also added a package option to enable custom packages to be run
instead of the default one.

Author: arunoruto

nixos/modules/module-list.nix

@@ -870,6 +870,7 @@
   ./services/misc/weechat.nix
   ./services/misc/workout-tracker.nix
   ./services/misc/xmrig.nix
+  ./services/misc/yubikey-touch-detector.nix
   ./services/misc/zoneminder.nix
   ./services/misc/zookeeper.nix
   ./services/monitoring/alerta.nix

nixos/modules/programs/yubikey-touch-detector.nix

@@ -43,21 +43,13 @@ in
   };
 
   config = lib.mkIf cfg.enable {
-    systemd.packages = [ pkgs.yubikey-touch-detector ];
-
-    systemd.user.services.yubikey-touch-detector = {
-      path = [ pkgs.gnupg ];
-
-      environment = {
-        YUBIKEY_TOUCH_DETECTOR_LIBNOTIFY = builtins.toString cfg.libnotify;
-        YUBIKEY_TOUCH_DETECTOR_NOSOCKET = builtins.toString (!cfg.unixSocket);
-        YUBIKEY_TOUCH_DETECTOR_VERBOSE = builtins.toString cfg.verbose;
-      };
-
-      wantedBy = [ "graphical-session.target" ];
-    };
-    systemd.user.sockets.yubikey-touch-detector = {
-      wantedBy = [ "sockets.target" ];
-    };
+    services.yubikey-touch-detector = cfg;
+
+    warnings = [
+      ''
+        The module programs.yubikey-touch-detector is deprecated.
+        Please use services.yubikey-touch-detector instead.
+      ''
+    ];
   };
 }

nixos/modules/services/misc/yubikey-touch-detector.nix

@@ -0,0 +1,63 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+let
+  inherit (lib) types;
+  cfg = config.services.yubikey-touch-detector;
+in
+{
+  options.services.yubikey-touch-detector = {
+
+    enable = lib.mkEnableOption "yubikey-touch-detector";
+
+    package = lib.mkPackageOption pkgs "yubikey-touch-detector" { };
+
+    libnotify = lib.mkOption {
+      # This used to be true previously and using libnotify would be a sane default.
+      default = true;
+      type = types.bool;
+      description = ''
+        If set to true, yubikey-touch-detctor will send notifications using libnotify
+      '';
+    };
+
+    unixSocket = lib.mkOption {
+      default = true;
+      type = types.bool;
+      description = ''
+        If set to true, yubikey-touch-detector will send notifications to a unix socket
+      '';
+    };
+
+    verbose = lib.mkOption {
+      default = false;
+      type = types.bool;
+      description = ''
+        Enables verbose logging
+      '';
+    };
+
+  };
+
+  config = lib.mkIf cfg.enable {
+    systemd.packages = [ cfg.package ];
+
+    systemd.user.services.yubikey-touch-detector = {
+      path = [ pkgs.gnupg ];
+
+      environment = {
+        YUBIKEY_TOUCH_DETECTOR_LIBNOTIFY = builtins.toString cfg.libnotify;
+        YUBIKEY_TOUCH_DETECTOR_NOSOCKET = builtins.toString (!cfg.unixSocket);
+        YUBIKEY_TOUCH_DETECTOR_VERBOSE = builtins.toString cfg.verbose;
+      };
+
+      wantedBy = [ "graphical-session.target" ];
+    };
+    systemd.user.sockets.yubikey-touch-detector = {
+      wantedBy = [ "sockets.target" ];
+    };
+  };
+}