-
Notifications
You must be signed in to change notification settings - Fork 12
/
anon_enc_nullifier_non_repudiation.circom
180 lines (165 loc) · 7.3 KB
/
anon_enc_nullifier_non_repudiation.circom
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
// Copyright © 2024 Kaleido, Inc.
//
// SPDX-License-Identifier: Apache-2.0
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
// http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
pragma circom 2.1.4;
include "./lib/check-positive.circom";
include "./lib/check-hashes.circom";
include "./lib/check-sum.circom";
include "./lib/check-nullifiers.circom";
include "./lib/check-smt-proof.circom";
include "./lib/ecdh.circom";
include "./lib/encrypt.circom";
include "./node_modules/circomlib/circuits/babyjub.circom";
// This version of the circuit performs the following operations:
// - derive the sender's public key from the sender's private key
// - check the input and output commitments match the expected hashes
// - check the input and output values sum to the same amount
// - perform encryption of the receiver's output UTXO value and salt
// - check the nullifiers are derived from the input commitments and the sender's private key
// - check the nullifiers are included in the Merkle tree
// - encrypt all secrets with an authority's public key (for non-repudiation purposes)
template Zeto(nInputs, nOutputs, nSMTLevels) {
signal input nullifiers[nInputs];
signal input inputCommitments[nInputs];
signal input inputValues[nInputs];
signal input inputSalts[nInputs];
// must be properly hashed and trimmed to be compatible with the BabyJub curve.
// Reference: https://github.com/iden3/circomlib/blob/master/test/babyjub.js#L103
signal input inputOwnerPrivateKey;
signal input root;
signal input merkleProof[nInputs][nSMTLevels];
signal input enabled[nInputs];
signal input outputCommitments[nOutputs];
signal input outputValues[nOutputs];
signal input outputSalts[nOutputs];
signal input outputOwnerPublicKeys[nOutputs][2];
signal input encryptionNonce;
signal input authorityPublicKey[2];
// the output for a 2-element input (value and salt) encryption is a 4-element array
signal output cipherTextReceiver[4];
// the number of cipher text messages returned by
// the encryption template will be 3n+1
// input length:
// - input owner public key (x, y): 2
// - secrets (value and salt) for each input UTXOs: 2 * nInputs
// - output owner public keys (x, y): 2 * nOutputs
// - secrets (value and salt) for each output UTXOs: 2 * nOutputs
var outputElementsLength = 2 + 2 * nInputs + 2 * nOutputs + 2 * nOutputs;
var l = outputElementsLength;
while (l % 3 != 0) {
l += 1;
}
signal output cipherTextAuthority[l+1];
// derive the sender's public key from the secret input
// for the sender's private key. This step demonstrates
// the sender really owns the private key for the input
// UTXOs
var inputOwnerPublicKey[2];
component pub = BabyPbk();
pub.in <== inputOwnerPrivateKey;
inputOwnerPublicKey[0] = pub.Ax;
inputOwnerPublicKey[1] = pub.Ay;
var inputOwnerPublicKeys[nInputs][2];
for (var i = 0; i < nInputs; i++) {
inputOwnerPublicKeys[i][0] = inputOwnerPublicKey[0];
inputOwnerPublicKeys[i][1] = inputOwnerPublicKey[1];
}
component checkPositives = CheckPositive(nOutputs);
checkPositives.outputValues <== outputValues;
component checkInputHashes = CheckHashes(nInputs);
checkInputHashes.commitments <== inputCommitments;
checkInputHashes.values <== inputValues;
checkInputHashes.salts <== inputSalts;
checkInputHashes.ownerPublicKeys <== inputOwnerPublicKeys;
component checkOutputHashes = CheckHashes(nOutputs);
checkOutputHashes.commitments <== outputCommitments;
checkOutputHashes.values <== outputValues;
checkOutputHashes.salts <== outputSalts;
checkOutputHashes.ownerPublicKeys <== outputOwnerPublicKeys;
component checkNullifiers = CheckNullifiers(nInputs);
checkNullifiers.nullifiers <== nullifiers;
checkNullifiers.values <== inputValues;
checkNullifiers.salts <== inputSalts;
checkNullifiers.ownerPrivateKey <== inputOwnerPrivateKey;
component checkSum = CheckSum(nInputs, nOutputs);
checkSum.inputValues <== inputValues;
checkSum.outputValues <== outputValues;
// With the above steps, we demonstrated that the nullifiers
// are securely bound to the input commitments. Now we need to
// demonstrate that the input commitments belong to the Sparse
// Merkle Tree with the root `root`.
component checkSMTProof = CheckSMTProof(nInputs, nSMTLevels);
checkSMTProof.root <== root;
checkSMTProof.merkleProof <== merkleProof;
checkSMTProof.enabled <== enabled;
checkSMTProof.leafNodeIndexes <== inputCommitments;
// generate shared secret for the receiver
var sharedSecretReceiver[2];
component ecdh1 = Ecdh();
ecdh1.privKey <== inputOwnerPrivateKey;
// our circuit requires that the output UTXO for the receiver must be the first in the array
ecdh1.pubKey[0] <== outputOwnerPublicKeys[0][0];
ecdh1.pubKey[1] <== outputOwnerPublicKeys[0][1];
sharedSecretReceiver[0] = ecdh1.sharedKey[0];
sharedSecretReceiver[1] = ecdh1.sharedKey[1];
// encrypt the value for the receiver
component encrypt1 = SymmetricEncrypt(2);
// our circuit requires that the output UTXO for the receiver must be the first in the array
encrypt1.plainText[0] <== outputValues[0];
encrypt1.plainText[1] <== outputSalts[0];
encrypt1.key <== sharedSecretReceiver;
encrypt1.nonce <== encryptionNonce;
// the output for a 2-element input encryption is a 4-element array
encrypt1.cipherText[0] ==> cipherTextReceiver[0];
encrypt1.cipherText[1] ==> cipherTextReceiver[1];
encrypt1.cipherText[2] ==> cipherTextReceiver[2];
encrypt1.cipherText[3] ==> cipherTextReceiver[3];
// generate shared secret for the authority
var sharedSecretAuthority[2];
component ecdh2 = Ecdh();
ecdh2.privKey <== inputOwnerPrivateKey;
// our circuit requires that the output UTXO for the receiver must be the first in the array
ecdh2.pubKey[0] <== authorityPublicKey[0];
ecdh2.pubKey[1] <== authorityPublicKey[1];
sharedSecretAuthority[0] = ecdh2.sharedKey[0];
sharedSecretAuthority[1] = ecdh2.sharedKey[1];
// encrypt the values for the authority
component encrypt2 = SymmetricEncrypt(2 + 2 * nInputs + 4 * nOutputs);
encrypt2.plainText[0] <== inputOwnerPublicKey[0];
encrypt2.plainText[1] <== inputOwnerPublicKey[1];
var idx1 = 2;
for (var i = 0; i < nInputs; i++) {
encrypt2.plainText[idx1] <== inputValues[i];
idx1++;
encrypt2.plainText[idx1] <== inputSalts[i];
idx1++;
}
for (var i = 0; i < nOutputs; i++) {
encrypt2.plainText[idx1] <== outputOwnerPublicKeys[i][0];
idx1++;
encrypt2.plainText[idx1] <== outputOwnerPublicKeys[i][1];
idx1++;
}
for (var i = 0; i < nOutputs; i++) {
encrypt2.plainText[idx1] <== outputValues[i];
idx1++;
encrypt2.plainText[idx1] <== outputSalts[i];
idx1++;
}
encrypt2.key <== sharedSecretAuthority;
encrypt2.nonce <== encryptionNonce;
encrypt2.cipherText ==> cipherTextAuthority;
}
component main { public [ nullifiers, outputCommitments, encryptionNonce, root, enabled, authorityPublicKey ] } = Zeto(2, 2, 64);