build.gradle

plugins {
    id "com.jfrog.bintray" version "1.6"
    id 'groovy'
    id 'idea'
    id 'maven'
}

defaultTasks 'clean', 'jar', 'test'

group = 'com.athaydes'
version = "1.2.13"
description = 'This project is a global extension for Spock to create test (or, in Spock terms, Specifications) reports.'

def groovyVersion = '2.0.8'
def spockVersion = '1.0-groovy-2.0'

repositories {
    mavenLocal()
    mavenCentral()
}

dependencies {
    compile "org.codehaus.groovy:groovy-all:${groovyVersion}"
    compile "org.spockframework:spock-core:${spockVersion}"
    compile 'org.slf4j:slf4j-api:1.7.13'

    testCompile "cglib:cglib-nodep:2.2.2"
    testCompile "org.slf4j:slf4j-simple:1.7.13"
}

test {
    maxParallelForks = 4
    exclude '**/FakeTest.class'
    systemProperty 'project.buildDir', project.buildDir
    testLogging.showStandardStreams = true
    beforeTest { descriptor ->
        logger.lifecycle( "Running test: " + descriptor )
    }
}

jar {
    manifest {
        attributes(
                "Implementation-Title": "Athaydes-Spock-Reports",
                "Implementation-Version": version )
    }
}

/* Publishing config */

task javadocJar( type: Jar ) {
    classifier = 'javadoc'
    from javadoc
}

task sourcesJar( type: Jar ) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

artifacts {
    archives javadocJar, sourcesJar
}

// add all the info required by Maven Central to the pom
configure( install.repositories.mavenInstaller ) {
    pom.project {
        inceptionYear '2013'
        name project.name
        packaging 'jar'
        description project.description

        url 'https://github.com/renatoathaydes/spock-reports'

        scm {
            connection 'git@github.com:renatoathaydes/spock-reports.git'
            developerConnection 'git@github.com:renatoathaydes/spock-reports.git'
            url 'https://github.com/renatoathaydes/spock-reports'
        }

        licenses {
            license {
                name 'The Apache License, Version 2.0'
                url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
            }
        }

        developers {
            developer {
                id 'renatoathaydes'
                name 'Renato Athaydes'
                email 'renato@athaydes.com'
            }
        }
    }
}

def getProjectProperty = { String propertyName ->
    project.properties[ propertyName ]
}

bintray {
    user = getProjectProperty "bintrayUserName"
    key = getProjectProperty "bintrayApiKey"
    configurations = [ 'archives' ]
    publish = true
    pkg {
        repo = 'maven'
        name = 'spock-reports'
        licenses = [ 'Apache-2.0' ]
        labels = [ 'groovy', 'java', 'spock', 'bdd', 'test', 'report' ]
        publicDownloadNumbers = true

        //noinspection GroovyAssignabilityCheck
        version {
            name = project.version
            vcsTag = project.version
            gpg {
                sign = true
            }
            mavenCentralSync {
                sync = true
                user = getProjectProperty 'ossrhUsername'
                password = getProjectProperty 'ossrhPassword'
                close = '1' // '0' to NOT close
            }
        }
    }
}

bintrayUpload.dependsOn build, sourcesJar