build.gradle

version = "0.3.3.2-alpha"

// Set up javafx
buildscript {
    dependencies {
        classpath group: 'de.dynamicfiles.projects.gradle.plugins', name: 'javafx-gradle-plugin', version: '8.8.2'
    }

    repositories {
        mavenLocal()
        mavenCentral()
    }
}

// apply plugins
apply plugin: 'java'
apply plugin: 'javafx-gradle-plugin'

repositories {
    mavenLocal()
    mavenCentral()
}

javadoc{
    doLast{
        copy{
            from ("src/main/java"){
                include "**/doc-files/**"
            }
            into "build/docs/javadoc/"
        }
    }
}

jfx {
    // minimal requirement for jfxJar-task
    mainClass = 'com.creativeartie.writerstudio.main.Main'

    // minimal requirement for jfxNative-task
    vendor = 'CreativeArtie'
    nativeReleaseVersion = "${version}"

    bundleArguments = [
        licenseFile: 'LICENSE.md'
    ]

    // runAppParameter = '--test=base'
}

compileJava {
    options.encoding = 'UTF-8'
    options.compilerArgs << "-Xlint:unchecked" << "-Xlint:deprecation"
}

compileTestJava {
    options.encoding = 'UTF-8'
    options.compilerArgs << "-Xlint:unchecked" << "-Xlint:deprecation"
}

dependencies {
    testCompile group: 'org.junit.jupiter', name: 'junit-jupiter-api', version: '5.2.0'
    testCompile group: 'org.junit.jupiter', name: 'junit-jupiter-engine', version: '5.2.0'
    testCompile group: 'org.junit.jupiter', name: 'junit-jupiter-params', version: '5.2.0'

    compile group: 'com.google.guava', name: 'guava', version: '23.5-jre'
    compile group: 'org.fxmisc.richtext', name: 'richtextfx', version: '0.9.0'
    compile group: 'org.apache.pdfbox', name: 'pdfbox', version: '2.0.9'
}

test {
    // Enable JUnit 5 (Gradle 4.6+).
    useJUnitPlatform(){
        // "heavy" tests will take a long time to complete
        // "timed" tests requires exact timing, which possibly never happens
        excludeTags "heavy", "timed"
    }

    enableAssertions = 'true'

    // Show test results.
    testLogging {
        events "passed", "skipped", "failed"
    }

    doFirst {
        project.file("build/outputs/").mkdirs()
    }
}

task testAll(type: Test){
    group = 'Verification'
    description = 'Test all files, (take a lot longer then test)'

    useJUnitPlatform()

    // Always run tests, even when nothing changed.
    dependsOn 'cleanTest'

    enableAssertions = 'true'

    // Show test results.
    testLogging {
        events "passed", "skipped", "failed"
    }

    doFirst {
        project.file("build/outputs/").mkdirs()
    }

}