build.gradle

// Copyright © 2020 IBA Group, a.s. All rights reserved. Use of this source code is governed by Eclipse Public License – v 2.0 that can be found at: https://www.eclipse.org/legal/epl-2.0/
import org.jetbrains.dokka.gradle.DokkaTask
import org.jetbrains.kotlin.config.LanguageVersion
import org.jetbrains.kotlin.gradle.tasks.KotlinCompile

plugins {
  id 'java'
  id 'org.jetbrains.kotlin.jvm' version '1.6.21'
  id 'org.jetbrains.dokka' version '1.7.20'
}

apply plugin: 'java'
apply plugin: 'kotlin'
apply plugin: 'signing'
apply plugin: 'maven-publish'

archivesBaseName = 'r2z'
group 'eu.ibagroup'
version projectVersion

java {
  sourceCompatibility = JavaVersion.VERSION_11
  targetCompatibility = JavaVersion.VERSION_11
}

repositories {
  mavenCentral()
}

dependencies {
  implementation "org.jetbrains.kotlin:kotlin-stdlib"
  implementation "org.jetbrains.kotlin:kotlin-reflect:1.6.21"
  testImplementation 'org.junit.jupiter:junit-jupiter-api:5.9.2'
  testImplementation 'com.squareup.okhttp3:mockwebserver:4.10.0'
  testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine'
  implementation 'com.squareup.retrofit2:retrofit:2.9.0',
                 'com.squareup.retrofit2:converter-gson:2.9.0',
                 'com.squareup.retrofit2:converter-scalars:2.9.0',
                 'com.google.code.gson:gson:2.10',
                 'com.starxg:java-keytar:1.0.0',
                 'org.yaml:snakeyaml:1.33'
}

test {
  useJUnitPlatform()
}

tasks.withType(KotlinCompile).all {
  kotlinOptions {
    jvmTarget = JavaVersion.VERSION_11.toString()
    languageVersion = LanguageVersion.LATEST_STABLE.versionString
  }
}

tasks.withType(DokkaTask.class) {
  String dokkaBaseConfiguration = """
    {
      "footerMessage": "(c) 2022 IBA Group",
      "templatesDir": "${file("dokka/templates").getAbsolutePath().replace('\\', '/')}",
      "customAssets": ["${file("dokka/assets/zowe-icon.png").getAbsolutePath().replace('\\', '/')}"],
      "customStyleSheets": ["${file("dokka/assets/logo-styles.css").getAbsolutePath().replace('\\', '/')}"]
    }
    """
  pluginsMapConfiguration.set(
          // fully qualified plugin name to json configuration
          ["org.jetbrains.dokka.base.DokkaBase": dokkaBaseConfiguration]
  )
}

task sourceJar(type: Jar) {
  classifier "sources"
  from sourceSets.main.allSource
}

task javadocJar(type: Jar, dependsOn: javadoc) {
  classifier "javadoc"
  from javadoc.destinationDir
}

/**
 * Adds intTest source sets
 */
sourceSets {
  intTest {
    java {
      compileClasspath += main.output
      runtimeClasspath += main.output
      srcDir 'src/intTest/kotlin'
    }
    resources {
      srcDir 'src/intTest/resources'
    }
  }
}

/**
 * Configures the integration tests to inherit the testImplementation and testRuntimeOnly in dependencies
 */
configurations {
  intTestImplementation.extendsFrom testImplementation
  intTestRuntimeOnly.extendsFrom testRuntimeOnly
}

task intTest(type:Test) {
  description = "Run integration tests"
  group = "verification"
  testClassesDirs = sourceSets.intTest.output.classesDirs
  classpath = sourceSets.intTest.runtimeClasspath
  useJUnitPlatform() {
    excludeTags "FirstTime"
  }
  testLogging {
    events("passed", "skipped", "failed")
  }
}

artifacts {
  archives jar
  archives sourceJar
  archives javadocJar
}

signing {
  sign configurations.archives
  required {
    // signing is required if this is a release version and the artifacts are to be published
    !version.toString().endsWith('-SNAPSHOT') && tasks.withType(PublishToMavenRepository).find {
      gradle.taskGraph.hasTask it
    }
  }
  sign publishing.publications
}


publishing {
  publications {
    mavenJava(MavenPublication) {
      customizePom(pom)
      groupId 'eu.ibagroup'
      artifactId 'r2z'
      version projectVersion

      from components.java


      artifact(sourceJar) {
        classifier = 'sources'
      }
      artifact(javadocJar) {
        classifier = 'javadoc'
      }
    }
  }
  repositories {
    maven {
      url "https://s01.oss.sonatype.org/service/local/staging/deploy/maven2"
      credentials {
        username ossrhUsername
        password ossrhPassword
      }
    }
  }
}

def customizePom(pom) {
  pom.withXml {
    def root = asNode()

    // eliminate test-scoped dependencies (no need in maven central POMs)
    root.dependencies.removeAll { dep ->
      dep.scope == "test"
    }

    // add all items necessary for maven central publication
    root.children().last() + {
      resolveStrategy = Closure.DELEGATE_FIRST

      description 'Library that allows to perform http requests to IBM z/OSMF REST API with the help of Retorfit2.'
      name 'Retrofit2-ZOSMF-Library'
      url 'https://github.com/for-mainframe/Retrofit2-ZOSMF-Library'

      issueManagement {
        system 'GitHub'
        url 'https://github.com/for-mainframe/Retrofit2-ZOSMF-Library/issues'
      }
      licenses {
        license {
          name 'Apache License 2.0'
          url 'https://github.com/for-mainframe/Retrofit2-ZOSMF-Library/blob/main/License'
          distribution 'repo'
        }
      }
      scm {
        url 'https://github.com/for-mainframe/Retrofit2-ZOSMF-Library'
        connection 'scm:git:git://github.com/for-mainframe/Retrofit2-ZOSMF-Library.git'
        developerConnection 'scm:git:git@github.com:for-mainframe/Retrofit2-ZOSMF-Library.git'
      }
      developers {
        developer {
          id 'formainframe'
          name 'For Mainframe'
          email 'formainframe@ibagroup.eu'
        }
      }
    }
  }
}

model {
  tasks.generatePomFileForMavenJavaPublication {
    destination = file("$buildDir/generated-pom.xml")
  }
  tasks.publishMavenJavaPublicationToMavenLocal {
    dependsOn project.tasks.signArchives
  }
  tasks.publishMavenJavaPublicationToMavenRepository {
    dependsOn project.tasks.signArchives
  }
}