Provide consistent MAC addresses for macvlans

This gives DHCP a consistent handle so the address won't change every
time I reboot.

Author: PsychoLlama

lib/define-host.nix

@@ -13,6 +13,19 @@ let
   inherit (config.lab) domain datacenter;
   home = config.home-manager.users.root;
 
+  # Chunk a list into sublists of a specified size.
+  #
+  # chunkBy 2 [ 1 2 3 4 ] -> [ [ 1 2 ] [ 3 4 ] ]
+  chunkBy =
+    size: list:
+    if list == [ ] then
+      [ ]
+    else
+      [
+        (lib.take size list)
+      ]
+      ++ chunkBy size (lib.drop size list);
+
   # Proxy all network traffic through a macvlan interface. This allows the
   # host to communicate with containers using macvlans and vice versa.
   #
@@ -28,6 +41,40 @@ let
         mode = "bridge";
         interface = config.lab.host.interface;
       };
+
+      # Provide a stable MAC address to preserve the DHCP lease.
+      interfaces.mv-primary.macAddress = lib.pipe config.networking.hostName [
+        # Use the hostname hash to derive the MAC address.
+        (builtins.hashString "md5")
+
+        # [ "" "f" "0" .. "1" "e" "" ]
+        (lib.splitString "")
+
+        # [ "f" "0" .. "1" "e" ]
+        (lib.filter (char: char != ""))
+
+        # Take the first 12 characters (for a 6-byte MAC address).
+        (lib.take 12)
+
+        # [ 15 0 .. 1 14 ]
+        (map lib.fromHexString)
+
+        # Make sure the last bits of the first byte are `0b10` to indicate
+        # a locally-administered unicast MAC address.
+        (lib.imap0 (index: value: if index == 1 then lib.bitAnd (-2) (lib.bitOr value 2) else value))
+
+        # [ "F" "2" .. "1" "E" ]
+        (map lib.toHexString)
+
+        # [ [ 15 2 ] .. [ 1 14 ] ]
+        (chunkBy 2)
+
+        # [ "F2" .. "1E" ]
+        (lib.map (lib.concatStringsSep ""))
+
+        # "F2:<...>:1E"
+        (lib.concatStringsSep ":")
+      ];
     };
   };