Clone error when deploying on multiple nodes

[uchris13]

I have a 3 node PVE cluster in HA and Ceph storage shared across all the nodes. I have a Debian12 cloud init template in my node PVE001. I am instructing terraform to deploy machines in specific nodes (pve001, 002 & 003)

The machines deployed in pve001 are correct but when it tries to deploy one in pve002 or pve003 i get this error

│ Error: error waiting for VM clone: All attempts fail: │ #1: error cloning VM: received an HTTP 500 response - Reason: unable to find configuration file for VM 9001 on node 'dev-pve002' │ │ with proxmox_virtual_environment_vm.vm["worker02"], │ on main.tf line 26, in resource "proxmox_virtual_environment_vm" "vm": │ 26: resource "proxmox_virtual_environment_vm" "vm" {

this is my main.tf and I have run out of Ideas as why is this happening. Manual cloning works perfectly

# 1️⃣ Create Cloud-Init Snippet Before VM Creation
resource "proxmox_virtual_environment_file" "user_data_cloud_config" {
  for_each = var.vm_config

  content_type = "snippets"
  datastore_id = "local"  # Ensure local storage is used for Cloud-Init
  node_name    = each.value.node

  source_raw {
    data = <<EOF
#cloud-config
users:
  - name: ${each.value.username}
    sudo: ALL=(ALL) NOPASSWD:ALL
    groups: sudo
    shell: /bin/bash
    ssh_authorized_keys:
      - ${file("~/.ssh/rsa.id")}
EOF
    file_name = "${each.value.hostname}-cloudinit.yaml"  
  }
  file_mode = "0644"  # Ensure proper permissions
}

# 2️⃣ Create VMs Using Cloud-Init Template
resource "proxmox_virtual_environment_vm" "vm" {
  for_each = var.vm_config

  name      = each.value.hostname
  node_name = each.value.node

  clone {
    vm_id = 9001  
  }

  agent {
    enabled = true
  }

  machine = "q35"  # Explicitly set machine type

  cpu {
    cores = each.value.num_cpus
  }

  memory {
    dedicated = each.value.memory_mb
  }

  disk {
    datastore_id = each.value.storage
    size         = each.value.disk_gb
    interface    = "virtio"
  }

  network_device {
    bridge  = "vmbr1"
    vlan_id = each.value.vlan_id
  }

  initialization {
    ip_config {
      ipv4 {
        address = each.value.ip_address
        gateway = var.gateway
      }
    }

    dns {
      servers = var.dns_servers
    }

    user_data_file_id = proxmox_virtual_environment_file.user_data_cloud_config[each.key].id
  }

  depends_on = [proxmox_virtual_environment_file.user_data_cloud_config]
}

[bpg]

Hey @uchris13 👋🏼

You may need to specify node_name of the source location in the clone section, i.e.

...
  clone {
    vm_id = 9001
    node_name = "pve001"
  }
...

If blank then the provider assumes the source is on the same node as the clone.