build.gradle

/*
 * Copyright (C) 2016 Appflate.io
 *
 *  Licensed under the Apache License, Version 2.0 (the "License");
 *  you may not use this file except in compliance with the License.
 *  You may obtain a copy of the License at
 *
 * http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

apply plugin: "com.android.application"
apply from: "../quality_tools/findbugs.gradle"

android {
    compileSdkVersion 27
    buildToolsVersion "26.0.3"

    testOptions {
        unitTests.includeAndroidResources = true
    }

    defaultConfig {
        applicationId "io.appflate.restmock.androidsample"
        minSdkVersion 14
        targetSdkVersion 27
        versionCode 1
        versionName "1.0"
        testInstrumentationRunner "io.appflate.restmock.androidsample.CustomTestRunner"
    }
    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile("proguard-android.txt"), "proguard-rules.pro"
        }
    }

    lintOptions {
        warningsAsErrors true
        abortOnError true
        disable "InvalidPackage"
        disable "ObsoleteLintCustomCheck" //https://github.com/JakeWharton/butterknife/issues/1074
    }
}


configurations.all {
    resolutionStrategy {
        force "com.android.support:support-annotations:${supportLibraryVersion}"
        force "com.squareup.okhttp3:okhttp:${okHttpVersion}"
    }
}

dependencies {
    implementation fileTree(dir: "libs", include: ["*.jar"])
    implementation "com.android.support:appcompat-v7:${supportVersion}"
    implementation "com.android.support:design:${supportVersion}"
    implementation "com.jakewharton:butterknife:8.8.1"
    annotationProcessor 'com.jakewharton:butterknife-compiler:8.8.1'
    implementation "com.google.dagger:dagger:2.14.1"
    implementation "com.squareup.retrofit2:retrofit:2.3.0"
    implementation "com.squareup.retrofit2:converter-gson:2.3.0"
    implementation "com.google.code.gson:gson:2.8.2"
    implementation "com.google.code.findbugs:annotations:2.0.3"
    provided "javax.annotation:jsr250-api:1.0"
    annotationProcessor "com.google.dagger:dagger-compiler:2.14.1"

    //Test dependencies
    androidTestImplementation "com.android.support.test:runner:1.0.1"
    androidTestImplementation "com.android.support.test:rules:1.0.1"
    androidTestImplementation "com.android.support.test.espresso:espresso-core:3.0.1"
    //this dependency tends to break things for most users. Im adding it to check whether the app compiles correctly
    androidTestImplementation "com.android.support.test.espresso:espresso-intents:3.0.1"
    androidTestImplementation("com.android.support.test.espresso:espresso-contrib:3.0.1") {
        exclude group: "com.android.support", module: "appcompat"
        exclude group: "com.android.support", module: "support-v4"
        exclude module: "recyclerview-v7"
    }
    androidTestImplementation "com.android.support:support-annotations:${supportVersion}"
    androidTestImplementation "com.android.support:appcompat-v7:${supportVersion}"
    androidTestImplementation "com.android.support:design:${supportVersion}"

    //the most important, RESTMock! :)
    androidTestImplementation project(":android")

    testImplementation "com.android.support:appcompat-v7:${supportVersion}"
    testImplementation "com.android.support:design:${supportVersion}"
    testImplementation "junit:junit:4.12"
    testImplementation "com.android.support.test.espresso:espresso-core:3.0.1"
    testImplementation("com.android.support.test.espresso:espresso-contrib:3.0.1") {
        exclude group: "com.android.support", module: "appcompat"
        exclude group: "com.android.support", module: "support-v4"
        exclude module: "recyclerview-v7"
    }
    testImplementation project(":android")
    testImplementation(project(":core")) {
        exclude group: "org.bouncycastle", module: "bcprov-jdk15on"
    }
}