build.gradle

plugins {
	id 'maven-publish'
	id 'fabric-loom' version '1.6-SNAPSHOT' apply false

	// https://github.com/ReplayMod/preprocessor
	// https://github.com/Fallen-Breath/preprocessor
	id 'com.replaymod.preprocess' version '88169fc'

	// https://github.com/Fallen-Breath/yamlang
	id 'me.fallenbreath.yamlang' version '1.3.1' apply false
}

preprocess {
	def mc114      = createNode('1.14.4'  , 1_14_04, 'yarn')
	def mc115      = createNode('1.15.2'  , 1_15_02, 'yarn')
	def mc116      = createNode('1.16.5'  , 1_16_05, 'yarn')
	def mc117      = createNode('1.17.1'  , 1_17_01, 'yarn')
	def mc118      = createNode('1.18.2'  , 1_18_02, 'yarn')
	def mc119      = createNode('1.19.4'  , 1_19_04, 'yarn')
	def mc120      = createNode('1.20.1'  , 1_20_01, 'yarn')
	def mc1202     = createNode('1.20.2'  , 1_20_02, 'yarn')
	def mc1204     = createNode('1.20.4'  , 1_20_04, 'yarn')
	def mc1206     = createNode('1.20.6'  , 1_20_06, 'yarn')
	def mc1211     = createNode('1.21.1'  , 1_21_01, 'yarn')
	def mc1213     = createNode('1.21.3'  , 1_21_03, 'yarn')
	def mc1214     = createNode('1.21.4'  , 1_21_04, 'yarn')

	mc1214.link(mc1213, null)
	mc1213.link(mc1211, null)
	mc1211.link(mc1206, null)
	mc1206.link(mc1204, null)
	mc1204.link(mc1202, null)
	mc1202.link(mc120 , null)
	mc120 .link(mc119 , null)
	mc119 .link(mc118 , null)
	mc118 .link(mc117 , null)
	mc117 .link(mc116 , null)
	mc116 .link(mc115 , null)
	mc115 .link(mc114 , null)
}

tasks.register('buildAndGather') {
	subprojects {
		dependsOn project.tasks.named('build').get()
	}
	doFirst {
		println 'Gathering builds'
		def buildLibs = {
			p -> p.buildDir.toPath().resolve('libs')
		}
		delete fileTree(buildLibs(rootProject)) {
			include '*'
		}
		subprojects {
			copy {
				from(buildLibs(project)) {
					include '*.jar'
					exclude '*-dev.jar', '*-sources.jar'
				}
				into buildLibs(rootProject)
				duplicatesStrategy DuplicatesStrategy.INCLUDE
			}
		}
	}
}