deploy.gradle

// deploy:
// ./gradlew clean
// ./gradlew assemble
// ./gradlew publishToGithub

apply plugin: "maven-publish"
apply plugin: "com.jfrog.bintray"

ext.pluginGroupdId = "com.halcyonmobile.publish.custom"
ext.pluginArtifactId = "java-and-aar"
ext.pluginVersion = "2.0.1"


task sourcesJar(type: Jar, dependsOn: classes) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

task publishToGitHub(dependsOn: "publishMavenJavaPublicationToGitHubPackagesRepository") {
    group = "Publishing"
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java

            groupId "$pluginGroupdId"
            version "$pluginVersion"
            artifactId "$pluginArtifactId"
            artifact sourcesJar
        }
    }

    repositories {
        maven {
            name = "GitHubPackages"
            url = uri("https://github.com/halcyonmobile/halcyon-custom-gradle-publish-plugin")
            credentials {
                username = System.getenv("GITHUB_USERNAME")
                password = System.getenv("GITHUB_TOKEN")
            }
        }
    }
}

bintray {
    user = System.getenv("bintray_username")
    key = System.getenv("bintray_password")
    publications = ['mavenJava']
    publish = true
    override = true
    pkg {
        repo = 'maven'
        name = "$pluginGroupdId:$pluginArtifactId"
        userOrg = "halcyonmobiledevteam"
        vcsUrl = 'https://github.com/halcyonmobile/halcyon-custom-gradle-publish-plugin'
        licenses = ['Apache-2.0']
        version {
            name = pluginVersion
        }
    }
}