android-bintray.gradle

apply plugin: 'com.jfrog.bintray'

bintray {
    user = project.hasProperty('bintrayUser') ? project.property('bintrayUser') : System.getenv('BINTRAY_USER')
    key = project.hasProperty('bintrayKey') ? project.property('bintrayKey') : System.getenv('BINTRAY_KEY')

    publications = ['MyMaven']

    dryRun = project.hasProperty('bintrayDryRun')
    publish = project.hasProperty('bintrayPublish')
    override = project.hasProperty('bintrayOverride')

    pkg {
        repo = 'maven'
        name = "${project.group}:${project.name}"
        userOrg = user
        licenses = ['Apache-2.0']

        websiteUrl = rootProject.WEBSITE_URL
        issueTrackerUrl = rootProject.ISSUE_TRACKER_URL
        vcsUrl = rootProject.VCS_URL

        githubRepo = rootProject.GITHUB_REPO
        githubReleaseNotesFile = rootProject.GITHUB_RELEASE_NOTES_FILE

        publicDownloadNumbers = true

        version {
            name = project.version
            vcsTag = "v${project.version}"
            released  = new Date()
        }
    }
}

tasks.named("bintrayUpload").configure {
    dependsOn tasks.named("publishToMavenLocal")
}