mfhds-fromtsv

infile="${1}"

if [[ -z ${infile} ]];then echo "You must supply a file name for a tab delimited file\nYou will need to modify the fields in the awk script to match the headers of your input file";fi

fileroot=$(echo "${infile}" | sed 's/\.....\?$//')

if [[ "${fileroot}" =~ [Ii}[Tt][Ee][Mm] ]];then
	echo -e "\nItem file detected -- ignoring note fields\n"
	outfile="mfhds_fromitems.mrc"
else
	echo -e  "\nCheckin file assumed. Place the string \"item\" in your source file name if this is not intended\n"
	outfile="mfhds_fromcheckins.mrc"
fi

read -r -d '' awkscript << "ENDOFAWK"
#!/usr/bin/awk -f 

BEGIN {
	record_template="=LDR  00159cx  a22000733  4500"FS"=001  HOLDINGSID"FS"=004  BIBID"FS"=008  9810090p    8   4001aueng0000000"FS"=852   0"SFS"bLOCATION"SFS"kCALLPREFIX"SFS"hCALLNUM"

	if(length("а") != 2) {
		badawk = 1
		printf("Your version of awk does not support mfhds-fromitems -- you need a version that supports the -b switch\\n")
		exit
	}
}
function build_mfhd() {
	leader1 = "cx  a22"
	leader2 = "3  4500"
	directory = ""
	base_address = 0
	field_counter = 0 
	field_length = 0
	record_content = ""
	record_counter++

	text_mfhd = record_template

	gsub(/LOCATION/, $location, text_mfhd)
	gsub(/BIBID/, $bibId, text_mfhd)
	gsub(/HOLDINGSID/, holdId, text_mfhd)
	gsub(/CALLNUM/, callNum, text_mfhd)

	if (callPrefix > 0) {gsub(/CALLPREFIX/, $callPrefix, text_mfhd)} else {gsub(/CALLPREFIX/, "", text_mfhd)}

	### nonrequired fields must be entered here
	if (recType > 0) {
		switch($recType) {
			case "s":
				leader1 = "cy  a22"
				break
			case "v":
				leader1 = "cv  a22"
				break
			case "u":
				leader1 = "cu  a22"
				break
		}
	}

	if (publicNote > 0 && $publicNote ~ /[a-zA-Z0-9]/) {
		split($publicNote, statements, ";")
		for (statement in statements) { text_mfhd = text_mfhd""FS"=538    "SFS"a"statements[statement] }
	}
	if (ownershipNote > 0 && $ownershipNote ~ /[a-zA-Z0-9]/) {
		split($ownershipNote, statements, ";")
		for (statement in statements) { text_mfhd = text_mfhd""FS"=561  0 "SFS"a"statements[statement] }
	}
	if (copyNote > 0 && $copyNote ~ /[a-zA-Z0-9]/) {
		split($copyNote, statements, ";")
		for (statement in statements) { text_mfhd = text_mfhd""FS"=562  0 "SFS"a"statements[statement] }
	}
	if (bindingNote > 0 && $bindingNote ~ /[a-zA-Z0-9]/) {
		split($bindingNote, statements, ";")
		for (statement in statements) { text_mfhd = text_mfhd""FS"=563    "SFS"a"statements[statement] }
	}
	if (actionNote > 0 && $actionNote ~ /[a-zA-Z0-9]/) {
		split($actionNote, statements, ";")
		for (statement in statements) { text_mfhd = text_mfhd""FS"=583    "SFS"a"statements[statement] }
	}
	if (notecheckin > 0 && $notecheckin ~ /[a-zA-Z0-9]/) {
		split($notecheckin, statements, ";")
		for (statement in statements) { text_mfhd = text_mfhd""FS"=583    "SFS"a"statements[statement] }
	}
	if (staffnote > 0 && $staffnote ~ /[a-zA-Z0-9]/) {
		split($staffnote, statements, ";")
		for (statement in statements) { text_mfhd = text_mfhd""FS"=583    "SFS"a"statements[statement] }
	}
	if (staffnote2 > 0 && $staffnote2 ~ /[a-zA-Z0-9]/) {
		split($staffnote2, statements, ";")
		for (statement in statements) { text_mfhd = text_mfhd""FS"=583    "SFS"a"statements[statement] }
	}
	if (acquisitionstatus > 0 && $acquisitionstatus ~ /[a-zA-Z0-9]/) {
		split($acquisitionstatus, statements, ";")
		for (statement in statements) { text_mfhd = text_mfhd""FS"=583    "SFS"a"statements[statement] }
	}
	if (libHas > 0 && $libHas ~ /[a-zA-Z0-9]/) {
		gsub(/^1\.[1-9]?[0-9] /, "", $libHas)
		gsub(/;1\.[1-9]?[0-9] /, "", $libHas)
		split($libHas, statements, ";") 
		for (statement in statements) { text_mfhd = text_mfhd""FS"=866    "SFS"a"statements[statement]
		}
	}

	split(text_mfhd, marc_array, FS)	
	num_mfhd_fields = length(marc_array)
	
	for (field = 2; field <= num_mfhd_fields; ++field) {
		tag = substr(marc_array[field], 2, 3)
	
		field_content = substr(marc_array[field], 7)""OFS
		field_length=sprintf("%04d", length(field_content))
	
		directory_address = sprintf("%05d", base_address)
		base_address = base_address + field_length
	
		directory = directory""tag""field_length""directory_address
		record_content = record_content""field_content
		field_counter++
		}
	
	directory = directory""OFS
	base_data_address = sprintf("%05d", 24 + length(directory))
	
	record_content = record_content

	record_length = 24 + length(directory) + length(record_content) + 1
	
	leader = sprintf("%05d", record_length)""leader1""base_data_address""leader2

	if (processed[holdId] != 1){ 
		print leader""directory""record_content > OUTFILE
		processed[holdId] = 1
		created = created + 1
	}

	if (NR % 10000 == 0){ printf "Records processed: %d :created: %d \\r", record_counter, created }
}
{
	sub("\r", "", $NF)

	if (NR == 1) {

		itemfile = 0

		if ( FILENAME ~ /[Ii}[Tt][Ee][Mm]/ ){ itemfile = 1 }

		for(i=1;i<=NF;i++) {
			compareheader=tolower($i)
			gsub(/[^a-z0-9]/, "", compareheader)

			switch(compareheader) {
				case "bibno":
					bibId=i
					printf ("Bib ID found in "$i"\\n")
					break
				case "bibid":
					bibId=i
					printf ("Bib ID found in "$i"\\n")
					break
				case "recordbibliographic":
					bibId=i
					printf ("Bib ID found in "$i"\\n")
					break
				case "recordbiblio":
					bibId=i
					printf ("Bib ID found in "$i"\\n")
					break
				case "loc":
					location=i
					printf ("Location found in "$i"\\n")
					break
				case "location":
					location=i
					printf ("Location found in "$i"\\n")
					break
				case "locationcode":
					location=i
					printf ("Location found in "$i"\\n")
					break
				case "callmarc":
					callNumPos=i
					printf ("Call number found in "$i"\\n")
					break
				case "call":
					callNumPos=i
					printf ("Call number found in "$i"\\n")
					break
				case "callno":
					callNumPos=i
					printf ("Call number found in "$i"\\n")
					break
				case "callnumber":
					callNumPos=i
					printf ("Call number found in "$i"\\n")
					break
				case "callitem":
					callNumPos=i
					printf ("Call number found in "$i"\\n")
					break
				case "callprefix":
					callPrefix=i
					printf ("Call number prefix found in "$i"\\n")
					break
				case "callbibliographic":
					callNumFallback=i
					printf ("Call number fallback found in "$i"\\n")
					break
				case "bibcall":
					callNumFallback=i
					printf ("Call number fallback found in "$i"\\n")
					break
				case "callbiblio":
					callNumFallback=i
					printf ("Call number fallback found in "$i"\\n")
					break
				case "callnonmarc":
					callNumFallback=i
					printf ("Call number fallback found in "$i"\\n")
					break
				case "libhas":
					libHas=i
					printf ("Lib has was found in "$i"\\n")
					break
				case "libhascheckin":
					libHas=i
					printf ("Lib has was found in "$i"\\n")
					break
				case "holdid":
					holdIdpos=i
					holdId=i
					printf ("Holdings ID fallback found in "$i"\\n")
					break
				case "holdingsid":
					holdIdpos=i
					holdId=i
					printf ("Holdings ID fallback found in "$i"\\n")
					break
				case "intnote":
					if (itemfile == 0) {
						intnote=i
						printf ("Internal note was found in "$i"\\n")
					}
					break
				case "notecheckin":
					if (itemfile == 0) {
						notecheckin=i
						printf ("Checkin note was found in "$i"\\n")
					}
					break
				case "staffnote":
					if (itemfile == 0) {
						staffnote=i
						printf ("Staff note was found in "$i"\\n")
					}
					break
				case "staffnote2":
					if (itemfile == 0) {
						staffnote2=i
						printf ("Staff note was found in "$i"\\n")
					}
					break
				case "acquisitionstatus":
					if (itemfile == 0) {
						acquisitionstatus=i
						printf ("Acq status note was found in "$i"\\n")
					}
					break
				case "actionnote":
					if (itemfile == 0) {
						actionNote=i
						printf ("Action note was found in "$i"\\n")
					}
					break
				case "bindingnote":
					if (itemfile == 0) {
						bindingNote=i
						printf ("Binding note was found in "$i"\\n")
					}
					break
				case "copynote":
					if (itemfile == 0) {
						copyNote=i
						printf ("Copy note was found in "$i"\\n")
					}
					break
				case "ownershipnote":
					if (itemfile == 0) {
						ownershipNote=i
						printf ("Ownership note was found in "$i"\\n")
					}
					break
				case "publicnote":
					if (itemfile == 0) {
						publicNote=i
						printf ("Public note was found in "$i"\\n")
					}
					break
				case "holdingstype":
					if (itemfile == 0) {
						recType=i
						printf ("Holdings type was found in "$i"\\n")
					}
					break
			}
		}
	if (! bibId) {  printf ("\\nNo valid bib ID field could be found\\n"); exit }
	if (! location ) {  printf ("\\nNo valid location field could be found\\n"); exit }

	if (! callNumPos && ! callNumFallback ) {  emptyCall = 1 } else { emptyCall = 0 }
	if (! callNumPos && callNumFallback > 0 ) { callNumPos = callNumFallback; callNumFallback = "" }

	if (! recType) {  printf ("\\nNo record type field detected, defaulting to Single part holdings\\n") }
	printf("\\n\\n")
	}

	gsub(/"/, "", $0) 
	gsub(/^ */, "", $location) 
	gsub(/ *$/, "", $location) 

	if (emptyCall == 0) {
		callNum = $callNumPos
		if (callNumFallback > 0 && length($callNumPos) == 0) {callNum = $callNumFallback}
	} else {
		if (NR == 1) { callNum = "callNum" } else { callNum = "" }
	}

	if (! holdIdpos) {holdId = $bibId""$location""callNum; gsub(/[^a-zA-Z0-9]/, "", holdId)} else { holdId = $holdIdpos }


	build_mfhd()
}
END { 
	if (badawk != 1) {
		printf ("\\n\\n Records processed: %d Records created: %d Output file: %s\\n", record_counter, created, OUTFILE)
	}
}

ENDOFAWK

echo -e "${awkscript}" > tmp_checkmarc
chmod 700 tmp_checkmarc

awk -v ORS=$'\x1d' -v RS='\n' -v OFS=$'\x1e' -v FS='\t' -v SFS=$'\x1f' -v OUTFILE="${outfile}" -b -f tmp_checkmarc "${infile}"

rm -f tmp_*