build.gradle

plugins {
	id 'application'
	id 'eclipse'
	id 'org.beryx.jlink' version '2.23.5'
}

def currentOS = org.gradle.nativeplatform.platform.internal.DefaultNativePlatform.currentOperatingSystem;
def platform
if (currentOS.isWindows()) {
	 platform = 'win'
} else if (currentOS.isLinux()) {
	 platform = 'linux'
} else if (currentOS.isMacOsX()) {
	 platform = 'mac'
}

repositories {
	// Use JCenter for resolving dependencies.
	jcenter()
	mavenCentral()
}

java {
	modularity.inferModulePath = true
}

application {
	mainModule = 'ProjectModuleName'
	mainClass = 'com.company.project.App'
}

dependencies {
	implementation "org.openjfx:javafx-base:15.0.1:${platform}"
	implementation "org.openjfx:javafx-controls:15.0.1:${platform}"
	implementation "org.openjfx:javafx-fxml:15.0.1:${platform}"
	implementation "org.openjfx:javafx-graphics:15.0.1:${platform}"
	implementation "org.openjfx:javafx-media:15.0.1:${platform}"
	implementation "org.openjfx:javafx-web:15.0.1:${platform}"
}

eclipse {
	classpath {
		file {
			whenMerged {
				entries.findAll { it.properties.kind.equals('lib') }.each {
					it.entryAttributes['module'] = 'true'
				}
			}
		}
	}
}

jlink {
	
	options = ['--strip-debug', '--compress', '2', '--no-header-files', '--no-man-pages']
	
	jpackage {
		skipInstaller = true
	}
	
	launcher {
		name = 'BinaryName'
	}
}