build.gradle

plugins {
    id 'java-library'
    id 'io.freefair.lombok' version '8.10.2'
    id 'jacoco'
    id 'org.sonarqube' version '5.1.0.4882'
    id 'maven-publish'
}

group = 'com.iexec.commons'

ext {
    testContainersVersion = '1.20.4'
}

if (!project.hasProperty('gitBranch')) {
    ext.gitBranch = 'git rev-parse --abbrev-ref HEAD'.execute().text.trim()
}

if (gitBranch != 'main' && gitBranch != 'master' && !(gitBranch ==~ '(release|hotfix|support)/.*')) {
    version += '-NEXT-SNAPSHOT'
}

repositories {
    mavenLocal()
    mavenCentral()
    maven {
        url 'https://docker-regis-adm.iex.ec/repository/maven-public/'
        credentials {
            username nexusUser
            password nexusPassword
        }
    }
    maven { url 'https://jitpack.io' }
}

dependencies {
    implementation platform('org.springframework.boot:spring-boot-dependencies:2.7.18')

    // web3j
    api 'org.web3j:core:4.9.7'

    // apache commons.lang3
    implementation 'org.apache.commons:commons-lang3'

    // multiaddresses (IPFS)
    implementation 'com.github.multiformats:java-multiaddr:v1.4.6'

    // jaxb required with Java 11 DataTypeConverter in BytesUtils
    implementation 'javax.xml.bind:jaxb-api'

    // failsafe
    implementation 'net.jodah:failsafe:2.4.4'
    //TODO Migrate from Awaitility to Failsafe everywhere
    implementation 'org.awaitility:awaitility'

    // javax annotations like PostConstruct
    implementation 'javax.annotation:javax.annotation-api'
}

java {
    toolchain {
        languageVersion.set(JavaLanguageVersion.of(17))
    }
    sourceCompatibility = "11"
    targetCompatibility = "11"
    withJavadocJar()
    withSourcesJar()
}

testing {
    suites {
        test {
            useJUnitJupiter()
            dependencies {
                implementation 'org.junit.jupiter:junit-jupiter'
                implementation 'org.mockito:mockito-junit-jupiter'
                implementation 'org.assertj:assertj-core'
                implementation "org.testcontainers:junit-jupiter:$testContainersVersion"
                // spring-test for ReflectionTestUtils
                implementation 'org.springframework:spring-test'
                // logback
                runtimeOnly 'ch.qos.logback:logback-classic'
            }
        }
    }
}

tasks.withType(Test).configureEach {
    finalizedBy jacocoTestReport
}

test {
    reports {
        junitXml.required = true
        html.required = true
    }
}

tasks.register('itest') {
    group 'Verification'
    description 'Runs the integration tests.'
}

// sonarqube code coverage requires jacoco XML report
jacocoTestReport {
    reports {
        xml.required = true
    }
}
tasks.sonarqube.dependsOn tasks.jacocoTestReport

publishing {
    publications {
        maven(MavenPublication) {
            from components.java
        }
    }
    repositories {
        maven {
            credentials {
                username nexusUser
                password nexusPassword
            }
            url = project.hasProperty('nexusUrl') ? nexusUrl : ''
        }
    }
}