build.gradle

group 'dev.salascarlos.thymetextmode'
version '1.0.0'

buildscript {
    repositories {
        mavenCentral()
        mavenLocal()
        jcenter()
    }
    dependencies {
        classpath("org.springframework.boot:spring-boot-gradle-plugin:2.1.4.RELEASE")
        classpath "org.jfrog.buildinfo:build-info-extractor-gradle:4.4.17"
        classpath "net.saliman:gradle-cobertura-plugin:2.4.0"
    }
}

apply plugin: 'java'
apply plugin: "org.springframework.boot"
apply plugin: 'idea'
apply plugin: 'maven-publish'
apply plugin: "com.jfrog.artifactory"
apply plugin: "net.saliman.cobertura"
apply plugin: 'checkstyle'
apply plugin: 'findbugs'

jar {
    baseName = 'thymetextmode'
    version =  '1.0.0'
}

idea {
    module {
        inheritOutputDirs = false
        outputDir = file("$buildDir/classes/main/")
    }
}

repositories {

    maven { url "https://repo.maven.apache.org/maven2" }
    

}



publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java
        }
    }
}

//noinspection GroovyUnusedAssignment
sourceCompatibility = 1.8

//noinspection GroovyUnusedAssignment
targetCompatibility = 1.8

test {
    testLogging {
        showStandardStreams = true
        exceptionFormat = 'full'
    }
}

idea{
    module {
        downloadSources = true
    }
}

cobertura {
    coverageFormats = ["xml"]
}

checkstyle {
    configFile = rootProject.file('checkstyle/checkstyle.xml')
    toolVersion = '7.7'
}

findbugs {
    ignoreFailures = true
}

configurations {
    itestCompile.extendsFrom testCompile
    itestRuntime.extendsFrom testRuntime

}

sourceSets {
    itest {
        compileClasspath += main.output + test.output
        runtimeClasspath += main.output + test.output
        java.srcDir file('src/itest/java')

    }
    test {
        resources.srcDir file('src/itest/resources')
    }
}

task itest(type: Test) {
    testClassesDir = sourceSets.itest.output.classesDir
    classpath = sourceSets.itest.runtimeClasspath
    testLogging {
        showStandardStreams = true
        exceptionFormat = 'full'
    }

}

configurations {
    compile.exclude module: "spring-boot-starter-tomcat"
}

dependencies {
    compile group: 'com.google.guava', name: 'guava', version: '21.0'
    compile("org.springframework.boot:spring-boot-starter-web:2.1.4.RELEASE")
    compile("org.springframework.boot:spring-boot-starter-jetty:2.1.4.RELEASE")
    compile("com.fasterxml.jackson.datatype:jackson-datatype-jdk8:2.8.8")
    compile "org.springframework.boot:spring-boot-starter-thymeleaf:2.1.4.RELEASE"

    testCompile group: 'org.springframework.boot', name: 'spring-boot-starter-test', version: '2.1.4.RELEASE'

    itestCompile group: 'org.seleniumhq.selenium', name: 'selenium-java', version: '3.4.0'
    itestCompile group: 'org.seleniumhq.selenium', name: 'selenium-htmlunit-driver', version: '2.52.0'
    itestCompile group: 'org.springframework.boot', name: 'spring-boot-starter-test', version: '2.1.4.RELEASE'
}