build.gradle

buildscript {
	repositories {
		jcenter()
		mavenCentral()
	}
	dependencies {
		classpath "org.jfrog.buildinfo:build-info-extractor-gradle:3.1.1"
	}
}

apply plugin: 'groovy'
apply plugin: 'java'
apply plugin: 'maven'
apply plugin: 'maven-publish'
apply plugin: 'com.jfrog.artifactory'

apply from: "$rootDir/gradle/dependencies.gradle"
apply from: "$rootDir/gradle/test-setup.gradle"
apply from: "$rootDir/gradle/functional-test.gradle"
apply from: "$rootDir/gradle/additional-artifacts.gradle"
apply from: "$rootDir/gradle/publishing.gradle"
apply from: "$rootDir/gradle/documentation.gradle"
apply from: "$rootDir/gradle/release.gradle"

repositories {
    jcenter()
    mavenCentral()
}

dependencies {
    compile localGroovy(), gradleApi()
    testCompile('org.spockframework:spock-core:1.0-groovy-2.4') {
        exclude group: 'org.codehaus.groovy'
    }
}

ext.compatibilityVersion = '1.7'
sourceCompatibility = compatibilityVersion
targetCompatibility = compatibilityVersion

jar {
    manifest {
        attributes 'Implementation-Title': 'gradle-bitbucket-rest-plugin',
                   'Implementation-Version': version,
                   'Built-By': System.getProperty('user.name'),
                   'Built-Date': new Date(),
                   'Built-JDK': System.getProperty('java.version'),
                   'Built-Gradle': gradle.gradleVersion
    }
}

tasks.withType(JavaCompile) {
	options.compilerArgs += ["-Xlint:-options"]
}

artifactory {
	contextUrl = artifactoryURL
	publish {
		repository {
			repoKey = version.endsWith('-SNAPSHOT') ? snapshotRepository : releaseRepository
			username = artifactoryUser
			password = artifactoryPassword
			mavenCompatible = true
		}
		defaults {
			publications ('artifactoryJava')
		}
	}
}

publishing {
	publications {
		artifactoryJava(MavenPublication) {
			from components.java
			artifact sourcesJar
			artifact groovydocJar
		}
	}
}