Add full options search to docs

Author: arnarg

docs/build-options-doc.nix

@@ -82,6 +82,7 @@
         ''
           # Configuration Options
 
+          To see all available resources options, use the [nixidy options search](search) powered by [NüschtOS](https://github.com/NuschtOS/search).
         ''
       ]
       ++ (mapAttrsToList (n: opt:

docs/build-options-search.nix

@@ -0,0 +1,65 @@
+{
+  pkgs,
+  lib,
+  kubenix,
+  mkSearch,
+}: let
+  nixidyPath = toString ./..;
+  kubenixPath = toString kubenix;
+
+  # Borrowed from home-manager :)
+  gitHubDeclaration = user: repo: subpath: {
+    url = "https://github.com/${user}/${repo}/blob/main/${subpath}";
+    name = "${repo}/${subpath}";
+  };
+
+  options =
+    (lib.evalModules {
+      modules =
+        import ../modules/modules.nix
+        ++ [
+          {
+            nixidy.resourceImports = [
+              (kubenix + "/modules/generated/v1.30.nix")
+              ../modules/generated/argocd.nix
+            ];
+          }
+        ];
+      specialArgs = {
+        inherit pkgs lib;
+      };
+    })
+    .options;
+
+  optionsJSON =
+    (pkgs.buildPackages.nixosOptionsDoc {
+      options = removeAttrs options ["_module"];
+      transformOptions = opt:
+        opt
+        // {
+          declarations =
+            map (
+              decl:
+                if lib.hasPrefix nixidyPath (toString decl)
+                then gitHubDeclaration "arnarg" "nixidy" (lib.removePrefix "/" (lib.removePrefix nixidyPath (toString decl)))
+                else if lib.hasPrefix kubenixPath (toString decl)
+                then gitHubDeclaration "hall" "kubenix" (lib.removePrefix "/" (lib.removePrefix kubenixPath (toString decl)))
+                else if decl == "lib/modules.nix"
+                then gitHubDeclaration "NixOS" "nixpkgs" decl
+                else decl
+            )
+            opt.declarations;
+        }
+        // (lib.optionalAttrs (opt.description == null) {
+          description = "";
+        });
+    })
+    .optionsJSON;
+in
+  baseHref:
+    mkSearch {
+      inherit baseHref;
+      optionsJSON = optionsJSON + "/share/doc/nixos/options.json";
+      urlPrefix = "https://github.com/arnarg/nixidy/tree/main";
+      title = "nixidy options search";
+    }

docs/default.nix

@@ -1,9 +1,15 @@
 {
   pkgs,
   lib ? pkgs.lib,
+  kubenix,
+  mkSearch,
 }: let
   optionsMd = import ./build-options-doc.nix {inherit pkgs lib;};
 
+  buildSearch = import ./build-options-search.nix {
+    inherit pkgs lib kubenix mkSearch;
+  };
+
   libraryMd = import ./build-library-doc.nix {inherit pkgs lib;};
 
   docsHtml = pkgs.stdenv.mkDerivation {
@@ -83,8 +89,11 @@
     buildPhase = ''
       mkdir -p $out
       python -m mkdocs build
+
+      cp -r ${buildSearch "/nixidy/options/search/"} $out/options/search
     '';
   };
 in {
   html = docsHtml;
+  search = buildSearch "/";
 }

flake.lock

@@ -6,6 +6,14 @@
     flake-utils.url = "github:numtide/flake-utils";
     nix-kube-generators.url = "github:farcaller/nix-kube-generators";
 
+    nuschtos = {
+      url = "github:nuschtos/search";
+      inputs = {
+        nixpkgs.follows = "nixpkgs";
+        flake-utils.follows = "flake-utils";
+      };
+    };
+
     kubenix = {
       url = "github:hall/kubenix";
       inputs.nixpkgs.follows = "nixpkgs";
@@ -18,6 +26,7 @@
     flake-utils,
     nix-kube-generators,
     kubenix,
+    nuschtos,
   }:
     {
       lib = rec {
@@ -69,7 +78,12 @@
         inherit system;
       };
       docs = import ./docs {
-        inherit pkgs;
+        inherit pkgs kubenix;
+        mkSearch = nuschtos.packages.${system}.mkSearch;
+        lib = import ./lib {
+          inherit pkgs;
+          kubelib = nix-kube-generators;
+        };
       };
       packages = import ./nixidy pkgs;
     in {