build.gradle

import org.apache.tools.ant.filters.ReplaceTokens

buildscript {
    repositories {
        maven {
            name 'MinecraftForge'
            url 'https://files.minecraftforge.net/maven'
        }
    }
    dependencies {
        classpath 'net.minecraftforge.gradle:ForgeGradle:2.3-SNAPSHOT'
    }
}

apply plugin: 'eclipse'
apply plugin: 'maven-publish'
apply plugin: 'net.minecraftforge.gradle.forge'

group = project.mod_maven_group
archivesBaseName = project.mod_jar_name
version = "${project.minecraft_version}-${project.mod_version}"

sourceCompatibility = compileJava.sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = compileJava.targetCompatibility = JavaVersion.VERSION_1_8

minecraft {
    version = "${project.minecraft_version}-${project.forge_version}"
    mappings = "${project.mappings_channel}_${project.mappings_version}"
    runDir = "run"
}

repositories {
    maven {
        url 'https://cursemaven.com'
    }
    maven {
        url "https://maven.ic2.player.to" // Forestry
    }
    maven {
        url 'https://chickenbones.net/maven/' // CCL
    }
    maven {
        url 'https://dvs1.progwml6.com/files/maven/' // JEI
    }
}

dependencies {
    compile "codechicken:CodeChickenLib:${project.deps_ccl_version}:universal"

    deobfCompile "curse.maven:gregtech-${project.deps_gregtechceu_version}-${project.deps_gregtechceu_curse_ref}"
    deobfCompile "net.sengir.forestry:forestry_${project.deps_forestry_version}"

    compile "mezz.jei:jei_${project.deps_jei_version}"
}

processResources {
    from(sourceSets.main.resources.srcDirs) {
        include 'mcmod.info'
        expand(project.properties)
    }
    from(sourceSets.main.resources.srcDirs) {
        exclude 'mcmod.info'
    }
    duplicatesStrategy = 'include'
}

task processSource(type: Sync) {
    from sourceSets.main.java
    into "$buildDir/src"
    filter(ReplaceTokens, tokens: [
            MOD_ID        : project.mod_id,
            MOD_NAME      : project.mod_name,
            MOD_UPDATE_URL: project.mod_update_url,
    ])
}

compileJava {
    source = processSource.outputs
}

task sourcesJar(type: Jar, dependsOn: classes) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

artifacts {
    archives sourcesJar
}

jar {
    finalizedBy 'reobfJar'
    manifest {
        attributes([
                'Specification-Title'     : project.mod_name,
                'Specification-Version'   : project.mod_version,
                'Specification-Vendor'    : project.mod_author,
                'Implementation-Title'    : project.mod_id,
                'Implementation-Version'  : project.mod_version,
                'Implementation-Vendor'   : project.mod_author,
                'Implementation-Timestamp': new Date().format("yyyy-MM-dd'T'HH:mm:ssZ")
        ])
    }
}