build.gradle

plugins {
    id 'io.micronaut.application'
    id 'com.gradleup.shadow'
    id 'io.micronaut.openapi'
    id 'backend.server-conventions'
}

dependencies {
    implementation(project(":core"))

    // OpenAPI support
    annotationProcessor(mn.micronaut.openapi)
    compileOnly(mn.micronaut.openapi.annotations)

    // To try out the functions locally via a Netty HTTP server
    developmentOnly(mn.micronaut.http.server.netty)

    // For rendering the MDENet Education Platform tools JSON file
    implementation("org.eclipse.epsilon:org.eclipse.epsilon.egl.engine:${epsilonVersion}")

    // For testing the additional logic for exposing the services as an MDENet EP tool
    testImplementation(mn.micronaut.http.client)
    testImplementation(mn.micronaut.reactor)
}

application {
    mainClass = "org.eclipse.epsilon.labs.playground.Application"
}

micronaut {
    runtime("netty")
    testRuntime("junit5")
    processing {
        incremental(true)
        annotations("org.eclipse.epsilon.labs.playground.fn.*")
    }
}

tasks.named("dockerBuild") {
    images = (
        dockerTags
            .split(',')
            .collect {"ghcr.io/epsilonlabs/playground-backend/ep-tool-server:${it}"}
    )
}

// Webpack for syntax highlighting

def webpackBuildDir = "build/webpack"

task webpack(type: Exec) {
    inputs.file("package-lock.json").withPathSensitivity(PathSensitivity.RELATIVE)
    inputs.dir("src/main/js").withPathSensitivity(PathSensitivity.RELATIVE)
    inputs.file("webpack.config.js")
    outputs.dir(webpackBuildDir)
    outputs.cacheIf { true }

    commandLine 'sh', '-c', "npm ci && node_modules/.bin/webpack"
}

sourceSets {
    main {
        resources {
            srcDir webpackBuildDir
        }
    }
}

tasks.named('processResources') {
    dependsOn webpack
}

tasks.named('inspectRuntimeClasspath') {
    dependsOn webpack
}