build.gradle

apply plugin: 'groovy'
apply plugin: 'maven'
apply plugin: 'signing'

group = 'ws.mobily'
version = '0.2'
archivesBaseName = "mobily-sms"

description = """Classes for Mobily.ws SMS messaging """

task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = 'javadoc'
    from 'build/docs/javadoc'
}
 
task sourcesJar(type: Jar) {
    from sourceSets.main.allSource
    classifier = 'sources'
}

artifacts {
    archives jar
    archives javadocJar
    archives sourcesJar
}
signing {
    sign configurations.archives
}
uploadArchives {
    repositories {
        mavenDeployer {
            beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }

            repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
              authentication(userName: sonatypeUsername, password: sonatypePassword)
            }

            pom.project {
               name 'Mobily-sms'
               packaging 'jar'
               description 'Mobily SMS is a library for sending SMS messages via Mobily.ws'
               url 'http://mobily.ws'

               scm {
                   url 'scm:git@github.com:gregorydickson/mobily-sms.git'
                   connection 'scm:git@github.com:gregorydickson/mobily-sms.git'
                   developerConnection 'scm:git@github.com:gregorydickson/mobily-sms.github'
               }

               licenses {
                   license {
                       name 'The Apache Software License, Version 2.0'
                       url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                       distribution 'repo'
                   }
               }

               developers {
                   developer {
                       id 'gregorydickson'
                       name 'Gregory Dickson'
                   }
                   
               }
           }
        }
    }
}



test {
    testLogging {
        
        showStandardStreams = true

    }
}



repositories {
	mavenLocal()
	mavenCentral()
}

dependencies {
	compile 'org.codehaus.groovy:groovy:2.4.6'

	testCompile 'junit:junit:4.+'
	testCompile 'org.mockito:mockito-all:1.9.5'
}