-
Notifications
You must be signed in to change notification settings - Fork 3
/
proof.v
313 lines (284 loc) · 9.68 KB
/
proof.v
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
(* stateWriter laws *)
Require Import Notations.
Require Import FunctionalExtensionality.
Set Implicit Arguments.
(** * The Monad Type Class *)
Definition idf {A : Type} (x : A) : A := x.
Definition composition {A} {B} {C} (f : B -> C) (g : A -> B) (a : A) := f (g a).
Class Functor f := {
fmap: forall A B, (A -> B) -> f A -> f B;
fmap_id: (forall A (a: f A), fmap idf a = a);
fmap_dist: (forall A B C (fn : A -> B) (g : B -> C) (a : f A),
fmap g (fmap fn a) = fmap (fun x => g (fn x)) a)
}.
Class Applicative (m : Type -> Type) (F: Functor m) := {
pure: forall A, A -> m A;
app: forall A B, m (A -> B) -> m A -> m B;
app_identity: forall A (a : m A), app (pure idf) a = a;
app_homo: forall A B (f : A -> B) (a : A), app (pure f) (pure a) = pure (f a);
app_interchange: forall A B (u : m (A -> B)) (y : A), app u (pure y) = app (pure (fun f => f y)) u;
app_composition: forall A B C (u : m (B -> C)) (v : m (A -> B)) (w : m A),
app u (app v w) =
app (app (app (pure composition) u) v) w;
fmap_app: forall A B (f : A -> B) (x : m A), app (pure f) x = fmap f x
}.
Theorem fmap_pure (m : Type -> Type) (AF: Functor m) (AP: Applicative AF) :
forall A B (a : A) (f : A -> B),
fmap f (pure a) = pure (f a).
Proof.
intros.
rewrite <- app_homo.
rewrite fmap_app.
reflexivity.
Qed.
Class Monad (m : Type -> Type) (AF: Functor m) (AP: Applicative AF) := {
bind : forall A B, m A -> (A -> m B) -> m B;
right_unit: forall A (a: m A), a = bind a (fun x => pure x);
left_unit: forall A (a: A) B (f: A -> m B),
f a = bind (pure a) f;
associativity: forall A (ma : m A) B f C (g: B -> m C),
bind ma (fun x => bind (f x) g) = bind (bind ma f) g;
app_bind: forall A B (fs : m (A -> B)) (xs : m A),
app A B fs xs = bind fs (fun f => bind xs (fun x => pure (f x)));
}.
Theorem fmap_return (m : Type -> Type) (AF: Functor m) (AP: Applicative AF) (AM: Monad AP):
forall A B (ma : m A) (f : A -> B),
bind B ma (fun a => pure (f a)) = fmap f ma.
Proof.
intros.
rewrite <- fmap_app.
rewrite app_bind.
rewrite <- left_unit.
reflexivity.
Qed.
Theorem bind_fmap (m : Type -> Type) (AF: Functor m) (AP: Applicative AF) (AM: Monad AP):
forall A B C (ma : m A) (f : A -> B) (mf : B -> m C),
@bind m AF AP AM B C (fmap f ma) mf = @bind m AF AP AM A C ma (composition mf f).
Proof.
intros.
rewrite <- (fmap_return AM).
rewrite <- associativity.
apply f_equal.
extensionality x.
rewrite <- left_unit.
unfold composition.
reflexivity.
Qed.
Definition RSST (R : Type) (W : Type) (S : Type) (M : Type -> Type) (A : Type) :=
R -> (S * W) -> M (A * (S * W)).
Definition first {A : Type} {B : Type} {C : Type} (f : A -> B) (x : (A*C)) :=
(f (fst x), snd x).
Theorem pair_idf : forall A B, (fun (x : A * B) => (fst x, snd x)) = idf.
Proof.
intros. apply functional_extensionality.
destruct x. simpl. unfold idf. reflexivity.
Qed.
Theorem funProductBreak: forall (A B C: Type) (f : (A*B) -> C), (fun x : A * B => let (a,b) := x in f (a,b)) = f.
Proof.
intros. apply functional_extensionality. intros. destruct x. reflexivity.
Qed.
Theorem fstSnd: forall (A B C: Type) (f : A -> B -> C),
(fun x : A * B => let (a,b) := x in f a b) = (fun x => f (fst x) (snd x)).
Proof.
intros.
extensionality x. destruct x. simpl. reflexivity.
Qed.
Instance RSSTFunctor R W S (M : Type -> Type) (F: Functor M) : Functor (RSST R W S M) :=
{ fmap M A f FA := fun r sw => fmap (first f) (FA r sw)
}.
Proof.
- (* fmap_identity *)
intros T m.
extensionality r.
extensionality sw.
destruct sw.
unfold first. unfold idf.
rewrite pair_idf.
rewrite fmap_id.
reflexivity.
- (* fmap dist *)
intros.
extensionality r.
extensionality sw.
apply fmap_dist.
Defined.
Instance RSSTApplicative : forall R W S (M : Type -> Type) (FM : Functor M) (AM : Applicative FM) (MM : Monad AM)
, Applicative (RSSTFunctor R W S FM) :=
{
pure := fun A x r sw => @pure M FM AM (A*(S*W)) (x, sw);
app A B mf mb := fun r sw =>
@bind M FM AM MM ((A -> B)*(S*W)) (B*(S*W)) (mf r sw) (fun blob1 =>
let (f,sw') := blob1
in @bind M FM AM MM (A*(S*W)) (B * (S*W)) (mb r sw') (fun blob2 =>
let (x,sw'') := blob2 in pure (f x, sw'')))
}.
Proof.
- (* app identity *)
intros.
extensionality r. extensionality sw.
rewrite <- left_unit.
unfold idf.
rewrite funProductBreak.
rewrite <- right_unit.
reflexivity.
- (* app_homo *)
intros.
extensionality r. extensionality sw.
rewrite <- left_unit. rewrite <- left_unit. reflexivity.
- (* app_interchange *)
intros.
extensionality r. extensionality sw.
rewrite <- left_unit. apply f_equal.
extensionality sw'.
destruct sw.
destruct sw'.
rewrite <- left_unit. reflexivity.
- (* app_composition *)
intros.
extensionality r. extensionality sw.
rewrite <- left_unit. rewrite <- associativity. rewrite <- associativity.
apply f_equal.
extensionality sw'.
destruct sw. destruct sw'. rewrite <- left_unit.
rewrite <- associativity. rewrite <- associativity. apply f_equal.
extensionality sw''.
destruct sw''.
rewrite <- left_unit.
rewrite <- associativity. apply f_equal.
apply functional_extensionality. intros.
destruct p0. destruct x. rewrite <- left_unit. unfold composition. reflexivity.
- (* fmap pure *)
intros.
extensionality r. extensionality sw.
unfold fmap. simpl.
rewrite <- left_unit.
rewrite fstSnd.
rewrite fmap_return. reflexivity.
Defined.
Instance RSSTMonad : forall R W S (M : Type -> Type) (FM : Functor M) (AM : Applicative FM) (MM : Monad AM)
, Monad (RSSTApplicative R W S MM) :=
{
bind A B ma f :=
fun r sw =>
@bind M FM AM MM (A*(S*W)) (B*(S*W)) (ma r sw) (fun blob =>
let (a,sw') := blob
in (f a) r sw')
}.
Proof.
- (* right unit *)
intros.
extensionality r. extensionality sw.
unfold pure. simpl.
rewrite funProductBreak. rewrite <- right_unit. reflexivity.
- (* left unit *)
intros.
extensionality r. extensionality sw.
unfold pure. simpl.
rewrite <- left_unit. reflexivity.
- (* associativity *)
intros.
extensionality r. extensionality sw.
rewrite <- associativity. apply f_equal.
extensionality sw'.
destruct sw'. reflexivity.
- (* app_bind *)
intros.
extensionality r. extensionality sw.
destruct sw.
unfold pure. simpl. reflexivity.
Defined.
Class StateMonad (S : Type) (m : Type -> Type) (AF: Functor m) (AP: Applicative AF) (AM: Monad AP) := {
get : m S;
put : S -> m unit;
stateLaw1: @bind m AF AP AM S unit get put = pure tt;
stateLaw2: forall (s s' : S), bind unit (put s) (fun _ => put s') = put s';
stateLaw3: forall (s : S), @bind m AF AP AM unit S (put s) (fun _ => get) = @bind m AF AP AM unit S (put s) (fun _ => pure s);
stateLaw4: forall B (k : S -> S -> m B),
@bind m AF AP AM S B get (fun s => @bind m AF AP AM S B get (fun s' => k s s'))
= @bind m AF AP AM S B get (fun s => k s s)
}.
Instance RSSTState : forall R W S (M : Type -> Type) (FM : Functor M) (AM : Applicative FM) (MM : Monad AM)
, StateMonad S (RSSTMonad R W S MM) :=
{
get := fun r sw => pure (fst sw, sw);
put := fun ns r sw => pure (tt, (ns, snd sw))
}.
Proof.
- extensionality r; extensionality sw.
destruct sw. unfold pure at 3; simpl.
repeat(rewrite <- left_unit). simpl.
reflexivity.
- intros.
extensionality r; extensionality sw.
destruct sw.
unfold bind at 1. simpl.
repeat(rewrite <- left_unit). simpl.
reflexivity.
- intros.
extensionality r; extensionality sw.
destruct sw.
unfold bind at 1;simpl.
repeat(rewrite <- left_unit). simpl.
reflexivity.
- intros.
unfold bind at 1;simpl.
extensionality r; extensionality sw.
repeat(rewrite <- left_unit); simpl.
reflexivity.
Defined.
Class Monoid W := {
mempty : W;
mappend : W -> W -> W;
midleft: forall x, mappend mempty x = x;
midright: forall x, mappend x mempty = x;
massoc: forall a b c, mappend (mappend a b) c = mappend a (mappend b c)
}.
Class WriterMonad (W : Type) (m : Type -> Type) (AF: Functor m) (AP: Applicative AF) (AM: Monad AP) (MW: Monoid W):= {
tell: W -> m unit;
listen: forall A, m A -> m (A*W);
pass: forall A, m (A*(W->W)) -> m A
}.
Instance RSSTWriter: forall R W S (M : Type -> Type) (FM : Functor M) (AM : Applicative FM) (MM : Monad AM) (MW: Monoid W)
, WriterMonad (RSSTMonad R W S MM) MW :=
{
tell := fun w _ sw =>
let (s,ow) := sw in
pure (tt, (s,mappend ow w));
listen := fun A rw r sw =>
let (s,w) := sw
in @bind M FM AM MM (A*(S*W)) (A*W*(S*W))
(rw r (s,mempty))
(fun blob => let (a,sw') := blob in let (ns,nw) := sw' in pure ((a,nw),(ns,mappend w nw)));
pass := fun A rw r sw =>
let (s,w) := sw
in @bind M FM AM MM (A*(W->W)*(S*W)) (A*(S*W)) (rw r (s,mempty))
(fun blob =>
let (afw,sw') := blob in
let (a,fw) := afw in
let (s',w') := sw' in
pure (a,(s',mappend w (fw w'))))
}.
Definition lift {M : Type -> Type} {FM: Functor M} {AM: Applicative FM} {MM: Monad AM} {R} {W} {S} {A} :
M A -> RSST R W S M A :=
fun act _ sw => @bind M FM AM MM A (A*(S*W)) act (fun a => pure (a,sw)).
Theorem listenA R W S (M : Type -> Type) (FM: Functor M) (AM: Applicative FM) (MM: Monad AM) (MW: Monoid W):
forall A (act: M A),
@listen W (RSST R W S M) (RSSTFunctor R W S FM)
(RSSTApplicative R W S MM) (RSSTMonad R W S MM) MW
(RSSTWriter R S MM MW) A
(lift act) = fmap (fun v => (v,mempty)) (lift act).
Proof.
intros.
unfold listen, fmap. simpl. unfold first.
extensionality r. extensionality sw.
destruct sw. unfold lift.
rewrite <- associativity.
rewrite fmap_return.
rewrite fmap_dist. simpl.
rewrite <- (fmap_return MM).
apply f_equal.
extensionality a.
rewrite <- left_unit.
rewrite midright.
reflexivity.
Qed.