build.gradle

buildscript {
    repositories {
        jcenter()
        google()
    }

    dependencies {
        //  Android 默认的编译工具库插件
        classpath 'com.android.tools.build:gradle:3.0.1'

    }
}

allprojects {
    repositories {
        jcenter()
    }

    // Javadoc设定为UTF-8了
    tasks.withType(Javadoc) {
        options.addStringOption('Xdoclint:none', '-quiet')
        options.addStringOption('encoding', 'UTF-8')
    }
}

/**
 * 生成版本的时间
 */
static def releaseTime() {
    return new Date().format("yyyy_MMdd")
}

/**
 * 生成VersionCode
 */
static def generateVersionCode() {
    return new Date().format("yyyyMMddHH")
}

/**
 *  重命名Apk的方法
 */
def renameAPK(android, variant, output) {
    def flavor = variant.productFlavors[0];
    def flavorName;
    def versionName;

    if (flavor == null) {
        flavorName = ""
        versionName = android.defaultConfig.versionName
    } else {
        versionName = flavor.versionName
        flavorName = flavor.name
    }

    if (versionName == null || versionName.toString().equals("null")) {
        versionName = variant.versionName;
    }

    if (versionName == null || versionName.toString().equals("null")) {
        versionName = ""
    }

    def versionNameSuffix = variant.buildType.versionNameSuffix
    if (versionNameSuffix.toString().equals("null")) {
        versionNameSuffix = ""
    }

    def buildTypeName = variant.buildType.name;

    if (buildTypeName.equals("debug")) {
        buildTypeName = "dev"
    } else if (buildTypeName.equals("release")) {
        buildTypeName = "prod"
    }


    def outputFile = output.outputFile

    if (outputFile != null) {
        if (flavorName.equals("") || flavorName.equals("null")) {
            output.outputFileName = "${APK_PREFIX}_${buildTypeName}_v${versionName}${versionNameSuffix}_${releaseTime()}.apk"
        } else {
            output.outputFileName = "${APK_PREFIX}_${buildTypeName}_${flavorName}_v${versionName}${versionNameSuffix}_${releaseTime()}.apk"
        }
    }
}