build.gradle

import org.jetbrains.kotlin.gradle.dsl.JvmTarget

plugins {
    id 'org.jetbrains.kotlin.jvm' version '2.0.10'
    id "org.jetbrains.kotlin.kapt" version "2.0.10"
    id 'com.gradleup.shadow' version '8.3.0'
}

group 'one.oktw'
version '1.0-SNAPSHOT'

repositories {
    mavenCentral()
    maven { url = "https://jitpack.io" }
    maven {
        name 'papermc'
        url 'https://repo.papermc.io/repository/maven-public/'
    }
    maven {
        name 'adventure'
        url 'https://s01.oss.sonatype.org/content/repositories/snapshots/'
    }
}

dependencies {
    kapt 'com.velocitypowered:velocity-api:3.3.0-SNAPSHOT'
    compileOnly 'com.velocitypowered:velocity-api:3.3.0-SNAPSHOT'
    implementation 'io.fabric8:kubernetes-client:6.13.3'
    implementation 'io.fabric8:kubernetes-httpclient-okhttp:6.13.3'
    implementation 'com.github.fkorotkov:k8s-kotlin-dsl:3.3.0'
    implementation 'io.lettuce:lettuce-core:6.4.0.RELEASE'
    implementation 'org.jetbrains.kotlinx:kotlinx-coroutines-reactive' // lettuce need this
    implementation 'one.oktw:galaxy-lib:7376fcdf'
}

compileKotlin {
    compilerOptions.jvmTarget = JvmTarget.JVM_21
}

tasks.withType(AbstractArchiveTask).configureEach {
    preserveFileTimestamps = false
    reproducibleFileOrder = true
}

shadowJar {
    archiveClassifier.set('')
    minimize {
        exclude(dependency('io.fabric8:kubernetes-client:.*'))
    }
    exclude '*.aut'
    exclude '*.properties'
    exclude 'OSGI-INF'
    exclude 'schema'
}

jar.enabled = false
build.dependsOn(shadowJar)