build.gradle

plugins {
    id 'org.asciidoctor.convert' version '2.4.0'
    id 'eclipse'
    id 'idea'
    id 'java-library'
    id 'org.grails.grails-plugin'
    id 'org.grails.internal.grails-plugin-publish'
}

version project.projectVersion
group "org.grails.plugins"

repositories {
    mavenCentral()
    maven { url "https://repo.grails.org/grails/core" }
}

dependencyManagement {
    imports {
        mavenBom "org.grails:grails-bom:$grailsVersion"
    }
    applyMavenExclusions false
}

targetCompatibility = 1.8
sourceCompatibility = 1.8

configurations {
    documentation
}

dependencies {
    api 'org.springframework.boot:spring-boot-starter-logging'
    api "org.springframework.boot:spring-boot-starter-actuator"
    api "org.springframework.boot:spring-boot-autoconfigure"
    api "org.springframework.boot:spring-boot-starter-tomcat"
    api "org.grails:grails-dependencies"
    api "org.grails:scaffolding-core:$scaffoldingCoreVersion"
    console "org.grails:grails-console"
    profile "org.grails.profiles:plugin"
    testImplementation("org.spockframework:spock-core:${spockVersion}") {
        exclude group:'org.codehaus.groovy', module: 'groovy-all'
    }
    documentation "org.codehaus.groovy:groovy-all"
}

bootRun {
    jvmArgs('-Dspring.output.ansi.enabled=always')
}
// enable if you wish to package this plugin as a standalone application
bootJar.enabled = false

grailsPublish {
    userOrg = "grails"
    githubSlug = 'grails-plugins/grails-angular-scaffolding'
    license {
        name = 'Apache-2.0'
    }
    title = "Angular Scaffolding Plugin"
    desc = "Provides scaffolding for Angular applications"
    developers = [jameskleeh: "James Kleeh"]
}

asciidoctor {
    resources {
        from('src/docs/images')
        into "./images"
    }

    attributes 'experimental'  : 'true',
            'compat-mode'   : 'true',
            'toc'           : 'left',
            'icons'         : 'font',
            'version'       : project.version,
            'groupId'       : project.group,
            'artifactId'    : project.name,
            'scaffoldingCoreVersion': scaffoldingCoreVersion,
            'sourcedir'     : "${projectDir}/src/main/groovy"
}

task apidocs(type: Groovydoc) {
    source project.files('src/main/groovy')

    destinationDir = new File(buildDir, 'docs/api')
    // Might need a classpath
    docTitle = "Grails Angular Scaffolding ${version}"

    classpath = configurations.documentation
    groovyClasspath = configurations.documentation
}

task docs(type:Copy, dependsOn:[apidocs, asciidoctor])  {
    from "$buildDir/asciidoc/html5"
    into "$buildDir/docs"
}