build.gradle

/*
 *                 Twidere - Twitter client for Android
 *
 *  Copyright (C) 2012-2015 Mariotaku Lee <mariotaku.lee@gmail.com>
 *
 *  This program is free software: you can redistribute it and/or modify
 *  it under the terms of the GNU General Public License as published by
 *  the Free Software Foundation, either version 3 of the License, or
 *  (at your option) any later version.
 *
 *  This program is distributed in the hope that it will be useful,
 *  but WITHOUT ANY WARRANTY; without even the implied warranty of
 *  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 *  GNU General Public License for more details.
 *
 *  You should have received a copy of the GNU General Public License
 *  along with this program.  If not, see <http://www.gnu.org/licenses/>.
 */

apply plugin: 'com.android.application'
apply plugin: 'com.neenbedankt.android-apt'

// Top-level build file where you can add configuration options common to all sub-projects/modules.
buildscript {
    repositories {
        jcenter()
        maven { url 'https://plugins.gradle.org/m2/' }
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:2.0.0'
        classpath 'com.neenbedankt.gradle.plugins:android-apt:1.8'
        // NOTE: Do not place your application dependencies here; they belong
        // in the individual module build.gradle files
    }
}

android {
    compileSdkVersion 23
    buildToolsVersion "23.0.3"

    defaultConfig {
        applicationId "org.mariotaku.twidere.extension.shortener.gist"
        minSdkVersion 14
        targetSdkVersion 23
        versionCode 1
        versionName "0.9"
    }
    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }

    buildTypes.each { buildType ->
        def file = rootProject.file('signing.properties')
        if (file.exists()) {
            def cfg = signingConfigs.maybeCreate(buildType.name)
            loadSigningConfig(cfg, file)
            buildType.signingConfig = cfg
        }
    }

    lintOptions {
        abortOnError false
    }
}

repositories {
    jcenter()
    mavenLocal()
    maven { url 'https://jitpack.io' }
}

dependencies {
    apt 'com.bluelinelabs:logansquare-compiler:1.3.7'
    compile 'com.github.mariotaku.RestFu:urlconnection:0.9.27'
    compile 'com.github.TwidereProject.Twidere-Android:twidere.library.extension:3.1.6'
    compile fileTree(dir: 'libs', include: ['*.jar'])
}

def loadSigningConfig(def cfg, def file) {
    Properties signingProp = new Properties()
    signingProp.load(file.newInputStream())
    cfg.setStoreFile(new File((String) signingProp.get('storeFile')))
    cfg.setStorePassword((String) signingProp.get('storePassword'))
    cfg.setKeyAlias((String) signingProp.get('keyAlias'))
    cfg.setKeyPassword((String) signingProp.get('keyPassword'))
}