-
Notifications
You must be signed in to change notification settings - Fork 1
/
rhyme.xsl
698 lines (683 loc) · 38.2 KB
/
rhyme.xsl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:html="http://www.w3.org/1999/xhtml" xmlns:djb="http://www.obdurodon.org"
xmlns:xs="http://www.w3.org/2001/XMLSchema" exclude-result-prefixes="#all" version="2.0">
<!--
Filename: rhyme.xsl
Developer: David J. Birnbaum 2015-05-15 (see GitHub repo for commit history)
Repo: http://github.com/djbpitt/poetry
Synopsis:
Adds rhyme scheme annotation and line numbers within stanza to XML input
Identifies only exact rhyme; intended for postprocessing to identify inexact rhyme
Normal input is XML document with <poem> -> <body> -> <stanza> -> <line>, where line has <stress> and text() nodes
May also be run against itself to identify rhyme scheme in included $poem variable
Dependencies (in same directory):
proclitic_inc.xsl (which imports proclitics.xml from same directory)
enclitic_inc.xsl (which imports enclitics.xml from same directory)
lexical_inc.xsl (which imports lexical.xml from same directory)
Notes:
Regex based on:
http://akhmatova.obdurodon.org/resources.html
http://dh.obdurodon.org/drupal/iterating-over-transformations-without-you-know-hitting-go-million-times
(requires authentication)
Thanks to Wendell Piez for the "visitor pattern" pointer
License: GNU AGPLv3
Visitor pattern steps
=========================================
djb:prepareWords() : Flatten
Convert stressed vowels to uppercase and remove stress tags
Convert other text to lowercase
Strip punctuation
Normalize white space
djb:lexical(): Correct for -ого and lexical idiosyncrasies (e.g., солнце)
Final -ogo/-ego (before stripping spaces), except:
(ne)?mnogo, strogo, ubogo, razlogo, otlogo, pologo, segodnja
Č > š: что(б?ы)?, конечн.*, нарочн.*, очечник.*, прачечн.*, скучно, яичниц.*, ильиничн.*, саввичн.*, никитичн.*
Idiosyncrasies: solnc.*, zdravstvuj.*, čuvstv*, zvezdn.*, landšaft.*, pozdno, prazdnik.*, serdc.*, grustn.*,
izvestn.*, lestn.*, mestn.*, okrestnost.*, častn.*, sčastliv.*
djb:proclitics() : Merge proclitics with bases
djb:enclitics() : Merge enclitics with bases
djb:tsa() : Convert ть?ся$ to тса
djb:palatalize() : Capitalize all palatalized consonants (including unpaired)
djb:jot() : Normalize /j/
Insert Й before softening vowels after vowels, hard or soft sign, and (except in anlaut) и
Convert softening vowels to non-softening
Strip hard and soft signs
djb:romanize() : Romanize now that all information is represented by the segment
djb:finalDevoice() : Devoice obstruents in auslaut
djb:regressiveDevoice() : Regressive devoicing of obstruents and /v/
/v/ is easier to handle if we do devoicing first
djb:regressiveVoice() : Regressive voicing of obstruents, including /v/
djb:palatalAssimilation() : Regressive palatalization (Wade, section 6, p. 9)
djb:consonantCleanup() : c > ts, sč to šč, degeminate
djb:vowelReducation() : unstressed non-high vowels are i after soft consonants and i < e, a < o after hard
djb:stripSpaces() : remove all spaces
djb:rhymeString() : extract rhyme string (last stressed vowel, all following, supporting C for open masculine)
-->
<xsl:output method="xml" indent="yes"/>
<!-- ======================================== -->
<!--
Create bitstring for rhyming segment; return rhyming vowel and full bitstring
-->
<!-- ======================================== -->
<xsl:variable name="featureFile" as="document-node()" select="document('feature-chart.xhtml')"/>
<xsl:key name="bitStringBySegment" match="html:tr" use="html:th"/>
<xsl:function name="djb:bits" as="xs:string+">
<xsl:param name="input" as="xs:string"/>
<xsl:variable name="stressedVowel" as="xs:string" select="replace($input, '[^AEIOU]', '')"/>
<xsl:variable name="rhymeVowelBitString" as="xs:string"
select="string-join(key('bitStringBySegment', $stressedVowel, $featureFile)/html:td, '')"/>
<xsl:variable name="bitStrings" as="xs:string+">
<!-- bitstring for full rhyme -->
<xsl:for-each
select="
for $char in string-to-codepoints($input)
return
codepoints-to-string($char)">
<xsl:value-of
select="string-join(key('bitStringBySegment', ., $featureFile)/html:td, '')"/>
</xsl:for-each>
</xsl:variable>
<xsl:sequence select="($rhymeVowelBitString, string-join($bitStrings, ''))"/>
</xsl:function>
<!-- ======================================== -->
<!-- ======================================== -->
<!-- djb:findInexact(lines as element(line)+) as element(line)+ -->
<!-- ======================================== -->
<xsl:function name="djb:findInexact" as="element(line)+">
<xsl:param name="inputLines"/>
<xsl:param name="offset" as="xs:integer"/>
<xsl:choose>
<xsl:when test="$offset gt count($inputLines)">
<!-- all lines have been processed -->
<xsl:sequence select="$inputLines"/>
</xsl:when>
<xsl:otherwise>
<xsl:variable name="allLetters" as="xs:string+" select="$inputLines/@letter"/>
<xsl:variable name="unmatched_letters" as="xs:string*"
select="$allLetters[count(index-of($allLetters, .)) eq 1]"/>
<xsl:variable name="currentLine" as="element(line)" select="$inputLines[$offset]"/>
<xsl:choose>
<xsl:when test="not($currentLine/@letter = $unmatched_letters)">
<!-- $currentLine has a rhyme already -->
<xsl:sequence select="djb:findInexact($inputLines, $offset + 1)"/>
</xsl:when>
<xsl:otherwise>
<!-- domain is three preceding lines (not following, since we'll get to those later -->
<xsl:variable name="domain" as="element(line)*"
select="$inputLines[position() gt $offset - 4 and position() lt $offset and @letter = $unmatched_letters]"/>
<xsl:choose>
<!-- if there is a preceding stressed vowel match, the closest one is the rhyme -->
<xsl:when test="$currentLine/@vowelBitString = $domain/@vowelBitString">
<xsl:variable name="precedingRhymingLine" as="element(line)"
select="$domain[@vowelBitString = $currentLine/@vowelBitString][1]"/>
<xsl:variable name="newRhymeLetter" as="xs:string"
select="$precedingRhymingLine/@letter"/>
<xsl:variable name="rerhymedLine" as="element(line)">
<line>
<xsl:sequence
select="$currentLine/@* except $currentLine/@letter"/>
<xsl:attribute name="letter" select="$newRhymeLetter"/>
<xsl:sequence select="$currentLine/node()"/>
</line>
</xsl:variable>
<xsl:variable name="updatedInput" as="element(line)+">
<xsl:sequence select="$inputLines[position() lt $offset]"/>
<xsl:sequence select="$rerhymedLine"/>
<xsl:sequence select="$inputLines[position() gt $offset]"/>
</xsl:variable>
<xsl:sequence select="djb:findInexact($updatedInput, $offset + 2)"/>
</xsl:when>
<xsl:otherwise>
<!-- no rhyme; return line as is -->
<xsl:sequence select="djb:findInexact($inputLines, $offset + 1)"/>
</xsl:otherwise>
</xsl:choose>
</xsl:otherwise>
</xsl:choose>
</xsl:otherwise>
</xsl:choose>
</xsl:function>
<!-- ======================================== -->
<!-- ======================================== -->
<!-- Sample poem, used when stylesheet is run against itself -->
<!-- ======================================== -->
<xsl:variable name="poem" as="document-node()" select="doc('eo.xml')"/>
<!-- ======================================== -->
<!-- ======================================== -->
<!-- Variables used for rhyme scheme ($alphabet) and rhyme gender ($gender) -->
<!-- ======================================== -->
<xsl:variable name="alphabet"
select="tokenize('a b c d e f g h i j k l m n o p q r s t u v w x y z', ' ')"
as="xs:string+"/>
<xsl:variable name="genders" select="tokenize('m f d h1 h2 h3', ' ')" as="xs:string+"/>
<!-- ======================================== -->
<!-- ======================================== -->
<!-- Build table of rhymes by stressed vowel (used to resolve imperfect rhyme) -->
<!-- ======================================== -->
<xsl:key name="lineByStressedVowel" match="line" use="@vowelBitString"/>
<!-- ======================================== -->
<!-- ======================================== -->
<!-- Process <poem> element (external or embedded); identity template -->
<!-- ======================================== -->
<xsl:template match="/">
<xsl:choose>
<xsl:when test="tokenize(base-uri(), '/')[last()] eq 'rhyme.xsl'">
<xsl:apply-templates select="$poem"/>
</xsl:when>
<xsl:otherwise>
<xsl:apply-templates/>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xsl:template match="poem">
<xsl:copy>
<xsl:copy-of select="meta"/>
<xsl:apply-templates select="body"/>
</xsl:copy>
</xsl:template>
<xsl:template match="node() | @*">
<xsl:copy>
<xsl:apply-templates select="node() | @*"/>
</xsl:copy>
</xsl:template>
<!-- ======================================== -->
<!-- ======================================== -->
<!-- "Visitor" pattern; perform operations in this order -->
<!-- ======================================== -->
<xsl:variable name="operations" as="element()+">
<djb:prepareWords/>
<djb:lexical/>
<djb:proclitics/>
<djb:enclitics/>
<djb:tsa/>
<djb:palatalize/>
<djb:jot/>
<djb:romanize/>
<djb:finalDevoice/>
<djb:regressiveDevoice/>
<djb:regressiveVoice/>
<djb:palatalAssimilation/>
<djb:consonantCleanup/>
<djb:vowelReduction/>
<!--
diagnosticOutput writes the string to stderr as an <xsl:message>
move it around or comment it out, as appropriate
-->
<!--<djb:diagnosticOutput/>-->
<djb:stripSpaces/>
<djb:rhymeString/>
</xsl:variable>
<!-- ======================================== -->
<!-- ======================================== -->
<!-- Process stanzas here -->
<!-- ======================================== -->
<xsl:template match="stanza">
<xsl:variable name="lines_with_exact_rhyme" as="document-node()">
<!-- Make it a document so that we can use a key -->
<xsl:document>
<stanza>
<!-- ======================================== -->
<!-- Process lines phonetically before determining rhyme scheme -->
<!-- ======================================== -->
<xsl:variable name="processed" as="element(line)+">
<xsl:apply-templates select="line"/>
</xsl:variable>
<!-- ======================================== -->
<!-- Group lines by rhyme and create rhyme scheme -->
<!-- ======================================== -->
<xsl:variable name="outputLines" as="element(line)+">
<xsl:for-each-group select="$processed" group-by="@rhymeString">
<xsl:variable name="offset" as="xs:integer" select="position()"/>
<xsl:variable name="posttonic" as="xs:string"
select="replace(current-grouping-key(), '[^aeiou]+', '')"/>
<xsl:variable name="gender" as="xs:string"
select="$genders[position() eq string-length($posttonic) + 1]"/>
<xsl:variable name="letter" as="xs:string"
select="
$alphabet[position() eq (if ($offset mod 26 eq 0) then
26
else
$offset mod 26)]"/>
<xsl:variable name="renderedLetter" as="xs:string">
<xsl:choose>
<xsl:when test="$gender eq 'm'">
<xsl:value-of select="$letter"/>
</xsl:when>
<xsl:when test="$gender eq 'f'">
<xsl:value-of select="upper-case($letter)"/>
</xsl:when>
<xsl:when test="$gender eq 'd'">
<xsl:value-of select="concat(upper-case($letter), '′')"/>
</xsl:when>
<xsl:otherwise>
<xsl:value-of select="concat(upper-case($letter), '′′')"/>
</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<xsl:for-each select="current-group()">
<line letter="{$renderedLetter}">
<xsl:apply-templates select="@* | node()"/>
</line>
</xsl:for-each>
</xsl:for-each-group>
</xsl:variable>
<xsl:for-each select="$outputLines">
<xsl:sort select="number(@position)"/>
<xsl:copy-of select="."/>
</xsl:for-each>
</stanza>
</xsl:document>
</xsl:variable>
<!-- ======================================== -->
<!--
By this stage $stanza_with_exact_rhyme includes all exact rhymes
Now process for inexact
-->
<!-- ======================================== -->
<!-- ======================================== -->
<!-- Now process lines -->
<!-- ======================================== -->
<xsl:apply-templates select="$lines_with_exact_rhyme" mode="inexact"/>
</xsl:template>
<!-- ======================================== -->
<!-- ======================================== -->
<!-- First fine exact rhymes (no mode) -->
<!-- ======================================== -->
<!-- Process original input lines here -->
<!-- ======================================== -->
<xsl:template match="line">
<!-- ======================================== -->
<!-- The visitor tour gets the rhyme string -->
<!-- ======================================== -->
<xsl:variable name="rhymeString" as="xs:string">
<xsl:apply-templates select="$operations[1]" mode="operate">
<xsl:with-param name="input" select="."/>
<xsl:with-param name="remaining" select="remove($operations, 1)"/>
</xsl:apply-templates>
</xsl:variable>
<!-- ======================================== -->
<!-- Add line order, rhyme string, and bitstring to line -->
<!-- ======================================== -->
<xsl:variable name="bitStrings" as="xs:string+" select="djb:bits($rhymeString)"/>
<line position="{position()}" rhymeString="{$rhymeString}" vowelBitString="{$bitStrings[1]}"
bitString="{$bitStrings[2]}">
<xsl:apply-templates/>
</line>
</xsl:template>
<xsl:template match="line/text()">
<xsl:value-of select="replace(., '\s+', ' ')"/>
</xsl:template>
<!-- ======================================== -->
<!-- ======================================== -->
<!-- djb:prepareWords
Convert stressed vowels to uppercase and remove <stress> tags
Lowercase everything else
Strip punctuation
Input is <line>, output is string, all subsequent operations are on strings
This is the only visitor pattern not included in the general rule below
because it takes element(line) input
-->
<!-- ======================================== -->
<xsl:template match="djb:prepareWords" mode="operate">
<xsl:param name="input" as="element(line)" required="yes"/>
<xsl:param name="remaining" as="element()*"/>
<xsl:variable name="withWhiteSpace" as="xs:string+">
<!-- uppercase stressed vowel, lowercase other letters, strip punctuation -->
<xsl:apply-templates select="$input" mode="#current"/>
</xsl:variable>
<xsl:variable name="result" as="xs:string" select="string-join($withWhiteSpace, '')"/>
<xsl:apply-templates select="$remaining[1]" mode="#current">
<xsl:with-param name="input" select="$result"/>
<xsl:with-param name="remaining" select="remove($remaining, 1)"/>
</xsl:apply-templates>
<xsl:if test="empty($remaining)">
<xsl:sequence select="$result"/>
</xsl:if>
</xsl:template>
<xsl:template match="stress" mode="operate">
<xsl:value-of select="upper-case(.)"/>
</xsl:template>
<xsl:template match="line/text()" mode="operate">
<xsl:value-of select="replace(lower-case(.), '\p{P}', '')"/>
</xsl:template>
<!-- ======================================== -->
<!-- ======================================== -->
<!-- Include external functions -->
<!-- ======================================== -->
<xsl:include href="proclitic_inc.xsl"/>
<xsl:include href="enclitic_inc.xsl"/>
<xsl:include href="lexical_inc.xsl"/>
<!-- ======================================== -->
<!-- ======================================== -->
<!-- all visitor elements except djb:prepareWords (above), which requires element (not string) input -->
<!-- ======================================== -->
<xsl:template match="djb:*" mode="operate">
<xsl:param name="input" as="xs:string" required="yes"/>
<xsl:param name="remaining" as="element()*"/>
<xsl:variable name="results" as="xs:string*">
<xsl:choose>
<!-- ======================================== -->
<!-- djb:lexical: Idiosyncrasies in pronunciation (including -ogo) -->
<!-- ======================================== -->
<xsl:when test="self::djb:lexical">
<xsl:sequence select="djb:lexical($input)"/>
</xsl:when>
<!-- ======================================== -->
<!-- djb:proclitics: Merge proclitics with bases -->
<!-- ======================================== -->
<xsl:when test="self::djb:proclitics">
<xsl:sequence select="djb:proclitic($input, 1)"/>
</xsl:when>
<!-- ======================================== -->
<!-- djb:enclitics: Merge enclitics with bases -->
<!-- ======================================== -->
<xsl:when test="self::djb:enclitics">
<xsl:sequence select="djb:enclitic($input, 1)"/>
</xsl:when>
<!-- ======================================== -->
<!-- djb:tsa: Convert ть?ся$ to тса -->
<!-- ======================================== -->
<xsl:when test="self::djb:tsa">
<xsl:sequence select="replace($input, 'ться$', 'тса')"/>
</xsl:when>
<!-- ======================================== -->
<!-- djb:palatalize: Capitalize all palatalized consonants (including unpaired) -->
<!-- ======================================== -->
<xsl:when test="self::djb:palatalize">
<xsl:variable name="result1" as="xs:string+">
<xsl:analyze-string select="$input"
regex="([бвгдзклмнпрстфх])([яеиёюЯЕИЁЮь])">
<xsl:matching-substring>
<xsl:sequence
select="concat(upper-case(regex-group(1)), regex-group(2))"/>
</xsl:matching-substring>
<xsl:non-matching-substring>
<xsl:sequence select="."/>
</xsl:non-matching-substring>
</xsl:analyze-string>
</xsl:variable>
<xsl:sequence select="translate(string-join($result1, ''), 'чйщ', 'ЧЙЩ')"/>
</xsl:when>
<!-- ======================================== -->
<!-- djb:jot() : Normalize /j/ -->
<!-- ======================================== -->
<!--
Insert Й before softening vowels after vowels, hard or soft sign, and (except in anlaut) и
Convert softening vowels to non-softening
Strip hard and soft signs
-->
<xsl:when test="self::djb:jot">
<!-- $result1 processes softening vowels after vowels and signs, but not in anlaut-->
<xsl:variable name="result1" as="xs:string+">
<xsl:analyze-string select="$input"
regex="([аэыоуяеиёюАЭЫОУЯЕИЁЮьъ])([яеиёюЯЕИЁЮ])">
<xsl:matching-substring>
<xsl:value-of select="concat(regex-group(1), 'Й', regex-group(2))"/>
</xsl:matching-substring>
<xsl:non-matching-substring>
<xsl:value-of select="."/>
</xsl:non-matching-substring>
</xsl:analyze-string>
</xsl:variable>
<!-- $result2 processes softening vowels except и in anlaut-->
<xsl:variable name="result2" as="xs:string+">
<xsl:analyze-string select="string-join($result1, '')"
regex="( |^)([яеёюЯЕЁЮ])">
<xsl:matching-substring>
<xsl:value-of select="concat(regex-group(1), 'Й', regex-group(2))"/>
</xsl:matching-substring>
<xsl:non-matching-substring>
<xsl:value-of select="."/>
</xsl:non-matching-substring>
</xsl:analyze-string>
</xsl:variable>
<!-- $result3 conflates softening vowels into regular ones and strips hard and soft signs-->
<xsl:sequence
select="translate(string-join($result2, ''), 'яеиёюЯЕИЁЮьъ', 'аэыоуАЭЫОУ')"
/>
</xsl:when>
<!-- ======================================== -->
<!-- djb:romanize: Romanize now that all information is encoded in the segment -->
<!-- ======================================== -->
<xsl:when test="self::djb:romanize">
<xsl:sequence
select="replace(translate($input, 'абвгджзклмнопрстуфхцшыэАБВГДЖЗЙКЛМНОПРСТУФХЦЧШЩЫЭ', 'abvgdžzklmnoprstufxcšieABVGDŽZJKLMNOPRSTUFXCČŠQIE'), 'Q', 'ŠČ')"
/>
</xsl:when>
<!-- ======================================== -->
<!-- djb:finalDevoice: Devoice obstruents in auslaut -->
<!-- ======================================== -->
<xsl:when test="self::djb:finalDevoice">
<xsl:variable name="result1" as="xs:string+">
<xsl:analyze-string select="$input" regex="([bvgdžzBVGDZ])( |$)">
<xsl:matching-substring>
<xsl:value-of
select="concat(translate(regex-group(1), 'bvgdžzBVGDZ', 'pfktšsPFKTS'), regex-group(2))"
/>
</xsl:matching-substring>
<xsl:non-matching-substring>
<xsl:value-of select="."/>
</xsl:non-matching-substring>
</xsl:analyze-string>
</xsl:variable>
<xsl:sequence select="string-join($result1, '')"/>
</xsl:when>
<!-- ======================================== -->
<!-- djb:regressiveDevoice: Regressive devoicing of obstruents, including /v/ -->
<!-- ======================================== -->
<xsl:when test="self::djb:regressiveDevoice">
<xsl:variable name="result1" as="xs:string+">
<xsl:analyze-string select="$input"
regex="([bvgdžzBVGDZpfktšsPFKTSkcČ]+)([pfktšsPFKTSkcČ])">
<xsl:matching-substring>
<xsl:value-of
select="concat(translate(regex-group(1), 'bvgdžzBVGDZ', 'pfktšsPFKTS'), regex-group(2))"
/>
</xsl:matching-substring>
<xsl:non-matching-substring>
<xsl:value-of select="."/>
</xsl:non-matching-substring>
</xsl:analyze-string>
</xsl:variable>
<xsl:sequence select="string-join($result1, '')"/>
</xsl:when>
<!-- ======================================== -->
<!-- djb:regressiveVoice Regressive voicing of obstruents, but not before /v/ -->
<!-- ======================================== -->
<!--
ɣ (LC) = U+0263, Ɣ (UC) = U+0194
ʒ (LC) = U+0292, Ʒ (UC) = U+01B7
ǯ (LC) = U+01EF, Ǯ (UC) = U+01EE
-->
<xsl:when test="self::djb:regressiveVoice">
<xsl:variable name="result1" as="xs:string+">
<xsl:analyze-string select="$input"
regex="([bvgdžzBVGDZpfktšsPFKTSxcČ]+)([bgdžzBGDZ])">
<xsl:matching-substring>
<xsl:value-of
select="concat(translate(regex-group(1), 'pfktšsPFKTSxcČ', 'bvgdžzBVGDZɣʒǮ'), regex-group(2))"
/>
</xsl:matching-substring>
<xsl:non-matching-substring>
<xsl:value-of select="."/>
</xsl:non-matching-substring>
</xsl:analyze-string>
</xsl:variable>
<xsl:sequence select="string-join($result1, '')"/>
</xsl:when>
<!-- ======================================== -->
<!-- djb:palatalAssimilation: Regressive palatalization assimilation -->
<!-- ======================================== -->
<!-- šc has already been split, so requires special treatment -->
<xsl:when test="self::djb:palatalAssimilation">
<xsl:variable name="result3" as="xs:string+">
<xsl:analyze-string select="$input" regex="[tdn]+[TDNSZČL]+">
<xsl:matching-substring>
<xsl:value-of select="upper-case(.)"/>
</xsl:matching-substring>
<xsl:non-matching-substring>
<xsl:value-of select="."/>
</xsl:non-matching-substring>
</xsl:analyze-string>
</xsl:variable>
<xsl:variable name="result2" as="xs:string+">
<xsl:analyze-string select="string-join($result3, '')"
regex="[tdnTDNSZČL]+ŠČ">
<xsl:matching-substring>
<xsl:value-of select="upper-case(.)"/>
</xsl:matching-substring>
<xsl:non-matching-substring>
<xsl:value-of select="."/>
</xsl:non-matching-substring>
</xsl:analyze-string>
</xsl:variable>
<xsl:variable name="result1" as="xs:string+">
<xsl:analyze-string select="string-join($result2, '')"
regex="[tdnsz]+[TDNSZL]+">
<xsl:matching-substring>
<xsl:value-of select="upper-case(.)"/>
</xsl:matching-substring>
<xsl:non-matching-substring>
<xsl:value-of select="."/>
</xsl:non-matching-substring>
</xsl:analyze-string>
</xsl:variable>
<xsl:sequence select="string-join($result1, '')"/>
</xsl:when>
<!-- ======================================== -->
<!-- djb:consonantCleanup() : c > ts, sČ to ŠČ, degeminate -->
<!-- ======================================== -->
<xsl:when test="self::djb:consonantCleanup">
<xsl:variable name="result3" as="xs:string+">
<xsl:analyze-string select="$input" regex="c">
<xsl:matching-substring>
<xsl:text>ts</xsl:text>
</xsl:matching-substring>
<xsl:non-matching-substring>
<xsl:value-of select="."/>
</xsl:non-matching-substring>
</xsl:analyze-string>
</xsl:variable>
<xsl:variable name="result2" as="xs:string+">
<xsl:analyze-string select="string-join($result3, '')" regex="sČ">
<xsl:matching-substring>
<xsl:text>ŠČ</xsl:text>
</xsl:matching-substring>
<xsl:non-matching-substring>
<xsl:value-of select="."/>
</xsl:non-matching-substring>
</xsl:analyze-string>
</xsl:variable>
<xsl:variable name="result1" as="xs:string+">
<xsl:analyze-string select="string-join($result2, '')" regex="(.)\1">
<xsl:matching-substring>
<xsl:value-of select="regex-group(1)"/>
</xsl:matching-substring>
<xsl:non-matching-substring>
<xsl:value-of select="."/>
</xsl:non-matching-substring>
</xsl:analyze-string>
</xsl:variable>
<xsl:sequence select="string-join($result1, '')"/>
</xsl:when>
<!-- ======================================== -->
<!-- djb:vowelReduction() : unstressed non-high vowels > i after soft consonants and e > i, o > a after hard -->
<!-- ======================================== -->
<xsl:when test="self::djb:vowelReduction">
<xsl:variable name="result1" as="xs:string+">
<xsl:analyze-string select="$input" regex="([BVGDJZKLMNPRSTFXČ])([eao])">
<xsl:matching-substring>
<xsl:value-of select="concat(regex-group(1), 'i')"/>
</xsl:matching-substring>
<xsl:non-matching-substring>
<xsl:value-of select="."/>
</xsl:non-matching-substring>
</xsl:analyze-string>
</xsl:variable>
<xsl:sequence select="translate(string-join($result1, ''), 'eo', 'ia')"/>
</xsl:when>
<!-- ======================================== -->
<!-- djb:diagnosticOutput() : write string to stderr as <xsl:message> -->
<!-- ======================================== -->
<xsl:when test="self::djb:diagnosticOutput">
<xsl:message>
<xsl:sequence select="$input"/>
</xsl:message>
<xsl:sequence select="$input"/>
</xsl:when>
<!-- ======================================== -->
<!-- djb:stripSpaces() : strip all white space -->
<!-- ======================================== -->
<xsl:when test="self::djb:stripSpaces">
<xsl:sequence select="translate($input, ' ', '')"/>
</xsl:when>
<!-- ======================================== -->
<!-- djb:rhymeString(): last stressed vowel, all following, supporting C for open masculine -->
<!-- ======================================== -->
<xsl:when test="self::djb:rhymeString">
<xsl:variable name="result" as="xs:string">
<xsl:analyze-string select="$input" regex="(.)([AEIOU])([^AEIOU]*)$">
<xsl:matching-substring>
<xsl:value-of
select="
concat(if (regex-group(3) eq '')
then
regex-group(1)
else
(),
regex-group(2),
regex-group(3))"
/>
</xsl:matching-substring>
</xsl:analyze-string>
</xsl:variable>
<xsl:sequence select="$result"/>
</xsl:when>
<!-- ======================================== -->
<!-- Default to continue processing if operate step has no code -->
<!-- ======================================== -->
<!--<xsl:otherwise>
<xsl:apply-templates select="$remaining[1]" mode="visit">
<xsl:with-param name="remaining" select="remove($remaining, 1)"/>
<xsl:with-param name="so-far" select="so-far"/>
</xsl:apply-templates>
</xsl:otherwise>-->
<!-- ======================================== -->
<!-- Default to terminate if operate step has no code -->
<!-- ======================================== -->
<xsl:otherwise>
<xsl:message terminate="yes">Unmatched visitor element <xsl:value-of
select="local-name()"/></xsl:message>
</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<xsl:variable name="result" as="xs:string" select="string-join($results, '')"/>
<!-- ======================================== -->
<!-- Move on to the next step or return if done -->
<!-- ======================================== -->
<xsl:apply-templates select="$remaining[1]" mode="#current">
<xsl:with-param name="input" select="$result"/>
<xsl:with-param name="remaining" select="remove($remaining, 1)"/>
</xsl:apply-templates>
<xsl:if test="empty($remaining)">
<xsl:sequence select="$result"/>
</xsl:if>
</xsl:template>
<!-- ======================================== -->
<!-- Process inexact rhyme (mode="inexact") -->
<!-- ======================================== -->
<xsl:template match="node() | @*" mode="inexact">
<xsl:copy>
<xsl:apply-templates select="node() | @*" mode="#current"/>
</xsl:copy>
</xsl:template>
<xsl:template match="stanza" mode="inexact">
<xsl:variable name="allLines" as="element(line)+">
<xsl:sequence select="line"/>
</xsl:variable>
<stanza>
<xsl:sequence select="djb:findInexact($allLines, 1)"/>
</stanza>
</xsl:template>
</xsl:stylesheet>