add nix flake setup and development environment

Author: fubhy

.gitignore

@@ -32,4 +32,12 @@ lcov.info
 
 # Docker volumes and debug logs
 .postgres
-logfile
+logfile
+
+# Nix related files
+.direnv
+.envrc
+.data
+
+# Local claude settings
+.claude/settings.local.json

flake.lock

@@ -0,0 +1,153 @@
+{
+  inputs = {
+    nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
+    rust.url = "github:oxalica/rust-overlay";
+    foundry.url = "github:shazow/foundry.nix/stable";
+    process-compose-flake.url = "github:Platonic-Systems/process-compose-flake";
+    services-flake.url = "github:juspay/services-flake";
+    flake-parts.url = "github:hercules-ci/flake-parts";
+  };
+
+  outputs = inputs@{ flake-parts, process-compose-flake, services-flake, nixpkgs, rust, foundry, ... }:
+    flake-parts.lib.mkFlake { inherit inputs; } {
+      imports = [ process-compose-flake.flakeModule ];
+      systems = [
+        "x86_64-linux" # 64-bit Intel/AMD Linux
+        "aarch64-linux" # 64-bit ARM Linux
+        "x86_64-darwin" # 64-bit Intel macOS
+        "aarch64-darwin" # 64-bit ARM macOS
+      ];
+
+      perSystem = { config, self', inputs', pkgs, system, ... }:
+        let
+          overlays = [
+            (import rust)
+            (self: super: {
+              rust-toolchain = super.rust-bin.stable.latest.default;
+            })
+            foundry.overlay
+          ];
+
+          pkgsWithOverlays = import nixpkgs { 
+            inherit overlays system; 
+          };
+        in {
+          devShells.default = pkgsWithOverlays.mkShell {
+            packages = (with pkgsWithOverlays; [
+              # Includes cargo, clippy, cargo-fmt, rustdoc, rustfmt, and other tools.
+              rust-toolchain
+              foundry-bin
+              solc
+              bun
+              protobuf
+              uv
+              cmake
+              corepack
+              nodejs
+              postgresql
+            ]);
+          };
+
+          process-compose = let 
+            inherit (services-flake.lib) multiService;
+            ipfs = multiService ./nix/ipfs.nix;
+            anvil = multiService ./nix/anvil.nix;
+
+            # Helper function to create postgres configuration with graph-specific defaults
+            mkPostgresConfig = { name, port, user, password, database, dataDir }: {
+              enable = true;
+              inherit port dataDir;
+              initialScript = {
+                before = ''
+                  CREATE USER \"${user}\" WITH PASSWORD '${password}' SUPERUSER;
+                '';
+              };
+              initialDatabases = [
+                {
+                  inherit name;
+                  schemas = [ (pkgsWithOverlays.writeText "init-${name}.sql" ''
+                    CREATE EXTENSION IF NOT EXISTS pg_trgm;
+                    CREATE EXTENSION IF NOT EXISTS btree_gist; 
+                    CREATE EXTENSION IF NOT EXISTS postgres_fdw;
+                    CREATE EXTENSION IF NOT EXISTS pg_stat_statements;
+                    GRANT USAGE ON FOREIGN DATA WRAPPER postgres_fdw TO "${user}";
+                    ALTER DATABASE "${database}" OWNER TO "${user}";
+                  '') ];
+                }
+              ];
+              settings = {
+                shared_preload_libraries = "pg_stat_statements";
+                log_statement = "all";
+                default_text_search_config = "pg_catalog.english";
+                max_connections = 200;
+              };
+            };
+          in {
+            # Unit tests configuration
+            unit-tests = {
+              imports = [ 
+                services-flake.processComposeModules.default
+                ipfs
+                anvil
+              ];
+
+              services.postgres."postgres-unit" = mkPostgresConfig {
+                name = "graph-test";
+                port = 5432;
+                dataDir = "./.data/unit/postgres";
+                user = "graph";
+                password = "graph";
+                database = "graph-test";
+              };
+
+              services.ipfs."ipfs-unit" = {
+                enable = true;
+                dataDir = "./.data/unit/ipfs";
+                apiPort = 5001;
+                gatewayPort = 8080;
+                swarmPort = 4001;
+              };
+            };
+
+            # Integration tests configuration
+            integration-tests = {
+              imports = [ 
+                services-flake.processComposeModules.default
+                ipfs
+                anvil
+              ];
+
+              services.postgres."postgres-integration" = mkPostgresConfig {
+                name = "graph-node";
+                port = 3011;
+                dataDir = "./.data/integration/postgres";
+                user = "graph-node";
+                password = "let-me-in";
+                database = "graph-node";
+              };
+
+              services.ipfs."ipfs-integration" = {
+                enable = true;
+                dataDir = "./.data/integration/ipfs";
+                apiPort = 3001;
+                gatewayPort = 3002;
+                swarmPort = 4001;
+              };
+
+              services.anvil."anvil-integration" = {
+                enable = true;
+                package = pkgsWithOverlays.foundry-bin;
+                port = 3021;
+                host = "127.0.0.1";
+                gasLimit = "100000000000";
+                baseFee = 1;
+                blockTime = 2;
+                timestamp = 1743944919;
+                mnemonic = "test test test test test test test test test test test junk";
+                accounts = 10;
+              };
+            };
+          };
+        };
+    };
+}