BUILD.gn

# This Source Code Form is subject to the terms of the Mozilla Public
# License, v. 2.0. If a copy of the MPL was not distributed with this file,
# You can obtain one at http://mozilla.org/MPL/2.0/.

assert(is_mac)

sparkle_binaries = [
  "Sparkle.framework",
  "BinaryDelta",
  "generate_keys",
  "sign_update"
]

bundle_data("sparkle_framework_bundle_data") {
  public_deps = [ ":build_sparkle_framework" ]

  sources = [ "$root_out_dir/Sparkle.framework" ]
  outputs = [ "{{bundle_contents_dir}}/Frameworks/{{source_file_part}}" ]
}

action("build_sparkle_framework") {
  script="build_sparkle_framework.py"
  outputs = []
  foreach(binary, sparkle_binaries) {
    outputs += [ "$root_out_dir/" + binary ]
  }
}

copy("copy_old_sign_update") {
  sources = [ "bin/old_dsa_scripts/sign_update" ]

  outputs = [
    "$root_out_dir/old_dsa_scripts/{{source_file_part}}",
  ]
}

action("tar_sparkle_binaries") {
  script="tar_sparkle_binaries.py"

  outputs = [ "$root_out_dir/sparkle_binaries.tar.gz" ]

  args = sparkle_binaries

  deps = [ ":build_sparkle_framework" ]
}