-
Notifications
You must be signed in to change notification settings - Fork 10
/
ti2single.z80
117 lines (105 loc) · 1.47 KB
/
ti2single.z80
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
#ifndef included_ti2Single
#define included_ti2Single
#include "pushpop.z80"
#include "mov4.z80"
#include "mulSingle.z80"
#include "str2single.z80"
ti2single:
;converts a TI-float to a single precision float.
call pushpop
push bc
;Save the sign !
ld a,(hl)
add a,a
push af
;Save the base 10 exponent
inc hl
ld a,(hl)
push af
;Convert four bytes of the mantissa (BCD) to an 8-bit integer on [0,99].
;TI's is big-endian and we want little endian copied to scrap
ld de,scrap+3
ld b,4
_:
inc hl
ld a,(hl)
and $F0
rra
ld c,a
rra
rra
sub c
add a,(hl)
ld (de),a
dec de
djnz -_
;Now get 4 bytes of the binary float's mantissa
ld d,100
call scrap_times_256
ld a,c
push af
call scrap_times_256
push bc
call scrap_times_256
push bc
call scrap_times_256
ld l,c
pop bc
ld h,c
pop bc
pop af
;Now let's normalize our mantissa, ACHL
ld b,$7F
or a
jp m,ti2single_normalized
_:
dec b
add hl,hl
rl c
adc a,a
jp p,-_
ti2single_normalized:
;Our float is BACH.
ld l,h
ld h,c
add a,a
ld c,a
;Pop off the exponent.
pop de
;Pop off the sign
pop af
rr c
ld (scrap),hl
ld (scrap+2),bc
ld a,d
sub 7Fh
ld de,pow10LUT
jr nc,+_
neg
ld de,pown10LUT
cp 40
jp nc,strToSingle_zero
_:
cp 40
jp nc,strToSingle_inf+1
;
ld hl,scrap
ld b,h
ld c,l
call +_
call +_
call +_
call +_
call +_
call +_
pop de
jp mov4
_:
rra
call c,mulSingle
inc de
inc de
inc de
inc de
ret
#endif