Help with changing the ctx in biff

[augustulus11]

I'm new to clojure and thought I'd try giving biff a go. I'm just making a simple blog but thought I'd challenge myself to use postgres as the database. I followed the biff postgres tutorial however I've found that the :example/ds key from the context returns nil (I also removed everything the blog wouldn't need like authentication).

; In my main project file...
(defn use-postgres [{:keys [biff/secret] :as ctx}]
  (let [ds (jdbc/get-datasource (secret :example/postgres-url))]
    (assoc ctx :example/ds ds)))

; ...

(def components
  [biff/use-aero-config
   biff/use-queues
   biff/use-jetty
   biff/use-chime
   biff/use-beholder
   use-postgres])

; ... In my blogs file:


(defn blog-home [{:keys [example/ds] :as ctx} & body]
  (ui/page
   ctx
   [:h2 ""]
   [:p "This is my blog"]
   [:.blog-list (generate-blog-entries (database/get-n-blog-posts ds 10))]
   [:h3 "End blog list"]))

(defn blog-page [{:keys [path-params] :as ctx}]
  (ui/page
   ctx
   ))

(def module
  {:routes ["/blog"
            ["/" {:get blog-home}]]})

The exception I get is

[qtp1087121050-39] ERROR com.biffweb.impl.middleware - Exception while handling request
java.lang.IllegalArgumentException: No implementation of method: :-execute-all of protocol: #'next.jdbc.protocols/Executable found for class: nil

... and after some debugging I found that ds in blog-home is always nil.

I attempted to add the middleware like so:

(def module
  {:routes ["/blog" {:middleware [mid/wrap-site-defaults]}
            ["/" {:get blog-home}]]})

... but this did not fix anything.

Also, while looking at the repl, I found that ds is always present:

(defn get-context []
  (biff/merge-context @main/system))

(defn add-fixtures []
  (let [{:keys [example/ds] :as ctx} (get-context)
        user-id (random-uuid)]
    (log/info "Full CTX: " ctx)
    (log/info "Just db: " (ctx :example/ds))
    (comment
      (jdbc/execute! ds ["INSERT INTO users (id, email, foo) VALUES (?, ?, ?)"
                         user-id "a@example.com" "Some Value"])
      (jdbc/execute! ds ["INSERT INTO message (id, user_id, text) VALUES (?, ?, ?)"
                         (random-uuid) user-id "hello there"]))))

And I get
#object[next.jdbc.connection$url_PLUS_etc$reify__29062 0x149be200 postgresql://tester:postgres@localhost:5433/xyz]

so I am setting up JDBC correctly and putting it in the system map, it just doesn't show up blog's get.

here is the blog's github repo

[jacobobryant]

Hi! The problem is in the order of your components. use-postgres needs to come before biff/use-jetty. biff/use-jetty passes ctx to your ring handlers, so any modifications you make to ctx after biff/use-jetty runs won't be visible to your routes. So it should work if you change the order to this:

```clojure
(def components
  [biff/use-aero-config
   use-postgres
   biff/use-queues
   biff/use-jetty
   biff/use-chime
   biff/use-beholder])