Merge pull request #11 from PsychoLlama/feature/autojump-support

Feature: autojump support

Author: PsychoLlama

README.md

@@ -80,6 +80,13 @@ it.
 ### [zoxide](https://github.com/ajeetdsouza/zoxide)
 Zoxide is automatically detected - you don't have to do anything.
 
+### [autojump](https://github.com/wting/autojump)
+In order to get the `j` alias, you're probably sourcing an autojump file in
+your bash/zsh/fish setup. Find that file and set it in your vimrc:
+```viml
+let teleport#path = expand('~/path/to/autojump.sh')
+```
+
 ### Setting the integration
 If you have more than one of these installed (why???) there's a chance
 `teleport.vim` could choose the wrong one. You can force it to use
@@ -89,6 +96,7 @@ a particular driver by setting `teleport#driver`.
 let teleport#driver = 'z' " rupa/z
 let teleport#driver = 'z.lua' " skywind3000/z.lua
 let teleport#driver = 'zoxide' " ajeetdsouza/zoxide
+let teleport#driver = 'autojump' " wting/autojump
 ```
 
 If you don't see your favorite program listed here, feel free to [open

autoload/teleport/driver.vim

@@ -7,6 +7,7 @@ let s:drivers = {}
 let s:drivers.z = teleport#drivers#rupaz#()
 let s:drivers['z.lua'] = teleport#drivers#zlua#()
 let s:drivers.zoxide = teleport#drivers#zoxide#()
+let s:drivers.autojump = teleport#drivers#autojump#()
 let s:drivers.test = teleport#drivers#test#()
 
 func! s:get_driver_setting() abort

autoload/teleport/drivers/autojump.vim

@@ -0,0 +1,27 @@
+let s:autojump = { 'name': 'autojump' }
+
+func! s:autojump.is_supported() abort
+  if !executable('autojump') || !exists('g:teleport#path')
+    return 0
+  endif
+
+  let l:path_matches = fnamemodify(g:teleport#path, ':t') is# 'autojump.sh'
+  let l:explicitly_set_driver = get(g:, 'teleport#driver', v:null) is# 'autojump'
+  return l:path_matches || l:explicitly_set_driver
+endfunc
+
+func! s:autojump.query(search_term) abort
+  let l:output = s:exec_query(a:search_term)
+  return teleport#parse_output#autojump(a:search_term, l:output)
+endfunc
+
+func! teleport#drivers#autojump#() abort
+  return deepcopy(s:autojump)
+endfunc
+
+func! s:exec_query(search_term) abort
+  let l:cmd = 'source ' . fnameescape(g:teleport#path) . '; '
+  let l:cmd .= 'autojump --complete ' . fnameescape(a:search_term)
+
+  return systemlist(l:cmd)
+endfunc

autoload/teleport/parse_output.vim

@@ -30,3 +30,50 @@ endfunc
 func! teleport#parse_output#zlua(output) abort
   return teleport#parse_output#z(a:output)
 endfunc
+
+" Sample output (contains duplicates):
+" search-term__1__/path/to/result-1
+" search-term__2__/path/to/result-2
+" search-term__3__/path/to/result-3
+" search-term__4__/path/to/result-1
+" search-term__5__/path/to/result-2
+" search-term__6__/path/to/result-4
+func! teleport#parse_output#autojump(search_term, output) abort
+  let l:results = []
+
+  for l:line in a:output
+    let l:line_without_prefix = l:line[strlen(a:search_term):]
+    let [l:rank, l:directory] = split(l:line_without_prefix, '__')
+    call add(l:results, { 'frecency': str2float(l:rank), 'directory': l:directory })
+  endfor
+
+  call sort(l:results, function('s:order_by_directory_name'))
+  call uniq(l:results, function('s:filter_duplicates'))
+  call sort(l:results, function('s:order_by_rank'))
+  call map(l:results, function('s:set_rank_by_index', [copy(l:results)]))
+
+  return l:results
+endfunc
+
+func! s:order_by_directory_name(first, second) abort
+  if a:first.directory is# a:second.directory
+    return 0
+  endif
+
+  return a:first.directory > a:second.directory ? -1 : 1
+endfunc
+
+func! s:filter_duplicates(first, second) abort
+  return a:first.directory isnot# a:second.directory
+endfunc
+
+func! s:order_by_rank(first, second) abort
+  return float2nr(a:first.frecency - a:second.frecency)
+endfunc
+
+" As you might've noticed, the command doesn't reveal frecency. The best we
+" can do is approximate by the order it occurs in search results.
+func! s:set_rank_by_index(results, index, result) abort
+  let a:result.frecency = len(a:results) - a:index + 0.0
+  return a:result
+endfunc

autoload/teleport/tests/parse_output.vader

@@ -1,3 +1,4 @@
+### rupa/z
 Execute (returns a list):
   let output = teleport#parse_output#z([])
   silent AssertEqual v:t_list, type(output)
@@ -27,11 +28,34 @@ Execute (orders the output by frecency):
 # common: /some/file/path
 # That information is already obvious from frecency.
 Execute (ignores suggestions for common directories):
-  let output = teleport#parse_output#z( [
+  let output = teleport#parse_output#z([
     \   'common:    /first/file',
     \   '0.555      /second/file',
     \   '555.123    /first/file',
     \ ])
 
   silent AssertEqual 2, len(output)
   silent AssertEqual '/first/file', output[0].directory
+
+### autojump
+Execute (removes duplicates):
+  let output = teleport#parse_output#autojump('prefix', [
+    \   'prefix__1__/path/to/duplicate',
+    \   'prefix__2__/path/to/duplicate',
+    \   'prefix__3__/path/to/duplicate',
+    \ ])
+
+  AssertEqual [{ 'frecency': 1.0, 'directory': '/path/to/duplicate' }], output
+
+Execute (removes intermingled duplicates):
+  let output = teleport#parse_output#autojump('prefix', [
+  \   'prefix__1__/first',
+  \   'prefix__2__/second',
+  \   'prefix__3__/first',
+  \   'prefix__4__/third',
+  \ ])
+
+  let expected = [{ 'frecency': 3.0, 'directory': '/first' }]
+  call add(expected, { 'frecency': 2.0, 'directory': '/second' })
+  call add(expected, { 'frecency': 1.0, 'directory': '/third' })
+  AssertEqual expected, output

doc/tags

@@ -1,3 +1,4 @@
+autojump	teleport.txt	/*autojump*
 teleport#api#find_match()	teleport.txt	/*teleport#api#find_match()*
 teleport#api#find_matches()	teleport.txt	/*teleport#api#find_matches()*
 teleport#api#query()	teleport.txt	/*teleport#api#query()*

doc/teleport.txt

@@ -3,7 +3,7 @@
 Author:        Jesse Gibson <JesseTheGibson@gmail.com>
 Homepage:      https://github.com/PsychoLlama/teleport.vim
 License:       MIT
-Tags:          *z.sh* *zoxide* *z.lua* *z.vim* (old plugin name)
+Tags:          *z.sh* *zoxide* *z.lua* *autojump* *z.vim* (old plugin name)
 
 
     Press `gO` to show a table of contents.
@@ -17,6 +17,7 @@ If you're using this plugin, chances are you've installed one of these tools:
 - https://github.com/rupa/z
 - https://github.com/skywind3000/z.lua
 - https://github.com/ajeetdsouza/zoxide
+- https://github.com/wting/autojump
 
 They all do pretty much the same thing: they learn your most common
 directories, and when given a pattern, they jump to the most likely match.
@@ -59,6 +60,7 @@ These are your options:
 - `z`
 - `z.lua`
 - `zoxide`
+- `autojump`
 
 rupa/z~
 >
@@ -75,6 +77,11 @@ zoxide~
   " Uses the global command "zoxide".
   let teleport#driver = 'zoxide'
 <
+autojump~
+>
+  let teleport#path = expand('~/path/to/autojump.sh')
+  let telport#driver = 'autojump'
+<
 ------------------------------------------------------------------------------
 OPTIONS                                                       *teleport-options*
 
@@ -178,5 +185,10 @@ Changed:
 Added:
 - New |teleport#update_cwd| option.
 
+0.6.0 - UNRELEASED~
+
+Added:
+- Experimental autojump support.
+
 ==============================================================================
 vim: ft=help tw=78: