Edt find/load/create changes

- edt file is now parsed only once per map load, this should improve perf
- ability to create default map config on missing edt
- added convar sourcecoop_default_config, sourcecoop_default_config_dest
- added command sc_mkconfigs

Author: Alienmario

scripting/include/srccoop/commands.inc

@@ -84,4 +84,79 @@ public Action Command_DumpMapEntities(int iArgs)
 		MsgSrv("Failed opening file for writing: %s", szDumpPath);
 	}
 	return Plugin_Handled;
+}
+
+public Action Command_MakeConfigs(int iArgs)
+{
+	char szBuffer[PLATFORM_MAX_PATH];
+	ServerExecute();
+
+	g_pConvarDefaultMapConfig.GetString(szBuffer, 2);
+	if (szBuffer[0] == EOS)
+	{
+		g_pConvarDefaultMapConfig.GetName(szBuffer, sizeof(szBuffer));
+		MsgSrv("Set \"%s\" before running this command.", szBuffer);
+		return Plugin_Handled;
+	}
+
+	g_pConvarDefaultMapConfigDest.GetString(szBuffer, 2);
+	if (szBuffer[0] == EOS)
+	{
+		g_pConvarDefaultMapConfigDest.GetName(szBuffer, sizeof(szBuffer));
+		MsgSrv("Set \"%s\" before running this command.", szBuffer);
+		return Plugin_Handled;
+	}
+
+	DirectoryListing dir = OpenDirectory("maps", true);
+	if (!dir)
+	{
+		MsgSrv("Unable to enumerate maps folder.");
+		return Plugin_Handled;
+	}
+
+	bool bDryRun = !GetCmdArgInt(1);
+	int count;
+	FileType ft;
+	CoopConfigLocation ccl;
+	char szConfigPath[PLATFORM_MAX_PATH];
+
+	while (dir.GetNext(szBuffer, sizeof(szBuffer), ft))
+	{
+		int len = strlen(szBuffer); 
+		if (ft == FileType_File && StrEndsWithEx(szBuffer, len, ".bsp", false))
+		{
+			szBuffer[len - 4] = EOS;
+			if (!CoopManager.FindMapConfig(szBuffer, szConfigPath, ccl, false))
+			{
+				if (!bDryRun)
+				{
+					if (!CoopManager.CreateDefaultConfig(szBuffer, szConfigPath))
+					{
+						dir.Close();
+						MsgSrv("Aborted processing.");
+						return Plugin_Handled;
+					}
+				}
+				count++;
+			}
+		}
+	}
+	dir.Close();
+	
+	if (bDryRun)
+	{
+		char szTemplate[PLATFORM_MAX_PATH], szDest[PLATFORM_MAX_PATH];
+		g_pConvarDefaultMapConfig.GetString(szTemplate, sizeof(szTemplate));
+		g_pConvarDefaultMapConfigDest.GetString(szDest, sizeof(szDest));
+		GetCmdArg(0, szBuffer, sizeof(szBuffer));
+
+		PrintToServer("");
+		MsgSrv("You are about to create %d new map configs.\n Template: %s\n Destination dir: %s\nType %s 1 to continue...\n",
+				count, szTemplate, szDest, szBuffer);
+	}
+	else
+	{
+		MsgSrv("Success. Created %d configs.", count);
+	}
+	return Plugin_Handled;
 }

scripting/include/srccoop/globals.inc

@@ -17,6 +17,8 @@ ConVar g_pConvarEndWaitFactor;
 ConVar g_pConvarHomeMap;
 ConVar g_pConvarEndWaitDisplayMode;
 ConVar g_pConvarValidateSteamIds;
+ConVar g_pConvarDefaultMapConfig;
+ConVar g_pConvarDefaultMapConfigDest;
 
 #if defined GAMEPATCH_TEAMSELECT_UI
 ConVar g_pConvarDisableTeamSelect;

scripting/include/srccoop/manager.inc

