generated from FabricMC/fabric-example-mod
-
-
Notifications
You must be signed in to change notification settings - Fork 16
/
build.gradle
260 lines (219 loc) · 7.4 KB
/
build.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
plugins {
id "dev.architectury.loom" version "1.7-SNAPSHOT"
id "architectury-plugin" version "3.4-SNAPSHOT"
id "com.modrinth.minotaur"
}
base {
archivesName = project.archives_base_name
}
var String loader = loom.platform.get().displayName.toLowerCase()
var String mcVersion = stonecutter.current.version
var isFabric = loader == "fabric"
var isNeoForge = loader == "neoforge"
var isForge = loader == "forge"
// The current stonecutter version (0.4) has an issue with groovy gradle which makes
// stonecutter.configureEach { stonecutter.const(...) } not work correctly inside stonecutter.gradle.
// Putting it here fixes the problem.
stonecutter.const("fabric", isFabric)
stonecutter.const("neoforge", isNeoForge)
stonecutter.const("forge", isForge)
static def buildVersionString(String modVersion, String releaseType, String mcVersion, String loader) {
var semver = modVersion
var isPrerelease = releaseType != "release"
if (isPrerelease) semver += "-" + releaseType
semver += "+" + mcVersion + "-" + loader
if (isPrerelease) semver += ".rev." + 'git rev-parse --short HEAD'.execute().text.trim()
return semver
}
static def trimSuffix(String original, String suffix) {
if(original.endsWith(suffix)) {
return original.substring(0, original.length() - suffix.length())
}
return original
}
version = buildVersionString(property('mod.version').toString(), property('mod.release').toString().toLowerCase(), mcVersion, loader)
group = project.maven_group
architectury {
minecraft = mcVersion
platformSetupLoomIde()
if (isFabric)
fabric()
if (isForge)
forge()
if (isNeoForge)
neoForge()
}
repositories {
maven {
name = "TerraformersMC"
url = "https://maven.terraformersmc.com/releases/"
}
maven {
name = "Modrinth"
url = "https://api.modrinth.com/maven"
content {
includeGroup "maven.modrinth"
}
}
maven {
name = "Xander"
url = "https://maven.isxander.dev/releases"
}
maven {
name = 'NeoForged'
url = 'https://maven.neoforged.net/releases'
}
maven { url "https://maven.quiltmc.org/repository/release" }
}
loom {
accessWidenerPath.set(project.rootProject.file("src/main/resources/betterclouds.accesswidener"))
runConfigs.configureEach {
ideConfigGenerated true
runDir "../../run"
}
if (isForge) forge {
convertAccessWideners.set(true)
mixinConfigs(
"betterclouds.mixins.json",
"betterclouds.optional.mixins.json",
)
}
}
dependencies {
// To change the versions see the gradle.properties file
minecraft "com.mojang:minecraft:$mcVersion"
mappings loom.layered {
it.mappings("net.fabricmc:yarn:${property('loom.yarn')}:v2")
if (property('loom.yarn_patch_neoforge') != "") {
it.mappings("dev.architectury:yarn-mappings-patch-neoforge:${property('loom.yarn_patch_neoforge')}")
}
}
if (isFabric) {
modImplementation "net.fabricmc:fabric-loader:${property('loader.fabric')}"
modImplementation "net.fabricmc.fabric-api:fabric-api:${property("deps.fabric_api")}"
modImplementation "com.terraformersmc:modmenu:${property('deps.modmenu')}"
modImplementation "dev.isxander:yet-another-config-lib:${property('deps.yacl')}-fabric"
modCompileOnly "maven.modrinth:sodium-extra:${property('deps.sodium_extra')}"
modCompileOnly "maven.modrinth:iris:${property('deps.iris')}"
}
if (isNeoForge || isForge) {
if (isNeoForge)
neoForge "net.neoforged:neoforge:${property('loader.neoforge')}"
if (isForge)
forge "net.minecraftforge:forge:${property('loader.forge')}"
modImplementation("dev.isxander:yet-another-config-lib:${property('deps.yacl')}-neoforge") {
transitive = false
}
// These should be included with yacl, but it doesn't work correctly, so adding them here
forgeRuntimeLibrary(runtimeOnly("org.quiltmc.parsers:json:0.2.1"))
forgeRuntimeLibrary(runtimeOnly("org.quiltmc.parsers:gson:0.2.1"))
modCompileOnly "maven.modrinth:rubidium-extra:0.5.7e+mc1.21-build.129"
modCompileOnly "maven.modrinth:oculus:1.20.1-1.7.0"
// Because yarn mappings are used the mods can't be loaded from the 'mods' directory at runtime.
// It causes NoClassDefFoundErrors due to the different mappings.
// This is a workaround that uses 'modLocalRuntime' to remap the mods found in the 'mods-forge' directory.
// It requires a project reload when the mods change.
if(stonecutter.current.isActive) {
def localModsDir = project.rootProject.file('./run/mods-forge/')
if (localModsDir.exists() && localModsDir.isDirectory()) {
def localMods = localModsDir
.listFiles({ file -> file.isFile() && file.name.endsWith('.jar') } as FileFilter)
localMods.each { mod ->
println "Added Forge Mod: " + mod.name
dependencies {
modLocalRuntime files(mod)
}
}
}
}
}
compileOnly "maven.modrinth:distanthorizonsapi:3.0.0"
}
processResources {
var props = [
version: project.version,
]
if (isFabric) {
props["mc_version_range"] = findProperty("deps.minecraft").toString().split(",").collect {
"\"=$it\""
}.join(", ")
} else {
props["mc_version_range"] = findProperty("deps.minecraft").toString().split(",").collect {
"[$it]"
}.join(",")
}
props.forEach(inputs::property)
filesMatching(["fabric.mod.json", "META-INF/mods.toml", "META-INF/neoforge.mods.toml"]) {
expand props
}
if(isNeoForge || isForge)
exclude("fabric.mod.json")
if(isFabric)
exclude("META-INF/mods.toml", "META-INF/neoforge.mods.toml")
exclude("assets/**/*.ase")
exclude("assets/**/*.xcf")
}
remapJar {
if (isNeoForge) {
atAccessWideners.add("betterclouds.accesswidener")
}
}
stonecutter {
var j21 = eval(mcVersion, ">=1.20.6")
tasks.withType(JavaCompile).configureEach {
it.options.release = j21 ? 21 : 17
}
java {
withSourcesJar()
sourceCompatibility = j21 ? JavaVersion.VERSION_21 : JavaVersion.VERSION_17
targetCompatibility = j21 ? JavaVersion.VERSION_21 : JavaVersion.VERSION_17
}
}
if (stonecutter.current.isActive) {
rootProject.tasks.register("buildActive") {
group = "project"
dependsOn(tasks.named("build"))
}
}
jar {
from(project.rootProject.file("LICENSE").path) {
rename { "${it}_${project.archives_base_name}"}
}
}
modrinth { // Make sure it runs after build!
var loaderName = loom.platform.get().displayName
var releaseName = property('mod.release').toString().capitalize()
var releaseLetter = property('mod.release').toString().toLowerCase().substring(0, 1)
def secrets = new Properties()
project.rootProject.file("secrets.properties").withInputStream {
stream -> secrets.load(stream)
}
token.set(secrets.MODRINTH as String)
projectId = '5srFLIaK'
// Will fail if Modrinth has this version alread
versionNumber = "${property('mod.version')}+${mcVersion}-${loader}-${releaseLetter}"
versionName = "${releaseName} ${property('mod.version')} for ${mcVersion} ${loaderName}"
versionType = "${property('mod.release')}"
uploadFile = remapJar
gameVersions = findProperty("deps.minecraft").toString().split(",").collect { trimSuffix(it, ".0")}
loaders.add(loader)
dependencies {
// A special DSL for creating dependencies
// scope.type
// The scope can be `required`, `optional`, `incompatible`, or `embedded`
// The type can either be `project` or `version`
required.version "yacl", "${property('deps.yacl')}-${loader}"
if(isFabric) {
required.project "fabric-api"
optional.project "modmenu"
incompatible.project "vulkanmod"
}
if(isFabric || stonecutter.eval(mcVersion, ">=1.21")) {
optional.project "sodium"
optional.project "iris"
} else {
optional.project "embeddium"
optional.project "oculus"
}
}
}