ИерархическийСборXML.os

Перем ОбщийФайлПравил;
Перем КаталогИсходныхКодов;

Процедура СобратьКоллекциюОбъектов(ИсходныйЭлемент, КаталогРодителя)
	
	КаталогРодителяНаДиске = Новый Файл(КаталогРодителя);
	Если Не КаталогРодителяНаДиске.Существует() Тогда
		Возврат;
	КонецЕсли;
	
	КаталогГруппыПравил = Новый Файл(КаталогРодителя + "Группа\");
	Если КаталогГруппыПравил.Существует() Тогда
		СобратьКоллекциюОбъектов(ИсходныйЭлемент, КаталогРодителя + "Группа\");
	КонецЕсли;

	КаталогГруппаПравил = Новый Файл(КаталогРодителя + "Правило\");
	Если КаталогГруппаПравил.Существует() Тогда
		СобратьКоллекциюОбъектов(ИсходныйЭлемент, КаталогРодителя + "Правило\");
	КонецЕсли;

	НайденныеФайлы = НайтиФайлы(КаталогРодителя, "*.xml");
	Для Каждого Файл Из НайденныеФайлы Цикл
		
		ДобавляемыйЭлемент = ПрочитатьЭлементИзФайла(Файл.ПолноеИмя);
		ИсходныйЭлемент.appendChild(ДобавляемыйЭлемент);
		
		ДочерниеЭлементы = ДобавляемыйЭлемент.selectNodes("*");
		Для Каждого Элемент Из ДочерниеЭлементы Цикл
			
			КаталогКоллекции = КаталогКоллекции(КаталогРодителя + ДополнительныйКаталогЭлемента(ДобавляемыйЭлемент), Элемент);
			
			Если ЭлементЯвляетсяРасширениемОбъекта(Элемент.nodeName) Тогда
				ДобавитьРасширениеОбъекта(Элемент.text, КаталогКоллекции, Элемент.nodeName);
			КонецЕсли;
			
			Если ЭлементЯвляетсяКоллекцией(Элемент) Тогда
				СобратьКоллекциюОбъектов(Элемент, КаталогКоллекции);
			КонецЕсли;		

		КонецЦикла;
		
		Если ЭлементСодержитДочерниеКоллекции(ДобавляемыйЭлемент.nodeName) Тогда
			КаталогКоллекции = КаталогКоллекции(КаталогРодителя + ДополнительныйКаталогЭлемента(ДобавляемыйЭлемент), Элемент);
			СобратьКоллекциюОбъектов(ДобавляемыйЭлемент, КаталогКоллекции);
		КонецЕсли;		
		
	КонецЦикла;
	
КонецПроцедуры


Процедура ДобавитьРасширениеОбъекта(Содержание, ИсходныйКаталог, ИмяФайла, РасширениеФайла = "bsl")
	
	КаталогРасширений = ИсходныйКаталог + "Ext\";
	
	ЧтениеТекста = Новый ЧтениеТекста(КаталогРасширений + ИмяФайла + "." + РасширениеФайла);
	СодержимоеФайла = ЧтениеТекста.Прочитать();
	ЧтениеТекста.Закрыть();
	
	Если СодержимоеФайла <> Неопределено Тогда
		Содержание = СодержимоеФайла;
	КонецЕсли;
	
КонецПроцедуры

Функция ПрочитатьЭлементИзФайла(ИмяФайла)

	ЭлементыКоллекции = Новый COMОбъект("MSXML2.DOMDocument.6.0");
	ЭлементыКоллекции.async = false;
	ЭлементыКоллекции.load(ИмяФайла);
	
	Возврат ЭлементыКоллекции.documentElement;
	
КонецФункции

Функция КаталогКоллекции(ИсходныйКаталог, ИсходныйЭлемент)

	Если ИсходныйЭлемент.nodeName = "Свойства" Или ИсходныйЭлемент.nodeName = "Значения" 
		Или ИсходныйЭлемент.nodeName = "Параметры" Или ИсходныйЭлемент.nodeName = "Обработки" 
		Или ИсходныйЭлемент.nodeName = "ПравилаКонвертацииОбъектов" 
		Или ИсходныйЭлемент.nodeName = "ПравилаВыгрузкиДанных" 
		Или ИсходныйЭлемент.nodeName = "ПравилаОчисткиДанных" 
		Или ИсходныйЭлемент.nodeName = "Алгоритмы" Или ИсходныйЭлемент.nodeName = "Запросы" Тогда

		КаталогКоллекции = ИсходныйКаталог + ИсходныйЭлемент.nodeName + "\";
		
	ИначеЕсли ИсходныйЭлемент.nodeName = "Алгоритм" 
		Или ИсходныйЭлемент.nodeName = "Запрос" 
		Или ИсходныйЭлемент.nodeName = "Параметр" Тогда

		ПутьКИмениЭлементаКоллекции = "@Имя";
		КаталогКоллекции = ИсходныйКаталог + ИсходныйЭлемент.SelectSingleNode(ПутьКИмениЭлементаКоллекции).text + "\";
		
	Иначе
		КаталогКоллекции = ИсходныйКаталог;
		ПутьКИмениЭлементаКоллекции = "";
	КонецЕсли;
	
	Возврат КаталогКоллекции;

КонецФункции

Функция ДополнительныйКаталогЭлемента(Элемент)
	
	КаталогЭлемента = "";
	
	Если Элемент.nodeName = "Правило" Или Элемент.nodeName = "Группа" Тогда
		
		КаталогЭлемента = Элемент.SelectSingleNode("Код").text + "\";
		
	ИначеЕсли Элемент.nodeName = "Алгоритм" Или Элемент.nodeName = "Запрос" Или Элемент.nodeName = "Параметр" Тогда

		КаталогЭлемента = Элемент.SelectSingleNode("@Имя").text + "\";
		
	ИначеЕсли Элемент.nodeName = "Свойство" Или Элемент.nodeName = "Значение" Тогда
		
		КаталогЭлемента = Элемент.SelectSingleNode("Код").text + "\";
		
	КонецЕсли;
	
	Возврат КаталогЭлемента;
		
КонецФункции


Функция ЭлементЯвляетсяРасширениемОбъекта(ИмяСвойства)
	
	МассивЭлементов = Новый Массив;

	// Обработчики Правил конвертации объектов
	МассивЭлементов.Добавить("ПередВыгрузкой");
	МассивЭлементов.Добавить("ПриВыгрузке");
	МассивЭлементов.Добавить("ПослеВыгрузки");
	МассивЭлементов.Добавить("ПослеВыгрузкиВФайл");
	МассивЭлементов.Добавить("ПоследовательностьПолейПоиска");		
	МассивЭлементов.Добавить("ПередЗагрузкой");
	МассивЭлементов.Добавить("ПриЗагрузке");
	МассивЭлементов.Добавить("ПослеЗагрузки");

	// Обработчики Правил выгрузки данных
	МассивЭлементов.Добавить("ПередОбработкойПравила");
	МассивЭлементов.Добавить("ПередВыгрузкойОбъекта");
	МассивЭлементов.Добавить("ПослеВыгрузкиОбъекта");
	МассивЭлементов.Добавить("ПослеОбработкиПравила");
	
	// Обработчики Правил очистки данных
	МассивЭлементов.Добавить("ПередОбработкойПравила");
	МассивЭлементов.Добавить("ПередУдалениемОбъекта");
	МассивЭлементов.Добавить("ПослеОбработкиПравила");
	
	// Текстовое поле алгоритма и запроса
	МассивЭлементов.Добавить("Текст");
	
	// Обработчики Конвертации
	МассивЭлементов.Добавить("ПослеЗагрузкиПравилОбмена");
	МассивЭлементов.Добавить("ПередВыгрузкойДанных");
	МассивЭлементов.Добавить("ПередПолучениемИзмененныхОбъектов");
	МассивЭлементов.Добавить("ПередВыгрузкойОбъекта");
	МассивЭлементов.Добавить("ПередОтправкойИнформацииОбУдалении");
	МассивЭлементов.Добавить("ПередКонвертациейОбъекта");
	МассивЭлементов.Добавить("ПослеВыгрузкиОбъекта");
	МассивЭлементов.Добавить("ПослеВыгрузкиДанных");
	МассивЭлементов.Добавить("ПередЗагрузкойДанных");
	МассивЭлементов.Добавить("ПослеЗагрузкиПараметров");
	МассивЭлементов.Добавить("ПослеПолученияИнформацииОбУзлахОбмена");
	МассивЭлементов.Добавить("ПередЗагрузкойОбъекта");
	МассивЭлементов.Добавить("ПриПолученииИнформацииОбУдалении");
	МассивЭлементов.Добавить("ПослеЗагрузкиОбъекта");
	МассивЭлементов.Добавить("ПослеЗагрузкиДанных");
	
	// Обработчики Параметров
	МассивЭлементов.Добавить("ПослеЗагрузкиПараметра");

	Возврат МассивЭлементов.Найти(ИмяСвойства) <> Неопределено;
	
КонецФункции

Функция ЭлементЯвляетсяКоллекцией(Элемент)
	
	Коллекции = Новый Соответствие;

	// Имена элементов-коллекций конревых элементов: Ключ - имя элемента коллекции, Значение - допустимые имена родителельских элементов
	Коллекции.Вставить("Параметры", "ПравилаОбмена");
	Коллекции.Вставить("Обработки", "");
	Коллекции.Вставить("ПравилаКонвертацииОбъектов", "");
	Коллекции.Вставить("ПравилаВыгрузкиДанных", "");
	Коллекции.Вставить("ПравилаОчисткиДанных", "");
	Коллекции.Вставить("Алгоритмы", "");
	Коллекции.Вставить("Запросы",  "");

	// Имена элементов-коллекций внутри Правил
	Коллекции.Вставить("Свойства", "");
	Коллекции.Вставить("Значения", "");

	НайденныйЭлемент = Коллекции.Получить(Элемент.nodeName);
	Если НайденныйЭлемент = Неопределено Тогда
		Возврат Ложь;
	КонецЕсли;

	Если НайденныйЭлемент = "" Тогда
		Возврат Истина;
	ИначеЕсли Найти(НайденныйЭлемент, Элемент.parentNode.nodeName) > 0 Тогда
		Возврат Истина;
	КонецЕсли;
	
	Возврат Ложь;
	
КонецФункции

Функция ЭлементСодержитДочерниеКоллекции(ИмяСвойства)
	
	МассивЭлементов = Новый Массив;

	// Имена элементов-коллекций внутри Правил
	МассивЭлементов.Добавить("Группа");
	
	Возврат МассивЭлементов.Найти(ИмяСвойства) <> Неопределено;
	
КонецФункции

Функция СоздаватьКаталогДляКоллекцииЭлементов(ИмяСвойства)
	
	МассивЭлементов = Новый Массив;
	МассивЭлементов.Добавить("Группа");
	МассивЭлементов.Добавить("Правило");
	
	Возврат МассивЭлементов.Найти(ИмяСвойства) <> Неопределено;	
	
КонецФункции


КаталогИсходныхКодов = "src\";

ОбщийФайлПравил = Новый COMОбъект("MSXML2.DOMDocument.6.0");
ОбщийФайлПравил.async = false;

СобратьКоллекциюОбъектов(ОбщийФайлПравил, КаталогИсходныхКодов);

ОбщийФайлПравил.save("ПравилаОбмена_Собранные.xml");