@@ -12,6 +12,7 @@
 
 enum struct CoopManagerData
 {	
+	KeyValues kv;
 	ChangeLevelManager m_pChangeLevelMgr;
 	int m_iEnabledFeatures;
 	bool m_bIsCoopMap;
@@ -45,6 +46,7 @@ methodmap CoopManager
 
 	public static bool OnLevelInit(char szMapEntities[ENTITYSTRING_LENGTH])
 	{
+		delete data.kv;
 		data.m_pDelayedOutputs.Clear();
 		data.m_pStartTimer = null;
 		data.m_pChangeLevelTimer = null;
@@ -61,9 +63,9 @@ methodmap CoopManager
 		g_pLevelLump.Clear();
 		SurvivalManager.Clear(true);
 
-		KeyValues kv = CoopManager.LoadMapConfig(g_szMapName, data.m_mapConfigLoc);
+		data.kv = CoopManager.LoadMapConfig(g_szMapName, data.m_mapConfigLoc);
 
-		if ((data.m_bIsCoopMap = kv != null))
+		if ((data.m_bIsCoopMap = data.kv != null))
 		{
 			if (CoopManager.IsNewMapSeries())
 			{
@@ -72,41 +74,37 @@ methodmap CoopManager
 				EquipmentManager.ClearAll();
 			}
 			g_pLevelLump.ParseMapEntities(szMapEntities);
-			g_pLevelLump.ParseConfigFile(kv);
+			g_pLevelLump.ParseConfigFile(data.kv);
 			g_pLevelLump.ToString(szMapEntities);
-			delete kv;
 			return true;
 		}
 		return false;
 	}
 
 	public static void OnMapStart()
 	{
-		if (data.m_bIsCoopMap)
-		{
-			PrecacheSound(Conf.SND_TICK);
-			PrecacheSound(Conf.SND_3);
-			PrecacheSound(Conf.SND_2);
-			PrecacheSound(Conf.SND_1);
-			PrecacheSound(Conf.SND_CHANGELEVEL);
-			PrecacheSound(Conf.SND_CHANGELEVEL_TICK);
-
-			#if defined SRCCOOP_BLACKMESA
-			CBM_MP_GameRules.SetStateEndTime(STATE_WARMUP, GetGameTime() + 60 * 60 * 24 * 7);
-			#endif
-
-			KeyValues kv = CoopManager.LoadMapConfig(g_szMapName, data.m_mapConfigLoc);
-			if (kv != null)
-			{
-				CCoopSpawnSystem.ParseConfigFile(kv);
-				
-				Call_StartForward(g_CoopMapConfigLoadedFwd);
-				Call_PushCell(kv);
-				Call_PushCell(data.m_mapConfigLoc);
-				Call_Finish();
-				delete kv;
-			}
-		}
+		if (!data.kv)
+			return;
+	
+		PrecacheSound(Conf.SND_TICK);
+		PrecacheSound(Conf.SND_3);
+		PrecacheSound(Conf.SND_2);
+		PrecacheSound(Conf.SND_1);
+		PrecacheSound(Conf.SND_CHANGELEVEL);
+		PrecacheSound(Conf.SND_CHANGELEVEL_TICK);
+
+		#if defined SRCCOOP_BLACKMESA
+		CBM_MP_GameRules.SetStateEndTime(STATE_WARMUP, GetGameTime() + 60 * 60 * 24 * 7);
+		#endif
+
+		data.kv.Rewind();
+		CCoopSpawnSystem.ParseConfigFile(data.kv);
+		
+		Call_StartForward(g_CoopMapConfigLoadedFwd);
+		Call_PushCell(data.kv);
+		Call_PushCell(data.m_mapConfigLoc);
+		Call_Finish();
+		delete data.kv;
 	}
 
 	public static void OnClientPutInServer(CBasePlayer pPlayer)
@@ -439,28 +437,72 @@ methodmap CoopManager
 	{
 		return data.m_bIsCoopMap;
 	}
-	
+
 	public static KeyValues LoadMapConfig(const char[] szMapName, CoopConfigLocation &src)
 	{
 		char szConfigPath[PLATFORM_MAX_PATH];
+		if (!CoopManager.FindMapConfig(szMapName, szConfigPath, src, true))
+			return null;
+		
+		KeyValues kv = new KeyValues(szMapName);
+		kv.SetEscapeSequences(true);
+		char szRoot[16];
+		if (!(kv.ImportFromFile(szConfigPath) && kv.GetSectionName(szRoot, sizeof(szRoot)) && strcmp(szRoot, "config", false) == 0))
+			ThrowError("Couldn't import \"%s\" into KeyValues", szConfigPath);
+		
+		return kv;
+	}
+
+	public static bool FindMapConfig(const char[] szMapName, char szConfigPath[PLATFORM_MAX_PATH], CoopConfigLocation &src, bool bCreateDefault)
+	{
 		BuildPath(Path_SM, szConfigPath, sizeof(szConfigPath), "data/srccoop/%s.edt", szMapName);
 		if (!FileExists(szConfigPath))
 		{
 			Format(szConfigPath, sizeof(szConfigPath), "maps/%s.edt", szMapName);
 			if (!FileExists(szConfigPath, true))
 			{
-				return null;
+				if (!bCreateDefault || !CoopManager.CreateDefaultConfig(szMapName, szConfigPath))
+				{
+					return false;
+				}
+				else src = CCL_MAPS;
 			}
 			else src = CCL_MAPS;
 		}
 		else src = CCL_SM_DATA;
-		
-		KeyValues kv = new KeyValues(szMapName);
-		kv.SetEscapeSequences(true);
-		char szRoot[16];
-		if (!(kv.ImportFromFile(szConfigPath) && kv.GetSectionName(szRoot, sizeof(szRoot)) && strcmp(szRoot, "config", false) == 0))
-			ThrowError("Couldn't import %s into KeyValues", szConfigPath);
-		return kv;
+		return true;
+	}
+
+	public static bool CreateDefaultConfig(const char[] szMapName, char szConfigPath[PLATFORM_MAX_PATH])
+	{
+		g_pConvarDefaultMapConfig.GetString(szConfigPath, sizeof(szConfigPath));
+		if (szConfigPath[0] != EOS)
+		{
+			if (FileExists(szConfigPath))
+			{
+				char szDest[PLATFORM_MAX_PATH];
+
+				g_pConvarDefaultMapConfigDest.GetString(szDest, sizeof(szDest));
+				Format(szDest, sizeof(szDest), "%s/%s.edt", szDest, szMapName);
+
+				if (FileCopy(szConfigPath, szDest))
+				{
+					LogMessage("Created default map config \"%s\"", szDest);
+					szConfigPath = szDest;
+					return true;
+				}
+				else
+				{
+					LogError("Failed to create default map config \"%s\" !", szDest);
+				}
+			}
+			else
+			{
+				g_pConvarDefaultMapConfig.GetName(szConfigPath, sizeof(szConfigPath));
+				LogError("Default config file is missing. Please fix \"%s\" !", szConfigPath);
+			}
+		}
+		return false;
 	}
 
 }

