Use gleam/dynamic/decode module for decoding JSON

Author: sisou

README.md

@@ -29,7 +29,7 @@ Further documentation can be found at <https://hexdocs.pm/fiber>.
 ## Client Example
 
 ```gleam
-import gleam/dynamic
+import gleam/dynamic/decode
 import gleam/json
 import gleeunit/should
 
@@ -45,7 +45,7 @@ fn start_client(fiber) {
 fn ping() {
   request.new(method: "ping")
   // We expect "pong" from this, so we can decode the result into a string.
-  |> request.with_decoder(dynamic.string)
+  |> request.with_decoder(decode.string)
 }
 
 fn file_updated(file_name) {

birdie_snapshots/invalid_request_error_message.accepted

@@ -1,7 +1,7 @@
 ---
-version: 1.2.3
+version: 1.2.6
 title: invalid request error message
 file: ./test/message_test.gleam
 test_name: invalid_message_test
 ---
-UnexpectedFormat([DecodeError("another type", "Dict", [])])
+UnableToDecode([DecodeError("Message", "Dict", [])])

src/fiber.gleam

@@ -1,5 +1,6 @@
 import gleam/dict
 import gleam/dynamic.{type Dynamic}
+import gleam/dynamic/decode
 import gleam/erlang/process
 import gleam/list
 import gleam/option
@@ -64,7 +65,7 @@ pub fn server_only(builder: backend.FiberBuilder) -> backend.FiberBuilder {
 
 pub type RequestError(a) {
   ReturnedError(message.ErrorData(Dynamic))
-  DecodeError(dynamic.DecodeErrors)
+  DecodeError(List(decode.DecodeError))
   CallError(process.CallError(a))
 }
 
@@ -85,7 +86,7 @@ pub fn call(
     |> result.map(fn(call_result) {
       call_result
       |> result.map(fn(data) {
-        request.decoder(data)
+        decode.run(data, request.decoder)
         |> result.map_error(DecodeError)
       })
       |> result.map_error(ReturnedError)

src/fiber/message.gleam

@@ -1,4 +1,5 @@
 import gleam/dynamic.{type Dynamic}
+import gleam/dynamic/decode
 import gleam/json.{type Json}
 import gleam/option.{type Option}
 import gleam/pair
@@ -35,87 +36,91 @@ pub type Message(dyn) {
   BatchResponseMessage(List(Response(dyn)))
 }
 
-fn id_decoder() {
-  dynamic.any([
-    fn(data) { dynamic.int(data) |> result.map(IntId) },
-    fn(data) { dynamic.string(data) |> result.map(StringId) },
+fn id_decoder() -> decode.Decoder(Id) {
+  decode.one_of(decode.int |> decode.map(IntId), [
+    decode.string |> decode.map(StringId),
   ])
+  |> decode.collapse_errors("Id")
 }
 
-fn error_data_decoder() {
-  dynamic.any([
-    fn(v) { dynamic.string(v) |> result.map(ErrorString) },
-    dynamic.decode3(
-      ErrorData,
-      dynamic.optional_field("data", dynamic.dynamic),
-      dynamic.field("code", dynamic.int),
-      dynamic.field("message", dynamic.string),
-    ),
-  ])
-}
-
-fn request_decoder() {
-  dynamic.any([
-    dynamic.decode3(
-      Request,
-      dynamic.optional_field("params", dynamic.dynamic),
-      dynamic.field("method", dynamic.string),
-      dynamic.field("id", id_decoder()),
-    ),
-    dynamic.decode2(
-      Notification,
-      dynamic.optional_field("params", dynamic.dynamic),
-      dynamic.field("method", dynamic.string),
-    ),
-  ])
-}
-
-fn response_decoder() {
-  dynamic.any([
-    dynamic.decode2(
-      SuccessResponse,
-      dynamic.field("result", dynamic.dynamic),
-      dynamic.field("id", id_decoder()),
-    ),
-    dynamic.decode2(
-      ErrorResponse,
-      dynamic.field("error", error_data_decoder()),
-      dynamic.field("id", id_decoder()),
-    ),
+fn error_data_decoder() -> decode.Decoder(ErrorData(Dynamic)) {
+  decode.one_of(decode.string |> decode.map(ErrorString), [
+    {
+      use data <- decode.optional_field(
+        "data",
+        option.None,
+        decode.optional(decode.dynamic),
+      )
+      use code <- decode.field("code", decode.int)
+      use message <- decode.field("message", decode.string)
+      decode.success(ErrorData(data, code, message))
+    },
   ])
+  |> decode.collapse_errors("ErrorData")
 }
 
-fn error_decoder() {
-  dynamic.field("error", error_data_decoder())
-}
-
-fn message_decoder() {
-  dynamic.any([
-    fn(d) {
-      response_decoder()(d)
-      |> result.map(ResponseMessage)
-    },
-    fn(d) {
-      request_decoder()(d)
-      |> result.map(RequestMessage)
-    },
-    fn(d) {
-      error_decoder()(d)
-      |> result.map(ErrorMessage)
-    },
-    fn(d) {
-      dynamic.list(request_decoder())(d)
-      |> result.map(BatchRequestMessage)
+fn request_decoder() -> decode.Decoder(Request(Dynamic)) {
+  decode.one_of(
+    {
+      use params <- decode.optional_field(
+        "params",
+        option.None,
+        decode.optional(decode.dynamic),
+      )
+      use method <- decode.field("method", decode.string)
+      use id <- decode.field("id", id_decoder())
+      decode.success(Request(params, method, id))
     },
-    fn(d) {
-      dynamic.list(response_decoder())(d)
-      |> result.map(BatchResponseMessage)
+    [
+      {
+        use params <- decode.optional_field(
+          "params",
+          option.None,
+          decode.optional(decode.dynamic),
+        )
+        use method <- decode.field("method", decode.string)
+        decode.success(Notification(params, method))
+      },
+    ],
+  )
+  |> decode.collapse_errors("Request")
+}
+
+fn response_decoder() -> decode.Decoder(Response(Dynamic)) {
+  decode.one_of(
+    {
+      use result <- decode.field("result", decode.dynamic)
+      use id <- decode.field("id", id_decoder())
+      decode.success(SuccessResponse(result, id))
     },
+    [
+      {
+        use error <- decode.field("error", error_data_decoder())
+        use id <- decode.field("id", id_decoder())
+        decode.success(ErrorResponse(error, id))
+      },
+    ],
+  )
+  |> decode.collapse_errors("Response")
+}
+
+fn error_decoder() -> decode.Decoder(ErrorData(Dynamic)) {
+  use error <- decode.field("error", error_data_decoder())
+  decode.success(error)
+}
+
+fn message_decoder() -> decode.Decoder(Message(Dynamic)) {
+  decode.one_of(response_decoder() |> decode.map(ResponseMessage), [
+    request_decoder() |> decode.map(RequestMessage),
+    error_decoder() |> decode.map(ErrorMessage),
+    decode.list(request_decoder()) |> decode.map(BatchRequestMessage),
+    decode.list(response_decoder()) |> decode.map(BatchResponseMessage),
   ])
+  |> decode.collapse_errors("Message")
 }
 
 pub fn decode(text: String) -> Result(Message(Dynamic), json.DecodeError) {
-  json.decode(text, message_decoder())
+  json.parse(text, message_decoder())
 }
 
 pub fn from_json(text: String) -> Result(Message(Dynamic), json.DecodeError) {

src/fiber/request.gleam

@@ -1,4 +1,5 @@
 import gleam/dynamic.{type Dynamic}
+import gleam/dynamic/decode
 import gleam/json.{type Json}
 import gleam/option.{type Option}
 import youid/uuid
@@ -9,7 +10,7 @@ pub type Request(return) {
   Request(
     method: String,
     params: Option(Json),
-    decoder: dynamic.Decoder(return),
+    decoder: decode.Decoder(return),
     id: Option(message.Id),
   )
 }
@@ -18,7 +19,7 @@ pub fn new(method method: String) -> Request(Dynamic) {
   Request(
     method:,
     params: option.None,
-    decoder: dynamic.dynamic,
+    decoder: decode.dynamic,
     id: option.None,
   )
 }
@@ -29,7 +30,7 @@ pub fn with_params(request: Request(a), params: Json) -> Request(a) {
 
 pub fn with_decoder(
   request: Request(a),
-  decoder decoder: dynamic.Decoder(b),
+  decoder decoder: decode.Decoder(b),
 ) -> Request(b) {
   Request(
     method: request.method,