MultiSigWallet.sol

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.10;

contract MultiSigWallet {
    event Deposit(address indexed sender, uint amount);
    event Submit(uint indexed txId);
    event Approve(address owner, uint indexed txId);
    event Revoke(address indexed owner, uint indexed txId);
    event Execute(uint indexed txId);

    // Structure of transaction
    struct Transaction {
        address to;
        uint value;
        bytes data;
        bool executed;
    }

    // Storing owners
    address[] public owners;
    // Checking owners
    mapping(address => bool) public isOwner;
    // no. approvels required for txn to execute
    uint public required;
    // Storing those transactions
    Transaction[] public transactions;
    // Storing approvel of each txn from each owners
    mapping(uint => mapping(address => bool)) public approved;

    // Owners
    modifier onlyOwner() {
        require(isOwner[msg.sender], "not owner");
        _;
    }

    // Checking the txns
    modifier txExists(uint _txId) {
        require(_txId < transactions.length, "tx does not exist");
        _;
    }

    // Checking the approval was already done
    modifier notApproved(uint _txId) {
        require(!approved[_txId][msg.sender], "tx already approved");
        _;
    }

    // Checking whether the txn is already executed
    modifier notExecuted(uint _txId) {
        require(!transactions[_txId].executed, "tx already executed");
        _;
    }

    constructor(address[] memory _owners, uint _required) {
        require(_owners.length > 0, "owners required");
        require(_required > 0 && _required <= _owners.length,
        "invalid required number of owners"
        );

        // Stating _owners to state variable owner
        for (uint i; i < _owners.length; i++) {
            address owner = _owners[i];
            
            require(owner != address(0), "invalid owner");
            // Checking for duplicate owners
            require( !isOwner[owner], "owner is not unique");

            isOwner[owner] = true;
            owners.push(owner);
        }

        required = _required;

    }

    receive() external payable {
        emit Deposit(msg.sender, msg.value);
    }

    // Function to submit transactions for approval
    function submit( address _to, uint _value, bytes calldata _data)
        external
        onlyOwner
        {
            transactions.push(Transaction({
                to: _to,
                value: _value,
                data: _data,
                executed: false
            }));
            emit Submit(transactions.length - 1);
        }

    // Function for each approval
    function approve(uint _txId)
        external
        onlyOwner
        txExists(_txId)
        notApproved(_txId)
        notExecuted(_txId)
        {
            approved[_txId][msg.sender] = true;
            emit Approve(msg.sender, _txId);
        }

    // Counting the number of approvals
    function _getApprovalCount(uint _txId) private view returns (uint count) {
        for (uint i; i < owners.length; i++) {
            if (approved[_txId][owners[i]]) {
                count += 1;
            }        
        }
    }

    // Function to execute transaction
    function execute(uint _txId) external txExists(_txId) notExecuted(_txId) {
        require(_getApprovalCount(_txId) >= required, "approvals count < required count");
        Transaction storage transaction = transactions[_txId];

        transaction.executed = true;

        (bool success, ) = transaction.to.call{value: transaction.value}(
            transaction.data
        );
        require(success, "tx failed");

        emit Execute(_txId);
    }

    // Function to revoke the txn
    function revoke(uint _txId) 
        external 
        onlyOwner
        txExists(_txId)
        notExecuted(_txId)
    {
        require(approved[_txId][msg.sender], "tx not approved");
        approved[_txId][msg.sender] = false;
        emit Revoke(msg.sender, _txId);
    }
}