scripting/include/srccoop/utils.inc

@@ -469,6 +469,17 @@ stock void UpperCaseString(const char[] szInput, char[] szOutput, int iSize)
 	szOutput[x] = '\0';
 }
 
+stock bool StrEndsWith(const char[] str, const char[] suffix, bool caseSensitive = true)
+{
+	return StrEndsWithEx(str, strlen(str), suffix, caseSensitive);
+}
+
+stock bool StrEndsWithEx(const char[] str, int realLen, const char[] suffix, bool caseSensitive = true)
+{
+	int suffixLen = strlen(suffix);
+	return (realLen >= suffixLen && StrEqual(str[realLen - suffixLen], suffix, caseSensitive));
+}
+
 stock bool IsAddSynonym(const char[] str)
 {
 	return (strcmp(str, "add", false) == 0 || strcmp(str, "create", false) == 0);
@@ -931,17 +942,17 @@ stock bool FileCopy(const char[] source, const char[] destination, bool use_valv
 
 	if (file_destination == null)
 	{
-		delete file_source;
+		file_source.Close();
 		return false;
 	}
 
 	int buffer[32];
 	int cache;
 
-	while (!IsEndOfFile(file_source))
+	while (!file_source.EndOfFile())
 	{
-		cache = ReadFile(file_source, buffer, sizeof(buffer), 1);
-		WriteFile(file_destination, buffer, cache, 1);
+		cache = file_source.Read(buffer, sizeof(buffer), 1);
+		file_destination.Write(buffer, cache, 1);
 	}
 
 	delete file_source;

scripting/srccoop.sp

@@ -211,6 +211,8 @@ public void OnPluginStart()
 	g_pConvarHomeMap = CreateConVar("sourcecoop_homemap", "", "The map to return to after finishing a campaign/map.");
 	g_pConvarEndWaitDisplayMode = CreateConVar("sourcecoop_end_wait_display_mode", "1", "Sets which method to show countdown. 0 is panel, 1 is hud text.", _, true, 0.0, true, 1.0);
 	g_pConvarValidateSteamIds = CreateConVar("sourcecoop_validate_steamids", "0", "Validate players steam id's? Increases security at the cost of some functionality breakage when Steam goes down.\n At the time of writing this includes survival mode and equipment persistence.", _, true, 0.0, true, 1.0);
+	g_pConvarDefaultMapConfig = CreateConVar("sourcecoop_default_config", "", "Default edt file, relative to game folder. This file is copied when starting a map with missing config as \"<sourcecoop_default_config_dest>/<mapname>.edt\". Useful for rapid development, or to enforce sourcecoop on all maps on the server.");
+	g_pConvarDefaultMapConfigDest = CreateConVar("sourcecoop_default_config_dest", "maps", "Destination folder for \"sourcecoop_default_config\", relative to game folder. Should be a one of edt scan paths!");
 
 	mp_friendlyfire = FindConVar("mp_friendlyfire");
 	mp_flashlight = FindConVar("mp_flashlight");
@@ -220,6 +222,7 @@ public void OnPluginStart()
 	RegAdminCmd("sc_ft", Command_SetFeature, ADMFLAG_ROOT, "Command for toggling plugin features on/off");
 	RegServerCmd("sourcecoop_dump", Command_DumpMapEntities, "Command for dumping map entities to a file");
 	RegServerCmd("sc_dump", Command_DumpMapEntities, "Command for dumping map entities to a file");
+	RegServerCmd("sc_mkconfigs", Command_MakeConfigs, "Creates default edt configs for all maps in the maps directory which are missing one");
 
 	g_pLevelLump.Initialize();
 	CCoopSpawnSystem.Initialize();